reversing a string (sort of)

[AdamGJohnson]

Hi Guys,

Need some help. I'm trying to write a script that will take a hex value and reverse the string two digits at a time, so F042EFCA will become CAEF42F0. So as you can see the string itself isn't reversed but the last two digits are now first,  the second from last two digits are next etc. Can anyone recommend a way of doing this please?

Thanks for yout time!

Adam

[Melba23]

AdamgJohnson,

Welcome to the AutoIt forum.

This is the easiest way to do that:

$sString = "F042EFCA"
$sReversed = StringRegExpReplace($sString, "(.{2})(.{2})(.{2})(.{2})", "$4$3$2$1")
MsgBox(0, "Reversed (sort of)", $sReversed)

Basically we divide the string into 2 character bits and then recombine them in reverse order.

M23

Edited February 14, 2014 by Melba23
Typnig

[FireFox]

Melba,

What if the string is longer ?

[Melba23]

FireFox,

Then we can do it like this:

$sString = "F042EFCA"
$aSplit = StringRegExp($sString, "(.{2})", 3) ; Get an array of the 2-char elements

$sReversed = ""
For $i = UBound($aSplit) - 1 To 0 Step -1
    $sReversed &= $aSplit[$i] ; Recombine in the reverse order
Next

MsgBox(0, "Reversed (sort of)", $sReversed)

Any more requests?

M23

[FireFox]

Nope

My try :

Local $s = "F042EFCA"

$s = StringReverse($s, 1)

Local $sReversed = ""

For $i = 1 To StringLen($s) Step 2
    $sReversed &= StringReverse(StringMid($s, $i, 2), 1)
Next

MsgBox(0, "Reversed (sort of)", $sReversed)

Should be efficient since the StringReverse function is now internal. Edited February 14, 2014 by FireFox

[AdamGJohnson]

You guys are awesome! thanks so much