Data type of new empty variables

[wraithdu]

I got caught by this today. Do you consider it a bug? I would expect a new, empty, unassigned variable to take on the type of the first assigned data, in this case binary. Tested AutoIt versions 3.3.9.25 beta.

Local $a
$a &= Binary("0x1234")
$a &= Binary("0x5678")
ConsoleWrite(VarGetType($a) & " : " & $a & @CRLF)
;; output -> String : 0x12340x5678
;; expected output -> Binary : 0x12345678

Local $b = Binary("")
$b &= Binary("0x1234")
$b &= Binary("0x5678")
ConsoleWrite(VarGetType($b) & " : " & $b & @CRLF)
;; output -> Binary : 0x12345678

Edited December 21, 2013 by wraithdu

[guinness]

It's the same in the stable, though I wouldn't say it's a bug as you're appending binary data to a variable not initialised and by default it's always a string data type.

Local $sVar
ConsoleWrite(VarGetType($sVar) & @CRLF)

Edited December 20, 2013 by guinness

[czardas]

I thought that &= was a string operator - converting the result to a string regardless. 0x12340x5678 is not what you should expect to get here though (I don't think). I would say bug. This is what I would expect ==>

MsgBox(0, "", Binary("0x1234") & Binary("0x5678")) ; 0x12345678

Edited December 20, 2013 by czardas

[guinness]

But you're not converting the initialisation. No bug.

Local $a = Binary('')
$a &= Binary("0x1234")
$a &= Binary("0x5678")
ConsoleWrite(VarGetType($a) & " : " & $a & @CRLF)

[guinness]

I thought that &= was a string operator - converting the result to a string regardless. 0x12340x5678 is not what you should expect to get here though (I don't think). I would say bug. This is what I would expect ==>

MsgBox(0, "", Binary("0x1234") & Binary("0x5678")) ; 0x12345678

But  the initial variable is a string, so you're appending binary data to a string.

 

I expect this...

$vVar = "" & Binary("0x1234") & Binary("0x5678")
MsgBox(0, "", VarGetType($vVar)) ; 0x12345678

Which is why when I said the other day initialise variables with the datatype you expect it to hold as being a good thing to do. This is a prime example of just that. Edited December 20, 2013 by guinness

[czardas]

Hmm strange. How come numbers are converted but binary data remains the same variable type?

Local $a = 1
$a &= 2
$a &= 3
ConsoleWrite(VarGetType($a) & " : " & $a & @CRLF)

Edited December 20, 2013 by czardas

[guinness]

Not strange, because you initialised with a number. Here try this as it's what wraithdu presented.

Local $a
$a &= 2
$a &= 3
ConsoleWrite(VarGetType($a) & " : " & $a & @CRLF)

[czardas]

 

Not strange, because you initialised with a number. Here try this as it's what wraithdu presented.

Local $a
$a &= 2
$a &= 3
ConsoleWrite(VarGetType($a) & " : " & $a & @CRLF)

This still comes out as a string. I find it hard to understand. Binary data sometimes remains as binary, but numbers are always converted to a string (initialized or not). Why?

Edited December 20, 2013 by czardas

[guinness]

Because an uninitialised variable is always a string datatype. What would you expect this datatype to be?

Local $a = '1'
$a &= 2
$a &= 3
ConsoleWrite(VarGetType($a) & " : " & $a & @CRLF)

String

[UEZ]

Binary data sometimes remains as binary, but numbers are always converted to a string (initialized or not). Why?

 

Local $b = Binary("") initializes the variable to a binary type and not to a string and that's the reason why it works.

Br,

UEZ

[czardas]

Because an uninitialised variable is always a string datatype. What would you expect this datatype to be?

 

Okay this is new information, but if I initialize a number it gets converted to a string anyway. What is confusing me is why the &= operator treats diferent pre-initialized data types differently. Converting numbers, but not converting binary.

Local $a = Number("")
$a &= 2
ConsoleWrite(VarGetType($a) & " : " & $a & @CRLF)

Edited December 20, 2013 by czardas

[guinness]

That I can see as being confusing for some people.

But binary and strings are the only two I can think of where you would need to "join" together.

Edited December 20, 2013 by guinness

[czardas]

I guess the reason might be that numeric concatenation would be limited to 15 digits if it were not converted to string data. Therefore I can see it as perhaps being a general solution to cover all bases. Confusing nonetheless.

Edited December 21, 2013 by czardas

[wraithdu]

I've only ever used &= for binary and string data. It would make no sense for numbers, where +=, -=, *= etc are the proper operators.

Local $a
MsgBox(0, "", VarGetType($a))
$a += 1
$a += 2
MsgBox(0, "", VarGetType($a) & " : " & $a)

I understand why the binary / string thing gets messed up, it's just not what I would expect. I would expect it to go all stringy if I was concatenating numbers.

[czardas]

Well concatenating numbers is quite a valid proceedure for some types of arithmetic. Multiply something by 10 in your head. Most people will add a zero on the right. This is just a simple example of numeric concatenation. I can't give a whole load of examples, but I know it is acceptable to do things like this.

Edited December 21, 2013 by czardas

[UEZ]

I assume it changes the type regarding on the last operation and its type.

Local $a
ConsoleWrite(VarGetType($a) & @LF)
$a &= 1.5
$a += 3.0
$a &= 0.0 ;if you comment this line out you will see it is double and not a string
ConsoleWrite(VarGetType($a) & " : " & $a & @LF)

Br,

UEZ

Edited December 21, 2013 by UEZ

[trancexx]

Binary concatenation is undocumented feature. It's hard to say why is that. Probably forgotten when binary data type was added to the language.

[czardas]

I haven't concatenated binary data before, only hex strings. This will take some study,

Edited December 21, 2013 by czardas

[BrewManNH]

If you want to get even more confused, take the quotes off of the strings that are being converted to binary and check the results.

[AZJIO]

I considered that any concatenation of data is string. Binary data as a string can not be merged because obtain 0x120x13

Here is another unusual example:

Local $a = 4e-008
$a &= 3e-5
$a &= 1.1e-5
MsgBox(0, VarGetType($a), $a) ; 4e-0083e-0051.1e-005

Local $a = 1e3
$a &= 2e3
$a &= 3e3
MsgBox(0, VarGetType($a), $a) ; 100020003000

Local $a = 0x1A34
$a &= 0x56F8
$a &= 0x5D78
MsgBox(0, VarGetType($a), $a) ; 67082226423928

.

Edited December 21, 2013 by AZJIO