ListView - Add items in a loop

[Hawkysoft]

So since I'm playing with listview now I been trying this

Func Test()
    Local $LF_Count = 1
    Do
        Eval("ïtem" & $LF_Count) = GUICtrlCreateListViewItem("item" & $LF_Count & "|Testing", $listview)
        $LF_Count = $LF_Count + 1
    Until $LF_Count > 9
    $item5 =  GUICtrlCreateListViewItem("erhmz" & $LF_Count & "|testing", $listview)
    ;$item1 = GUICtrlCreateListViewItem("item1|test", $listview)
EndFunc

As you probably see it will error out on the Eval line, however I tried this as well

Func Test()
    Local $LF_Count = 1
    Do
                Local $LF_Input = Eval("ïtem" & $LF_Count) 
                $LF_Input = GUICtrlCreateListViewItem("item" & $LF_Count & "|" & $LF_Input, $listview)
        $LF_Count = $LF_Count + 1
    Until $LF_Count > 9
    $item5 =  GUICtrlCreateListViewItem("erhmz" & $LF_Count & "|testing", $listview)
    ;$item1 = GUICtrlCreateListViewItem("item1|test", $listview)
EndFunc

I added the line $item5 to see if it actually got named like that, however it seems it's not? is there any method to do this on a proper way?

I know I could just create item1 till item9 in a row, however I like it a little bit more clean

Anyone knows?

Edited November 26, 2013 by Hawkysoft

[Xenobiologist]

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $listview, $button, $item1, $item2, $item3, $msg

    GUICreate("listview items", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    GUISetBkColor(0x00E0FFFF) ; will change background color

    $listview = GUICtrlCreateListView("col1 |col2", 10, 10, 200, 150);,$LVS_SORTDESCENDING)
    $button = GUICtrlCreateButton("Value?", 75, 170, 70, 20)
;~  $item1 = GUICtrlCreateListViewItem("item2|col22|col23", $listview)

    GUISetState()

    $count = Random(1, 10, 1)
    Local $Lv[$count+1]

    For $i = 0 To $count -1
        $Lv[$i] = GUICtrlCreateListViewItem($i & '|' & @UserName , $listview)
    Next

    Do
        $msg = GUIGetMsg()

        Select
            Case $msg = $button
                MsgBox(0, "listview item", GUICtrlRead(GUICtrlRead($listview)), 2)
            Case $msg = $listview
                MsgBox(0, "listview", "clicked=" & GUICtrlGetState($listview), 2)
        EndSelect
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

[mikell]

I suppose you were trying to do something like this

GUICreate("listview items", 220, 250, 100, 200)
$listview = GUICtrlCreateListView("col1 |col2", 10, 10, 200, 150)
GUISetState()

For $i = 0 To 9
    Assign("item" & $i, GUICtrlCreateListViewItem($i & '|' & @UserName , $listview) )
Next

Msgbox(0,"", GUICtrlRead($item5))
Msgbox(0,"", GUICtrlRead(Eval("item6")))

But  Xenobiologist's solution using an array is by far a much better one 

[Hawkysoft]

I suppose you were trying to do something like this

GUICreate("listview items", 220, 250, 100, 200)
$listview = GUICtrlCreateListView("col1 |col2", 10, 10, 200, 150)
GUISetState()

For $i = 0 To 9
    Assign("item" & $i, GUICtrlCreateListViewItem($i & '|' & @UserName , $listview) )
Next

Msgbox(0,"", GUICtrlRead($item5))
Msgbox(0,"", GUICtrlRead(Eval("item6")))

But  Xenobiologist's solution using an array is by far a much better one 

 

Hmm still doesn't work for some reason when I try to replace a line/value

Func Test()
    For $i = 1 To 9
        Assign("item" & $i, GUICtrlCreateListViewItem("item" & $i & "|Testing", $listview))
    Next
    $item5 =  GUICtrlCreateListViewItem("erhmz|testing", $listview)
EndFunc

when $item5 get's added it just adds another line on the bottom instead of updating $item5 so it seems that there isn't an actual $item5 called at the assign part?

[kylomas]

HawkySoft,

when $item5 get's added it just adds another line on the bottom instead of updating $item5 so it seems that there isn't an actual $item5 called at the assign part?

 

If you are trying to change an existing item use _GUICtrlListView_SetItemText.

edit: Also, use an array as shown in Xeno's example.  It will save you headaches later.

Edited November 27, 2013 by kylomas

[Hawkysoft]

HawkySoft,

 

If you are trying to change an existing item use _GUICtrlListView_SetItemText.

edit: Also, use an array as shown in Xeno's example.  It will save you headaches later.

Epic failure, thanks mate and you again as well mikell

Edited November 27, 2013 by Hawkysoft