Re-write of _FileWriteToLine()

[guinness]

Could you guys test this to see if I haven't messed anything up. It now uses the native FileReadToArray() instead of FileRead() and a regular expression.

expandcollapse popup

#include <FileConstants.au3>

Local $hFileOpen = FileOpen('Test.txt', $FO_OVERWRITE)
For $i = 1 To 100
    FileWriteLine($hFileOpen, $i)
Next
FileClose($hFileOpen)
_FileWriteToLine('Test.txt', 10, 'Line_10', 1)
ConsoleWrite(@error & @CRLF)

; #FUNCTION# ====================================================================================================================
; Author ........: cdkid
; Modified.......: partypooper, MrCreatoR, guinness
; ===============================================================================================================================
Func _FileWriteToLine($sFilePath, $iLine, $sText, $iOverWrite = 0)
    If $iLine <= 0 Then Return SetError(4, 0, 0)
    If Not IsString($sText) Then
        $sText = String($sText)
        If $sText = "" Then Return SetError(6, 0, 0)
    EndIf
    If $iOverWrite <> 0 And $iOverWrite <> 1 Then Return SetError(5, 0, 0)
    If FileExists($sFilePath) = 0 Then Return SetError(2, 0, 0)

    Local $aArray = FileReadToArray($sFilePath)
    Local $iUBound = UBound($aArray) - 1
    If ($iUBound + 1) < $iLine Then Return SetError(1, 0, 0)

    Local $hFileOpen = FileOpen($sFilePath, FileGetEncoding($sFilePath) + $FO_OVERWRITE)
    If $hFileOpen = -1 Then Return SetError(3, 0, 0)

    Local $sData = ""
    $iLine -= 1 ; Now the array is 0-based, so reduce the line number by 1.
    For $i = 0 To $iUBound
        If $i = $iLine Then
            If $iOverWrite Then
                If $sText Then $sData &= $sText & @CRLF
            Else
                $sData &= $sText & @CRLF & $aArray[$i] & @CRLF
            EndIf
        ElseIf $i < $iUBound Then
            $sData &= $aArray[$i] & @CRLF
        ElseIf $i = $iUBound Then
            $sData &= $aArray[$i]
        EndIf
    Next

    FileWrite($hFileOpen, $sData)
    FileClose($hFileOpen)
    Return 1
EndFunc   ;==>_FileWriteToLine

Edited January 8, 2014 by guinness

[BrewManNH]

One thing I'd change in the demo script is the line number you're inserting to, or change what you're inserting. The text says line 10, you're inserting it in line 1.

BTW, other than that it works very well.

[guinness]

Whoops, it was just some left over testing to check it was working correctly. Thanks.

[jaberwacky]

Is the $iOverwrite param necessary?  Doesn't seem to do anything different to me.  OK, I tested it wrong, it doesn't overwrite the file.  But why?

Edited January 8, 2014 by jaberwocky6669

[BrewManNH]

It overwrites the line instead of inserting it at that line number. So 10 would become Line_10.

[jaberwacky]

Oh gosh, k, I see it now.

[jaberwacky]

One thing.  I see that $text is tested in this line:

If $sText Then $sData &= $sText & @CRLF

Though it's tested previously:

If $sText = "" Then Return SetError(6, 0, 0)

Maybe the 2nd line here should be brought out of the If and tested regardless.

Edited January 8, 2014 by jaberwocky6669

[trancexx]

Can't you write some regexp to insert lines? Looping through the whole array doesn't seem too efficient.

Forum community has some very good regexp freaks, maybe they could help.

[Mat]

You don't need to be a regex wizard.

Local $sData = ""

For $i = 1 To 10
    $sData &= "Line " & $i & @CRLF
Next

MsgBox(0, "Before", $sData)

Local $iLine = 5, $fOverwrite = True

$sData = StringRegExpReplace($sData, "((?:.*?\R){" & ($iLine - 1) & "})(.*?\R)", "${1}" & ($fOverwrite ? "" : "${2}") & "New Line 5" & @CRLF, 1)

MsgBox(0, "After", $sData)

[guinness]

Can't you write some regexp to insert lines? Looping through the whole array doesn't seem too efficient.

Forum community has some very good regexp freaks, maybe they could help.

 

 

You don't need to be a regex wizard.

Local $sData = ""

For $i = 1 To 10
    $sData &= "Line " & $i & @CRLF
Next

MsgBox(0, "Before", $sData)

Local $iLine = 5, $fOverwrite = True

$sData = StringRegExpReplace($sData, "((?:.*?\R){" & ($iLine - 1) & "})(.*?\R)", "${1}" & ($fOverwrite ? "" : "${2}") & "New Line 5" & @CRLF, 1)

MsgBox(0, "After", $sData)

