OnAutoItStartRegister is bug ?

[Viktor1703]

AutioIt v3.3.10.2 

Error "$SS_CENTERIMAGE - Variable used without being declared."
 

#OnAutoItStartRegister 'main'

#Include <WindowsConstants.au3>
#Include <StaticConstants.au3>
#Include <GUIConstantsEx.au3>

AutoItSetOption('MustDeclareVars', 1)

Global $hForm

;main()

Func main()
    $hForm = GUICreate('', 397, 339)
    GUICtrlCreateLabel('Test', 20, 20, 60, 21, $SS_CENTERIMAGE)
    GUISetState(@SW_SHOW, $hForm)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    Wend
EndFunc

Сorrectly

#Include <WindowsConstants.au3>
#Include <StaticConstants.au3>
#Include <GUIConstantsEx.au3>

AutoItSetOption('MustDeclareVars', 1)

Global $hForm

main()

Func main()
    $hForm = GUICreate('', 397, 339)
    GUICtrlCreateLabel('Test', 20, 20, 60, 21, $SS_CENTERIMAGE)
    GUISetState(@SW_SHOW, $hForm)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    Wend
EndFunc

Edited February 20, 2014 by Viktor1703

[PhoenixXL]

Before the including the script with constants(ie StaticConstants.au3) the function is executed, hence it shows the error.

 - As it says as Autoit Starts Execute the function "Main"

The following way of inserting the includes isn't recommended but would make you understand better.

#OnAutoItStartRegister "main"

AutoItSetOption('MustDeclareVars', 1)

Global $hForm

;main()

Func main()

    #Include <StaticConstants.au3>
    #Include <GUIConstantsEx.au3>

    ;The variable hForm is also not declared
    MsgBox(64, "Info", "IsDeclared(""hForm"")? " & IsDeclared("hForm") & @CRLF & "0 stands for not declared")   ; -1 stands for local variable

    $hForm = GUICreate('', 397, 339)    ;it is now declared by default as local due to the assignment.
    MsgBox(64, "Info", "IsDeclared(""hForm"")? " & IsDeclared("hForm") & @CRLF & "-1 stands for local variable")    ; -1 stands for local variable

    GUICtrlCreateLabel('Test', 20, 20, 60, 21, $SS_CENTERIMAGE)
    GUISetState(@SW_SHOW, $hForm)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    Wend
EndFunc 

Hope you understand from the example, ask if further queries are present.

Regards

Edited February 20, 2014 by PhoenixXL

[Viktor1703]

Thanks