Is FTPS or FTP over SSL possible in AutoIT

[Graeme]

Hi,

I'm trying to download a file from a secure site that doesn't allow ftp. I've been trying to use FTPS but I can't find anything about FTPS (or FTP over SSL) except one reference that was a few years ago. So I'm wondering if things have changed. I've trawled through WinHttp and FF but can't find anything.

If anyone has some good ideas I'd love to hear from you. here is one example of what I tried, and it seemed to work at first but then there was no response at the end:(

#include <string.au3>
#include <inet.au3>
#include <guiconstants.au3>
#include <winhttp.au3>

Dim $hw_connect, $hw_open, $h_openRequest, $LocalIP, $M

$LocalIP = "https://www.example.org"

$hw_open = _WinHttpOpen()

$hw_connect = _WinHttpConnect($hw_open, $LocalIP)

$h_openRequest = _WinHttpOpenRequest($hw_connect, "GET", "programname.exe")
MsgBox(0,"",$hw_connect&@error)
$M = _WinHttpSetCredentials($h_openRequest, $WINHTTP_AUTH_TARGET_SERVER, $WINHTTP_AUTH_SCHEME_BASIC, "username", "password")
MsgBox(0,"",$M)
$M= _WinHttpSendRequest($h_openRequest)
MsgBox(0,"",$M)

$M= _WinHttpReceiveResponse($h_openRequest)
MsgBox(0,"",$M& " " &@error)

[Melba23]

Graeme,

Please pay attention to where you post - the "Examples" section where you started this thread is clearly marked: "This is NOT a general support forum!". I have moved the thread for you, but would ask you to be more careful in future.

M23

[somdcomputerguy]

I don't know if you've searched thru the forums yet, but if not, try it. Use ftps as the keyword.

[Graeme]

Melba23 - Thanks for moving my question to the right place. Sorry that I made that error.

SoundComputerguy - Sorry I didn't specifiy that the forums were one of the places I had been also trawling through - my eyes are going square:( Any fresh ideas very welcome.

Blessings

Graeme

[wakillon]

Take a look to the >libcURL UDF topic.

[trancexx]

WinHTTP doesn't support FTP protocol in any form.

[Graeme]

Thanks for that trancexx. Have a good day.

Blessings

Graeme

[smcan]

Don't know if it would get you where you want to go but you could try using psftp.exe (http://www.chiark.greenend.org.uk/~sgtatham/putty/download.html).

Would need to have psftp.exe in the working directory or get it in the path of the script and you would need a separate script file for use by psftp in the working directory as well.

Script file contains the commands you want to run through psftp (example.scr):

cd /home/user

put test.txt

get test2.txt

quit

Would call it via autoit with:

Run(@ComSpec & " /c" & "psftp.exe user@hostname -pw password -b test.scr","",@SW_HIDE)

The -b test.scr is what calls the psftp script.

[Graeme]

Hi Wakillon,

I downloaded the libcurl.au3 etc but I can't make even the example files work? What could I be doing wrong?

Blessings

Graeme

[wakillon]

Hi Wakillon,

I downloaded the libcurl.au3 etc but I can't make even the example files work? What could I be doing wrong?

Blessings

Graeme

 

Try this way :

expandcollapse popup

#include <libcURL.au3>

Global $bCallbackBuffer

_url2file ( 'ftps://...../filename.txt', @DesktopDir & '\filename.txt' )

Func _url2file($sURL, $sFilePath)
    ConsoleWrite ( '$sURL : ' & $sURL & @Crlf )
    Local $hcurl = _curl_easy_init()
    If $hcurl Then
        Local $tCURLSTRUCT_URL = DllStructCreate("char[" & StringLen($sURL) + 1 & "]")
        DllStructSetData($tCURLSTRUCT_URL, 1, $sURL)
        _curl_easy_setopt($hcurl, $CURLOPT_URL, DllStructGetPtr($tCURLSTRUCT_URL))
        _curl_easy_setopt($hcurl, $CURLOPT_VERBOSE, 1)
        _curl_easy_setopt($hcurl, $CURLOPT_FOLLOWLOCATION, 1)
        _curl_easy_setopt($hcurl, $CURLOPT_NOPROGRESS, 1)

        _curl_easy_setopt ( $hcurl, $CURLOPT_PORT, 990 ) ; Port 990 for the FTPS control channel, and 989 for the FTPS data channel
        _curl_easy_setopt ( $hcurl, $CURLOPT_SSL_VERIFYPEER, 0 )
        _curl_easy_setopt ( $hcurl, $CURLOPT_SSL_VERIFYHOST, 1 )
        _curl_easy_setopt ( $hcurl, $CURLOPT_USE_SSL, $CURLOPT_FTPSSLAUTH )
        _curl_easy_setopt ( $hcurl, $CURLOPT_USERPWD, 'username:password' ) ; set your username and password
        _curl_easy_setopt ( $hcurl, $CURLOPT_SSLVERSION, 3 )

        $bCallbackBuffer = ""
        Local $handle = DllCallbackRegister("_my_fwrite", "uint:cdecl", "ptr;uint;uint;ptr")
        _curl_easy_setopt($hcurl, $CURLOPT_WRITEFUNCTION, DllCallbackGetPtr($handle))
        _curl_easy_setopt($hcurl, $CURLOPT_WRITEDATA, 0)
        _curl_easy_perform($hcurl)
        DllCallbackFree($handle)
        _curl_easy_cleanup($hcurl)
        If $bCallbackBuffer Then
            ConsoleWrite("+ $bCallbackBuffer: " & $bCallbackBuffer & @CRLF)
            Local $fh = FileOpen($sFilePath, 18)
            If $fh <> -1 Then
                FileWrite($fh, $bCallbackBuffer)
                FileClose($fh)
            EndIf
        EndIf
    EndIf
