ListViewItem not selected

[Reinhardt1julian]

I have 2 listviews and two buttons to move the items from one list to the other (One ">>" button and one "<<"). Now, when I select an item and press the >> button (The left listview1 is full while the right listview2 is empty) it puts this item into the other list. Now it seems like no item on the left list is selected, but when I press the >> button again, it copys the item that was below the item I moved over to the other list. (Now this item is on both lists) I can repeat that, so the item is on hte right list multiple times. Why? And how can I stop that?

Here's the code I am using:

$selectedwah = _GUICtrlListView_GetItemTextString($List1wah, _GUICtrlListView_GetSelectionMark($List1wah))
If $selectedwah = "|" OR $selectedwah = "||" Then
Else
    MsgBox(0,"",$selectedwah)
    GUICtrlCreateListViewItem($selectedwah, $List2wah)
    _GUICtrlListView_DeleteItemsSelected($List1wah)
    $aSorting = False
    _GUICtrlListView_SimpleSort($List2wah, $aSorting, 0)
    $selMessd = _GUICtrlListView_GetItemCount($List2wah)
    GUICtrlSetData($Label3wah, $selMessd & " Messdiener")
EndIf

[BrewManNH]

Please post a working example of the problem, it's hard to figure out what is happening with such a small snippet of the script. By working example I mean one that can be run as is that demonstrates the issue you're having.

[Reinhardt1julian]

Please post a working example of the problem, it's hard to figure out what is happening with such a small snippet of the script. By working example I mean one that can be run as is that demonstrates the issue you're having.

 

Sure thing, here you go:

expandcollapse popup

#include <ListViewConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiListView.au3>
    #include <WindowsConstants.au3>
    $Form5wah = GUICreate("Test", 674, 469, -1, -1)
    $List1wah = GUICtrlCreateListView("Name|Surename|", 8, 32, 353, 383, -1, BitOR($WS_EX_ACCEPTFILES,$LVS_EX_FULLROWSELECT))
    $List2wah = GUICtrlCreateListView("Name|Surename", 448, 32, 217, 357, -1, $WS_EX_ACCEPTFILES + $LVS_EX_FULLROWSELECT)
    $Button3wah = GUICtrlCreateButton(">>", 368, 184, 75, 25)
    $Button4wah = GUICtrlCreateButton("<<", 368, 232, 75, 25)
    GUISetState(@SW_SHOW)
    GUICtrlCreateListViewItem("Peter|Parker", $List1wah)
    GUICtrlCreateListViewItem("Louis|Smith", $List1wah)
    GUICtrlCreateListViewItem("Christian|Grey", $List1wah)
    GUICtrlCreateListViewItem("John|Williams", $List1wah)
    While 1
        $msg = GUIGetMsg()
        Switch $msg
            Case $GUI_EVENT_CLOSE
                GUIDelete($Form5wah)
                ExitLoop
            Case $Button3wah
                $selMessd2 = _GUICtrlListView_GetItemCount($List1wah)
                If $selMessd2 = 0 Then
                    MsgBox(0, "Error", "Nothing here")
                Else
                    $selectedwah = _GUICtrlListView_GetItemTextString($List1wah, _GUICtrlListView_GetSelectionMark($List1wah))
                    If $selectedwah = "|" OR $selectedwah = "||" Then
                    Else
                        GUICtrlCreateListViewItem($selectedwah, $List2wah)
                        _GUICtrlListView_DeleteItemsSelected($List1wah)
                        $aSorting = False
                        _GUICtrlListView_SimpleSort($List2wah, $aSorting, 0)
                    EndIf
                EndIf
            Case $Button4wah
                $selMessd2 = _GUICtrlListView_GetItemCount($List2wah)
                If $selMessd2 = 0 Then
                    MsgBox(0, "Error", "Nothing here")
                Else
                    $selMessd = _GUICtrlListView_GetItemCount($List2wah)
                    $selectedwah = _GUICtrlListView_GetItemTextString($List2wah, _GUICtrlListView_GetSelectionMark($List2wah))
                    If $selectedwah = "|" OR $selectedwah = "||" Then
                    Else
                        GUICtrlCreateListViewItem($selectedwah, $List1wah)
                        _GUICtrlListView_DeleteItemsSelected($List2wah)
                        $aSorting = False
                        _GUICtrlListView_SimpleSort($List1wah, $aSorting, 0)
                        _GUICtrlListView_SimpleSort($List2wah, $aSorting, 0)
                    EndIf
                EndIf
            EndSwitch
    WEnd

[Melba23]

Reinhardt1julian ,

Just check to see if there is anything selected before doing anything at all:

Case $Button3wah
    If _GUICtrlListView_GetSelectedIndices($List1wah) Then ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        $selMessd2 = _GUICtrlListView_GetItemCount($List1wah)
        If $selMessd2 = 0 Then
            MsgBox(0, "Error", "Nothing here")
        Else
            $selectedwah = _GUICtrlListView_GetItemTextString($List1wah, _GUICtrlListView_GetSelectionMark($List1wah))
            If $selectedwah = "|" Or $selectedwah = "||" Then
            Else
                GUICtrlCreateListViewItem($selectedwah, $List2wah)
                _GUICtrlListView_DeleteItemsSelected($List1wah)
                $aSorting = False
                _GUICtrlListView_SimpleSort($List2wah, $aSorting, 0)
            EndIf
        EndIf
    EndIf

That works for me.

M23

[Reinhardt1julian]

Thanks, that worked!