How to Set Transparent to GUI AutoIT

[scila1996]

Hi All !

I like this one simply GUIDE 

 

I want all of its windows to be transparent like this 

 

- Letters during writing without

 

#include <GUIConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("AForm1", 281, 165, 252, 199, BitOR($WS_SYSMENU,$WS_POPUPWINDOW,$WS_BORDER,$WS_CLIPSIBLINGS), BitOR($WS_EX_TRANSPARENT,$WS_EX_WINDOWEDGE))
$Label1 = GUICtrlCreateLabel("Welcome to Bkav", 64, 64, 147, 27)
GUICtrlSetFont(-1, 14, 400, 0, "Tahoma")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

This is my program.

I want it like this !

Thank You !

 

[Fraser]

Try WinSetTrans http://www.autoitscript.com/autoit3/docs/functions/WinSetTrans.htm

Edit: Like this

#include <GUIConstants.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("AForm1", 281, 165, 252, 199, BitOR($WS_SYSMENU,$WS_POPUPWINDOW,$WS_BORDER,$WS_CLIPSIBLINGS), BitOR($WS_EX_TRANSPARENT,$WS_EX_WINDOWEDGE))
$Label1 = GUICtrlCreateLabel("Welcome to Bkav", 64, 64, 147, 27)
GUICtrlSetFont(-1, 14, 400, 0, "Tahoma")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

WinSetTrans ( $Form1, "", 200 )

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Edited February 14, 2014 by Fraser

[scila1996]

Thank you. It's nice and simple, I like it !

[scila1996]

I have one small problem 

 

If used, it will WinSetTrans syntax throughout the entire GUI 

 

I want the words  "Welcode To Bkav" not transparent

 

I want it like this !

 

[Melba23]

scila1996,

Like this perhaps:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WINAPI.au3>

$hGUI = GUICreate("Test", 500, 500, Default, Default, Default, $WS_EX_LAYERED)
GUISetBkColor(0xABCDEF)

$cLabel = GUICtrlCreateLabel("This text is not transparent", 10, 200, 480, 100)
GUICtrlSetFont($cLabel, 30, 600)

_WinAPI_SetLayeredWindowAttributes($hGUI, 0xABCDEF, 200) ; Adjust transparency here (0-255)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Better?

M23

[scila1996]

Thanh !!!!!