Using a regexp to extract functions. Encountering difficulty.

[jaberwacky]

Hi.  I'm trying to use this regexp to extract the bodies of functions from an au3:

(?mi)\s*func\s*\w*\(.*\)[\v*.*]*endfunc
~~~~~~~~~~~~~~~~~~~~~~~~^^^^^^^^

The carets mark the section giving me trouble.  I can't make it repeat.  Is there a better way?

If I use:

(?mi)\s*func\s*\w*\(.*\)\v*.*\v*.*endfunc

Then I can get the function _NowDate.

If I use:

(?mi)\s*func\s*\w*\(.*\)\v*.*\v*.*\v*.*endfunc

Then I get the previous func plus _NowTime.  If I repeat it more than that I get an error of no matches found.

I am using the regexp helper found in the helpfile.

Here are the functions I'm using as a test:

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Author ........: Jos van der Zande
; Modified.......:
; ===============================================================================================================================
Func _NowDate()
  Return (_DateTimeFormat(@YEAR & "/" & @MON & "/" & @MDAY, 0))
EndFunc

; #FUNCTION# ====================================================================================================================
; Author ........: Jos van der Zande
; Modified.......:
; ===============================================================================================================================
Func _NowTime($sType = 3)
  If $sType < 3 Or $sType > 5 Then $sType = 3
  Return (_DateTimeFormat(@YEAR & "/" & @MON & "/" & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC, $sType))
EndFunc

; #FUNCTION# ====================================================================================================================
; Author ........: /dev/null
; Modified.......:
; ===============================================================================================================================
Func _SetDate($iDay, $iMonth = 0, $iYear = 0)
  ;============================================================================
  ;== Some error checking
  ;============================================================================
  If $iYear = 0 Then $iYear = @YEAR
  If $iMonth = 0 Then $iMonth = @MON
  If Not _DateIsValid($iYear & "/" & $iMonth & "/" & $iDay) Then Return 1

  Local $tSystemTime = DllStructCreate($tagSYSTEMTIME)

  ;============================================================================
  ;== Get the local system time to fill up the SYSTEMTIME structure
  ;============================================================================
  DllCall("kernel32.dll", "none", "GetLocalTime", "struct*", $tSystemTime)
  If @error Then Return SetError(@error, @extended, 0)

  ;============================================================================
  ;== Change the necessary values
  ;============================================================================
  DllStructSetData($tSystemTime, 4, $iDay)
  If $iMonth > 0 Then DllStructSetData($tSystemTime, 2, $iMonth)
  If $iYear > 0 Then DllStructSetData($tSystemTime, 1, $iYear)

  ;============================================================================
  ;== Set the new date
  ;============================================================================
  Local $iRetval = _Date_Time_SetLocalTime($tSystemTime)
  If @error Then Return SetError(@error + 10, @extended, 0)

  Return Int($iRetval)
EndFunc

EDIT: I had the Regexps all messed up.  Please look again.

Edited January 15, 2014 by jaberwacky

[jchd]

Untested:

(?imsx)^\s*func\s+\w*\(\N*?\).*?^\s*endfunc

EDIT: changed after realizing body was not only body...

Edited January 15, 2014 by jchd

[jaberwacky]

Fantastic!  Thank you.  Well, as an aside, I did ultimately want just the body without the func/endfunc parts but I think it might be up to me to experiment with what you gave me.

=)  Thank you again.

Edit: any idea on why I couldn't get [v*.*]* to repeat?

Edited January 15, 2014 by jaberwacky

[jchd]

Ha! That was my first reading of "body" but I instantly changed my mind right after posting. Here you are:

(?imsx)^\s*func\s+\w*\(\N*?\)\N*(.*?)^\s*endfunc

[v*.*]* is a character class and repetition doesn't work inside character classes.

[jaberwacky]

You are a gentleman and a scholar.

::heh:: yeah, I did decide like you did to keep the func/endfunc in there ... ok, but it's still a good thing to have both examples because now I get to study the differences between them.

[guinness]

I have done quite a bit with AutoIt scripts, even posted a thread about some parsing functions.

My version.

#include <Array.au3>

Example()

Func Example()
    Local $aArray = 0, $sData = FileRead(@ScriptFullPath)
    _GetFunctions($sData, $aArray) ; Produces an array with Function + FuncName.
    If UBound($aArray) Then _ArrayDisplay($aArray)
EndFunc   ;==>Example

Func _GetFunctions(ByRef $sData, ByRef $aArray)
    $aArray = StringRegExp($sData & @CRLF, '(?ims)(^Func(?=\h)\h+(\w+)\h*\(.*?(?<=\r|\n|\r\n)EndFunc(?=\R|\s))', 3)
EndFunc   ;==>_GetFunctions