EndFunc   ;==>_url2file

Func _my_fwrite($buffer, $size, $nmemb, $stream)
    Local $vData = DllStructCreate("byte[" & $size * $nmemb & "]", $buffer)
    $bCallbackBuffer &= DllStructGetData($vData, 1)
    Return $size * $nmemb
EndFunc   ;==>_my_fwrite

Not tested as i do not have access to a ftps server...

Try to adapt it to your needs 

[anh7codon]

Hello

Is there any example for Upload a file via FTPS with libcurl.au3

[t0nZ]

Hi @anh7codon, I share this function from one of my scripts, this piece of code uploads on a secure FTP site some files.PDF.

I worked starting from this post, and  in short you have to use the SFTPEx.au3 UDF and keep in the same folder with your script this executable: psftp.exe (read the post I linked...)

My code for upload:

expandcollapse popup

#include <SFTPEx.au3>

Func loadcorrections() ; carico i pdf invoice da correggere
    GOLLOG("checking corrections 2 send...")
    Local $corrarray = _FileListToArrayRec($folderPDF2correct, "fatt-*-*-*.pdf", 1, 0, 1, 0)
    If @error Then
        If @extended = 9 Then
            GOLLOG("no corrections 2 send !")
        Else
            $ctrlftpesito1 = "error checking corrections: " & @extended
            ExitwithError()
        EndIf
        Return
    EndIf

    ;_ArrayDisplay($corrarray) ; DEBUG
    ;ftp connessione
    Local $Open
    Local $conta = 0
    $Open = _SFTP_Open($psftp) ; inoltre apro e chiudo sFTP per ogni singola cartella
    $Conn = _SFTP_Connect($Open, $ftpserver, $ftpuser, $ftppass) ; SFTP 
    If $Conn = 0 Then
        $ctrlftpesito1 = "ftp_connect ERROR"
        ExitwithError()
    Else
        $ctrlftpesito1 = "ftp_connect OK"
        GOLLOG($ctrlftpesito1)
    EndIf
    ; imposto cartella di Upload

    If StringInStr(_SFTP_DirSetCurrent($Conn, $folderFTPcorrezioni), $folderFTPcorrezioni) <> 0 Then ;posiziono a directory ftp
        GOLLOG("dirSetCurrent OK")
    Else
        $ctrlftpesito1 = "error in ftp_dirsetcurrent " & @error
        ExitwithError()
    EndIf

    Do
        $conta += 1 ;contatore files
        If _SFTP_Fileput($Conn, $folderPDF2correct & "\" & $corrarray[$conta]) Then
            GOLLOG("UPLOADED " & $corrarray[$conta])
        Else
            $ctrlftpesito1 = "error" & @error & " uploading " & $corrarray[$conta]
            ExitwithError()
        EndIf

        If Not FileMove($folderPDF2correct & "\" & $corrarray[$conta], $folderPDFcorrectsent & "\" & $corrarray[$conta], 1) Then

            $ctrlftpesito1 = "error" & @error & " moving uploaded corrected file: " & $corrarray[$conta]
            ExitwithError()


        EndIf

    Until $conta = $corrarray[0]
    _SFTP_Close($Conn)

    Local $textcorr = $conta & " Corrected Invoices uploaded and stored "

    GOLLOG($textcorr)
    $textcorr = $textcorr & _ArrayToString($corrarray, "|", 1)
    mail("mail@themail.it", " -info- fatture corrette", $textcorr, "")

EndFunc   ;==>loadcorrections

In this func I search for a bunch of PDF files, I put the names in an array and I upload every file.

Bye