I dunno why I didn't think of that, I changed to regular expression for counting lines as well as _FileReadToArray(). 

[Mat]

Only problem is that the replacement text can't include "1" or anything that would normally refer to a matched group. Any ideas?

[guinness]

Mat, 

This is correct...

$sData = StringRegExpReplace($sData, "((?:.*?\R){" & ($iLine - 1) & "})(.*?\R)", "${1}" & (($fOverwrite And $sText = "") ? "": (($fOverwrite ? "" : "${2}") & $sText & @CRLF)), 1)

[guinness]

Only problem is that the replacement text can't include "1" or anything that would normally refer to a matched group. Any ideas?

$sText = StringReplace($sText, "", "") ; Escape backslashes.

[guinness]

Now similar to the functionality of _FileWriteToLine() where an empty string and overwrite set to True will delete the line.

Local $sData = ""

For $i = 1 To 10
    $sData &= "Line " & $i & @CRLF
Next

MsgBox(4096, "Before", $sData)

Local $iLine = 5, $fOverwrite = True
Local $sText = "\1"

$sText = StringReplace($sText, "\", "\\")
$sData = StringRegExpReplace($sData, "((?:.*?\R){" & ($iLine - 1) & "})(.*?\R)", "${1}" & (($fOverwrite And $sText = "") ? "" : (($fOverwrite ? "" : "${2}") & $sText & @CRLF)), 1)

MsgBox(4096, "After", $sData)

[Mat]

Dollar sign matched group references need to be escaped as well:

$sText = StringReplace($sText, "$", "\$")

[trancexx]

Be careful not to hit some regexp internal limit with that pattern. Check max value for quantfier you use.

[Mat]

According to man pcrelimit, the maximum value for a repeating quantifier is 65536. If we think we are going to hit that limit, then it's a bit of extra code to match a group of 65536 lines and then another group to match some more.

I've worked with CSV files larger than that, so it is conceivable. 

Edit: Something like:

Func _WriteToLine($sData, $iLine, $sText, $fOverwrite = 0)

    ; Escape matched group references in replacement text
    $sText = StringReplace($sText, "\", "\\")
    $sText = StringReplace($sText, "$", "\$")

    $iLine -= 1

    Local $sPattern = "("

    While $iLine > 65536
        $iLine -= 65536
        $sPattern &= "(?:.*?\R){65536}"
    WEnd

    If $iLine Then $sPattern &= "(?:.*?\R){" & $iLine & "}"

    $sPattern &= ")(.*?\R)"

    $sData = StringRegExpReplace($sData, $sPattern, "${1}" & (($fOverwrite And $sText = "") ? "" : (($fOverwrite ? "" : "${2}") & $sText & @CRLF)), 1)

    Return $sData
EndFunc   ;==>_WriteToLine

Edited January 8, 2014 by Mat

[guinness]

If people could test Mat's function then we can continue looking at adding it to the UDFs. Thanks.

[jaberwacky]

This is what I got:

expandcollapse popup

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100

When I ran this:

#include <FileConstants.au3>

Local $hFileOpen = FileOpen('Test.txt', $FO_OVERWRITE)
For $i = 1 To 100
    FileWriteLine($hFileOpen, $i)
Next
FileClose($hFileOpen)
_WriteToLine('Test.txt', 10, 'Line_10', 1)
ConsoleWrite(@error & @CRLF)

Func _WriteToLine($sData, $iLine, $sText, $fOverwrite = 0)
    ; Escape matched group references in replacement text
    $sText = StringReplace($sText, "\", "\\")
    $sText = StringReplace($sText, "$", "\$")

    $iLine -= 1

    Local $sPattern = "("

    While $iLine > 65536
        $iLine -= 65536
        $sPattern &= "(?:.*?\R){65536}"
    WEnd

    If $iLine Then $sPattern &= "(?:.*?\R){" & $iLine & "}"

    $sPattern &= ")(.*?\R)"

    $sData = StringRegExpReplace($sData, $sPattern, "${1}" & (($fOverwrite And $sText = "") ? "" : (($fOverwrite ? "" : "${2}") & $sText & @CRLF)), 1)

    Return $sData
EndFunc   ;==>_WriteToLine

[guinness]

jaberwocky6669,

Mat's function isn't complete, here try this..

#include <FileConstants.au3>

Local $hFileOpen = FileOpen('Test.txt', $FO_OVERWRITE)
For $i = 1 To 100
    FileWriteLine($hFileOpen, $i)
Next
FileClose($hFileOpen)
Local $sData = FileRead('Test.txt')
$sData = _WriteToLine($sData, 10, 'Line_10', 1)
ConsoleWrite(@error & @CRLF)
ConsoleWrite($sData & @CRLF)