How Do I Release Memory of a Static Variable?

[czardas]

Does anyone know a way to remove a Static variable from memory - as if the variable had never existed - so that it can be redeclared as static several times for defined periods: but only when needed.

Edited February 2, 2014 by czardas

[DatMCEyeBall]

I always wanted to know how to remove any variable from the AutoIt internal lists.

[czardas]

Actually I may have thought of a solution which suits my purposes. I can easily free memory setting the variable equal to zero, however it will require some startup and shutdown type code: so the static exists in memory until you run the additional code - I still need to think about this. I would still be interested to hear of any alternatives.

Edited February 2, 2014 by czardas

[guinness]

Well you can do Static $vVar = "", but what you're asking can't be done.

[Melba23]

czardas,

Could you give an example of when you would wish to do this? Perhaps we might then be able to come up with a workaround.

M23

[czardas]

To me a static variable is useful when you repeatedly call a function - perhaps in a loop. But if the variable uses a lot of memory then we may wish to simply clear memory after the loop process. Then the user decides to run the same (or a similar process) again. The function is called, again in a loop and the static declaration is encountered for the first time again on each subsequent batch process. You destroy the variable each time.

Edited February 2, 2014 by czardas

[guinness]

What about adding a clear param?
 

Func SomeFunc($vVar_1, $fClear = False)
    Local Static $kVar = '99 Problems'
    If $fClear Then
        $kVar = 0
    EndIf
EndFunc

[czardas]

What about adding a clear param?

 

That's the only thing I can think of and probably what I will try.

Edited February 2, 2014 by czardas

[guinness]

Or look at using ByRef instead?! 

SomeFunc(100, $vStaticData)
$vStaticData = 0

Func SomeFunc($vVar_1, ByRef $vStaticData)
    $vStaticData = '99 Problems'
EndFunc

[Melba23]

czardas,

How does that differ from a Global variable which is re-initialised before each new loop process:

Global $vPsuedo_Static

; Set the Pseudo_Static variable to the intiial value
$vPsuedo_Static = 100
; Run the first loop process
For $i = 1 To 5
    _Process_Func(1)
Next
; Clear the variable when finished
$vPsuedo_Static = 0
ConsoleWrite("Cleared: " & $vPsuedo_Static & @CRLF)

; Reset the intial value
$vPsuedo_Static = 100
; Run the second loop process
For $i = 1 To 5
    _Process_Func(2)
Next

Func _Process_Func($iLoop)
    ; Amend variable - value is retained for each call
    $vPsuedo_Static += 1
    ConsoleWrite("Loop " & $iLoop & ": - " & $vPsuedo_Static & @CRLF)
EndFunc

M23

[czardas]

Well using a global is another alternative of course. I would prefer static to global: to keep the variable invisible to other functions.

Edited February 2, 2014 by czardas

[jchd]

Ability to destroy variables in the back of the interpretor would be opening the hell gates.

czardas,

Static means initialization is only performed once. How do you want to violate this invariant?

[czardas]

Ability to destroy variables in the back of the interpretor would be opening the hell gates.

czardas,

Static means initialization is only performed once. How do you want to violate this invariant?

 

I was thinking of the convenience of simply being able to point to it and destroy it, rather than having to jump through hoops. I'll probably go with guinness' or Melba's suggestion.

Thanks to all.

Edited February 2, 2014 by czardas

[czardas]

I tried combining your suggestions - thanks again. I may do something like the following: so the variable $vStatic will not be visible to other functions.

;

expandcollapse popup

Global $g_STATIC_DESTROY = 1

_StartUp()
For $i = 0 To 9
    _Func($i)
Next
_ShutDown()

_Func(0) ; Checking the shutdown worked

_StartUp() ; Checking again
_Func(0)
_ShutDown()

Func _Func($iParam)
    Static $vStatic = _GetStatic()
    ConsoleWrite(($vStatic = _GetStatic()) & " " & ($g_STATIC_DESTROY = 0) & " ==> " & $iParam + $vStatic & @LF)

    If $vStatic = 0 Then
        $vStatic = _GetStatic()
    ElseIf $g_STATIC_DESTROY Then ; Shutdown
        $vStatic = 0
        Return
    EndIf

    ; Code continues
EndFunc

Func _StartUp()
    $g_STATIC_DESTROY = 0
EndFunc

Func _ShutDown()
    $g_STATIC_DESTROY = 1
    _Func(-1)
EndFunc

Func _GetStatic()
    ; Long process
    Return 1
EndFunc

Edited February 2, 2014 by czardas

[czardas]

Actually I don't like the code above. The function StartUp is not needed because of the way Static works. This is better:

;

expandcollapse popup

Global $g_STATIC_DESTROY = 0

For $j = 1 To 3
    For $i = 1 To 3
        _Func()
    Next
    _StaticDestroy()
    ConsoleWrite(@LF)
Next

Func _Func()
    Static $vStatic = _GetStatic()
    ConsoleWrite("$vStatic BEFORE = " & $vStatic & ", ")

    If $g_STATIC_DESTROY Then
        $vStatic = 0
        $g_STATIC_DESTROY = 0
        ConsoleWrite("Shutting down ==> $vStatic AFTER = " & $vStatic & @LF)
        Return
    ElseIf $vStatic = 0 Then
        $g_STATIC_DESTROY = 0
        $vStatic = _GetStatic()
    EndIf

    ConsoleWrite(" Code continues ==> $vStatic AFTER = " & $vStatic & @LF)
EndFunc

Func _StaticDestroy()
    $g_STATIC_DESTROY = 1
    _Func()
EndFunc

Func _GetStatic()
    ; Long process
    ConsoleWrite("Long Process ==> ")
    Return 1
EndFunc

Edited February 2, 2014 by czardas

[trancexx]

Why do you need global variable? Doesn't this do what you want:

Func Test($bDeleteStaticVal = False)
    Local Static $vStatic

    If $bDeleteStaticVal Then
        ConsoleWrite("-> freeing static" & @CRLF & @CRLF)
        $vStatic = ""
    ElseIf Not $vStatic Then
        ConsoleWrite("+> allocating and retrieving static" & @CRLF)
        $vStatic = "Some static value that occupies memory" & @CRLF
    Else
        ConsoleWrite("> retrieving static" & @CRLF)
    EndIf

    Return $vStatic
EndFunc


ConsoleWrite(Test() & @CRLF)
ConsoleWrite(Test() & @CRLF)
ConsoleWrite(Test() & @CRLF)

; memory is freed
Test(True)

; and here we go again...
ConsoleWrite(Test() & @CRLF)
ConsoleWrite(Test() & @CRLF)
ConsoleWrite(Test() & @CRLF)

[czardas]

Yes it's perfect trancexx! Why am I making it sound so complicated - I don't know.

[guinness]

Pretty much what I said back in #7!

[czardas]

Yeah I see. I intend to only use the second parameter when the function is called by a second function to clean up resources. I just didn't quite have a clear picture until now.