Input's clickable area doesn't properly scale with it's appearance

[T0M50N]

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$MainForm = GUICreate('Form1', @DesktopWidth/2, @DesktopHeight/2, @DesktopWidth/4, @DesktopHeight/4, BitOR($GUI_SS_DEFAULT_GUI,$WS_SIZEBOX,$WS_THICKFRAME))
$MenuItem1 = GUICtrlCreateMenu("File")
    $MenuItem1Pref = GUICtrlCreateMenuItem("Preferences", $MenuItem1)
    $MenuItem12 = GUICtrlCreateMenuItem("About", $MenuItem1)
    $MenuItem13 = GUICtrlCreateMenuItem("Help", $MenuItem1)
GUISetState(@SW_SHOW, $MainForm)

$Preferences = GUICreate("Preferences", 540, 118, (@DesktopWidth/2)-(@DesktopWidth/4)/2, (@DesktopHeight/2)-118/2, BitOR($GUI_SS_DEFAULT_GUI,$WS_SIZEBOX,$WS_THICKFRAME))
$Label1 = GUICtrlCreateLabel("Record Key:", 88, 8, 90, 24)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Button1 = GUICtrlCreateButton("RCtrl + RShift + RAlt + Printscreen", 184, 8, 201, 25)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP+$GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)
$Label2 = GUICtrlCreateLabel("Source Video Location: ", 8, 40, 173, 24)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Input1 = GUICtrlCreateInput("Input1", 184, 40, 249, 21)
GUICtrlSetResizing(-1,$GUI_DOCKBORDERS)
$Button2 = GUICtrlCreateButton("Browse", 440, 40, 89, 25)
GUICtrlSetResizing(-1, $GUI_DOCKRIGHT+$GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)
$Label3 = GUICtrlCreateLabel("Video Output Format: ", 24, 72, 161, 24)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Label4 = GUICtrlCreateLabel("Custom Name", 193, 72, 70, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Label5 = GUICtrlCreateLabel("Date", 272, 72, 27, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Label6 = GUICtrlCreateLabel("Unique Code", 312, 72, 66, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Label7 = GUICtrlCreateLabel("Video Number", 392, 72, 71, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Label8 = GUICtrlCreateLabel("Trim Times", 472, 72, 55, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Checkbox1 = GUICtrlCreateCheckbox("", 215, 89, 17, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Checkbox2 = GUICtrlCreateCheckbox("", 273, 91, 17, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Checkbox3 = GUICtrlCreateCheckbox("", 336, 91, 17, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Checkbox4 = GUICtrlCreateCheckbox("", 416, 90, 17, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
$Checkbox5 = GUICtrlCreateCheckbox("", 489, 89, 17, 17)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP)
GUIRegisterMsg($WM_GETMINMAXINFO, "PreferencesWinSizeLimit")

Func PreferencesWinSizeLimit($hWnd, $Msg, $wParam, $lParam)
    $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int",$lParam)
    If $hWnd = $Preferences Then
        DllStructSetData($minmaxinfo,7,550) ; min X
        DllStructSetData($minmaxinfo,8,156) ; min Y
        DllStructSetData($minmaxinfo,10,156) ; max Y
    EndIf
    Return 0
EndFunc

While 1
    $nMsg = GUIGetMsg(1)
    Switch $nMsg[1]

        Case $MainForm

            Switch $nMsg[0]

                Case $GUI_EVENT_CLOSE
                    Exit

                Case $MenuItem1Pref
                    GUISetState(@SW_SHOW, $Preferences)

            EndSwitch


        Case $Preferences

            Switch $nMsg[0]

                Case $GUI_EVENT_CLOSE
                    GUISetState(@SW_HIDE, $Preferences)

            EndSwitch
    EndSwitch
WEnd

$Input1 = GUICtrlCreateInput("Input1", 184, 40, 249, 21)
GUICtrlSetResizing(-1,$GUI_DOCKBORDERS)

The actual clickable area of the input scales incorrectly.

The red box shows where you can click to give focus to the input.

Help would be much appreciated but I'm off to bed now so don't expect a speedy reply.

Edited February 11, 2014 by T0M50N

[BrewManNH]

Change it to this:

$Label2 = GUICtrlCreateLabel("Source Video Location: ", 8, 40, 173, 24)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKTOP+$GUI_DOCKWIDTH)

Your label is overwriting the left side of the input, this keeps the size of the label to the original size.

[T0M50N]

Great, thanks.