Fetching run time menu item text

[Automationuser]

Hi All,

I want to fetch the run time menu item text.

1. I have to right click on a list view item.

2. A pop-up menu with 4 items appears and I have to fetch the text of the menu.

Is there any way to perform step 2 using autoit.

Any help will be appreciated.

Thanks in advance.

[Melba23]

Automationuser,

Run this code and use the "^r" HotKey once the pop-up menu is visible.

expandcollapse popup

#include <Array.au3>
#include <WinAPI.au3>
#include <GUIMenu.au3>
#include <WindowsConstants.au3>

HotKeySet("^r", "_Read")

HotKeySet("{ESC}", "On_Exit")

While 1
    Sleep(10)
WEnd


Func On_Exit()
    Exit
EndFunc

Func _Read()

    ; Run this once the popup menu has appeared
    $aPopUp_Text = GetPopUpText()
    If $aPopUp_Text[0] = 0 Then
        MsgBox(16, "Error", "Non-standard Pop-up Menu")
    Else
        _ArrayDisplay($aPopUp_Text)
    EndIf

EndFunc

Func GetPopUpText()

    Local $aPopUp_List = _WinAPI_EnumWindowsPopup()
    Local $hWnd = $aPopUp_List[1][0]
    Local $sClass = $aPopUp_List[1][1]
    If $sClass = "#32768" Then
        $hMenu = _SendMessage($hWnd, $MN_GETHMENU, 0, 0)
        If _GUICtrlMenu_IsMenu($hMenu) Then
            $iCount = _GUICtrlMenu_GetItemCount($hMenu)
            Local $aPopUp_Text[1] = [0]
            For $j = 0 To $iCount - 1
                If Not _GUICtrlMenu_GetItemType($hMenu, $j, True) = $MFT_SEPARATOR Then
                    $aPopUp_Text[0] += 1
                    ReDim $aPopUp_Text[$aPopUp_Text[0] + 1]
                    $aPopUp_Text[$aPopUp_Text[0]] = _GUICtrlMenu_GetItemText($hMenu, $j)
                EndIf
            Next
        EndIf
    EndIf

    Return $aPopUp_Text

EndFunc

It works for standard Windows menus, but not for ownerdrawn ones - so keep your fingers crossed.

M23

[Automationuser]

@Melba23 : Thank you very much..that worked perfectly..

Learnt some new things today.

[Melba23]

Automationuser,

Thank rover - most of the code was his, I just made it into a function.

M23