Read XML file and replace value

[Mecano]

Hallo AutoIt lovers,

After searching this forum and reading several messages,
I composed the following code but is this good?
(it works but I want some approval from experts.)
 

_shortcut()

Func _shortcut()
    Local $OutlookSettings = @AppDataDir & "\Microsoft\Outlook\Outlook.xml"
    If FileExists($OutlookSettings) Then
        Local $Readonly = StringInStr(FileGetAttrib($OutlookSettings), "R")
        Local $File = FileOpen($OutlookSettings, 0)
        If $File <> -1 Then
            Local $OutlookXML = FileRead($File)
            FileClose($File)
            If StringRegExp($OutlookXML, "(?i)<shortcutInit>0</shortcutInit>") Then
                $OutlookXML = StringReplace($OutlookXML, '<shortcutInit>0</shortcutInit>', _
                        '<shortcutInit>1</shortcutInit>')
                If $Readonly Then FileSetAttrib($OutlookSettings, "-R")
                Local $hFile = FileOpen($OutlookSettings, 130) ; Open file for writing in unicode UTF8 mode
                FileWrite($hFile, $OutlookXML)
                FileClose($hFile)
                If $Readonly Then FileSetAttrib($OutlookSettings, "+R") ; keep readonly
            EndIf
        EndIf
    Else
        MsgBox(48, "Outlook.xml", "Outlook.xml not found!", 3)
        Exit
    EndIf
EndFunc   ;==>_shortcut

part of Outlook.xml :

<?xml version="1.0"?>
<wundbar>
    <version>124518</version>
    <mailInit>1</mailInit>
    <shortcutInit>1</shortcutInit>
    <initMail>1</initMail>
    <initShortcuts>1</initShortcuts>
    <dataversion>1202</dataversion>
    <stores>

Thanks in advance

Edited December 1, 2013 by Mecano

[karlkar]

As long as you do not have multiple entities with the same parameter and value then this code is fine. However if you will have to parse more complex XMLs I'd suggest using XML UDF, that you can find here: '?do=embed' frameborder='0' data-embedContent>>

[Mecano]

Thanks for the answer and pointing to XML UDF,
 
My concern was about StringRegExp ( pattern pcrepattern ) and   FileOpen($OutlookSettings, 130) ; Open file for writing in unicode UTF8 mode

[Mecano]

One other question, if I want to remove the line <shortcutInit>0</shortcutInit> or <shortcutInit>1</shortcutInit> whats the correct pattern?
 
This will leave a empty line

  If StringRegExp($OutlookXML, "(?i)<shortcutInit>0</shortcutInit>") Then
                $OutlookXML = StringReplace($OutlookXML, '<shortcutInit>0</shortcutInit>', '')

[mikell]

$OutlookXML = StringRegExpReplace($OutlookXML, '.*<shortcutInit>\d</shortcutInit>.*\R', "")

You have to remove also the leading/trailing space(s) and the newline sequence 

Edited April 13, 2015 by mikell

[jdelaney]

XML dom will be soooo much easier.  You can always brute force a regexp to work, but why do that when there are com objects specifically for your question?

Example

 

Edited April 14, 2015 by jdelaney

[Mecano]

@jdelaney thanx, but see mine openings question.

@mikell excellent solution, works perfect

never thought of StringRegExpReplace

For non-digits can i use this, example: <textversion>False</textversion>

$OutlookXML = StringRegExpReplace($OutlookXML, '.*<textversion>(.*)</textversion>.*\R', "")

Edited April 14, 2015 by Mecano

[jdelaney]

Hallo AutoIt lovers,

After searching this forum and reading several messages,

I composed the following code but is this good?

 

I would suggest this is not a 'good' route, and you should use a tool that's more suited for it.

I would also suggest, that this is a much better route:

Local $oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.load("test.xml")
$oShortcutInit = $oXML.SelectSingleNode("//shortcutInit")
$oShortcutInit.text = Int($oShortcutInit.text) + 1
$oXML.save("test.xml")

Edited April 14, 2015 by jdelaney

[Mecano]

@jdelaney, gonna give it a try, time to learn AutoIt/Microsoft.XMLDOM

Thanks for reply