Preventing invalid characters from being entered into an input control?

[SlowCoder74]

I know I can validate entered data after the fact (e.g. user clicks Ok), but I'd like to prevent a user from entering invalid characters in the first place.

Looks like GUIGetMsg() only triggers when the input box loses focus AND the text has been changed, but not just when the text has been changed.

Ideas?

[Blinky]

You can try to filter invalid characters in the main loop with GuiCtrlRead

[JLogan3o13]

SlowCoder74, how about posting your code to clarify? You mention input box. If you're using an InputBox, it is a blocking function so the script will pause until it goes away. If you're meaning a GUICtrlCreateInput, that is something else entirely. Seeing your code will help us help you

 

Edit: If you do mean an input on your own GUI, you could always do something with AdLibRegister:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

;checks input to ensure the letter 'r' is not typed

AdlibRegister("check", 100)

Local $msg

GUICreate("Test", 300, 300)
Global $input = GUICtrlCreateInput("", 10, 10, 280, 40)

GUISetState(@SW_SHOW)

    While 1
        $msg = GUIGetMsg()
            Select
                Case $msg = $GUI_EVENT_CLOSE
                    ExitLoop
            EndSelect
    WEnd

GUIDelete()

Func check()
    If StringInStr(GUICtrlRead($input), "r") Then
        MsgBox(0, "", "Illegal character entered.") ;inform user
        GUICtrlSetData($input, StringTrimRight(GUICtrlRead($input), 1)) ;remove illegal letter
    EndIf
EndFunc

Edited February 17, 2014 by JLogan3o13

[SlowCoder74]

@Blinky, You are correct that I can check in the main loop.  I was hoping for a more direct method, using a trigger to control the checks.

@JLogan3o13, here's the sample that demonstrates my question:

(And yes, it's using GuiCtrlCreateInput)

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form2 = GUICreate("Form2", 171, 132, 234, 361)
$Input1 = GUICtrlCreateInput("Input1", 16, 16, 145, 21)
$Button1 = GUICtrlCreateButton("Button1", 48, 48, 65, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Input1
            msgbox(0,"","data entered")
    EndSwitch
WEnd

[JLogan3o13]

So try the example I put in, and let us know if that works for you.

[BrewManNH]

Found this in about 1 minute.

[guinness]

A clean way to do it.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $__iLabel = 9999

Example()

Func Example()
     ; Create a GUI with various controls.
    Local $hGUI = GUICreate('Input Filter')
    $__iLabel = GUICtrlCreateInput('', 5, 5, 390)
    GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam
    GUICtrlSetData($__iLabel, StringRegExpReplace(GUICtrlRead($__iLabel), '[\\/:*?"<>\|]', ''))
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

[Blinky]

here is an example with GuiCtrlRead and i borowed the rest     

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ###
$Form2 = GUICreate("Form2", 171, 132, 234, 361)
$Input1 = GUICtrlCreateInput("Input1", 16, 16, 145, 21)
$Button1 = GUICtrlCreateButton("Button1", 48, 48, 65, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
Global $buffer
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    $data=GUICtrlRead($Input1)

    If $buffer<>$data Then
         $newData=StringRegExpReplace(GUICtrlRead($Input1), '[\\/:*?"<>\|]', '')
         If @extended > 0 Then
            ToolTip("ILLEGAL CHARACTER.")
        Else
            ToolTip("")
        EndIf
         GUICtrlSetData($Input1, $newData)
         $buffer=$newData
     EndIf

 WEnd

[guinness]

Not very efficient code there Blinky.

[Blinky]

i know but i just made an example with GuiCtrlRead and a triger because he asked

[guinness]

i know but i just made an example with GuiCtrlRead and a triger because he asked

They only asked because they're limited in the knowledge they have of what AutoIt can do. Our job is to show them there are better ways to go about it.

Edited February 17, 2014 by guinness

[kylomas]

Drive the update to the edit control only when required...

#Include <GUIConstants.au3>
#Include <EditConstants.au3>
#Include <WindowsConstants.au3>

; disallow some special chars and lower/upper case 'a'
local $DisallowedCharsTable = '(?i)[\!\@\#\$\%\^\&\*\(\)A]' ;   precede special chars with a '\' just for safety (some are required, some not)

GUICreate('Character Filter Example', 300, 200)
$Input = GUICtrlCreateInput('', 10, 10, 280, 19)
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Switch BitAND($wParam, 0xFFFF)
        Case $Input
                Switch BitShift($wParam, 16)
                    Case $EN_UPDATE
                        guictrlsetdata($Input,stringregexpreplace(guictrlread($Input),$DisallowedCharsTable,''))
                EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
endfunc

kylomas

edit:something is goofing my tabs up...

Edited February 18, 2014 by kylomas

[guinness]

In case anyone is wondering, kylomas BitAND and BitShift is LoWord and HiWord.

[SlowCoder74]

I appreciate everyone's input!  I will look into the options.

I admit, it's obvious I'm ignorant of all of AutoIT's tricks, but I'm learning.  It's much more powerful than what I was led to believe when I first began using it.  At this time, it is my most used programming tool, and I am using it to build many applications and tools at my work, including some that are rather large.  It's much more than just a scripting language.