NewSciTE - Timesaver - Saves Copied Text as NewScript

[l3ill]

Hi All,
 
  Another little script that has saved me lots of time and clicks.
Needs to be complied and tied to a G-Key (additional Function key) or updated to work w/ a HotKey
 
Highlight any text from the Forum or another SciTE window, hit the key and Voila!
 
...I assume most of you have this already in some form, you are welcome to post them here so we can all learn from them. 
 
Bill
 
Edit: Title should say - Saves Highlighted text as New Script - Script Copies to clipboard as first step
 
16.12.2013
Edit: Updated _SciTE_Send_Command with the one from guinness SciTE Jump 
        Needs WM_COPYDATA.au3 
        All you need is in ZIP file
17.12.2013
Edit: Personal Feature Request - Will now start SciTE if it isn't already open.
 

Source Code:

expandcollapse popup

#include <Constants.au3>
#include <Clipboard.au3>
#include "WM_COPYDATA.au3"
Local $iBatch = String(@HOUR & @MIN & @SEC)
Local $sFilePath = (@DesktopDir & "\" & $iBatch)
Send("^c")
$sString = _ClipBoard_GetData($CF_TEXT)

$hWndSC = WinGetHandle("DirectorExtension")
If @error = 1 Then
    ShellExecute("SciTE.exe")
    Sleep(500)
    $hWndSC = WinGetHandle("DirectorExtension")
    EndIf
_SciTE_Send_Command(0, $hWndSC, 'open:')

WinActivate($hWndSC)
WinWaitActive($hWndSC)
_SciTE_InsertText($sString)  ;Copied text that is new script

Send("^s")
WinWaitActive("Save File")
Send($sFilePath)   ; Individual Name for new SciTE file
Send("!s")

Func _SciTE_InsertText($sString)
    $sString = StringReplace($sString, '\', '\\')
    _SciTE_ReplaceMarcos($sString)
    Return _SciTE_Send_Command(0, WinGetHandle('DirectorExtension'), 'insert:' & $sString)
EndFunc   ;==>_SciTE_InsertText

Func _SciTE_ReplaceMarcos(ByRef $sString)
    $sString = StringReplace($sString, @TAB, '\t')
    $sString = StringReplace($sString, @CR, '\r')
    $sString = StringReplace($sString, @LF, '\n')
EndFunc   ;==>_SciTE_ReplaceMarcos

Func _SciTE_Send_Command($hWnd, $hSciTE, $sString)
    If StringStripWS($sString, $STR_STRIPALL) = '' Then
        Return SetError(2, 0, 0) ; String is blank.
    EndIf
    $sString = ':' & Dec(StringTrimLeft($hWnd, 2)) & ':' & $sString
    Local $tData = DllStructCreate('char[' & StringLen($sString) + 1 & ']') ; wchar
    DllStructSetData($tData, 1, $sString)

    Local Const $tagCOPYDATASTRUCT = 'ptr;dword;ptr' ; ';ulong_ptr;dword;ptr'
    Local $tCOPYDATASTRUCT = DllStructCreate($tagCOPYDATASTRUCT)
    DllStructSetData($tCOPYDATASTRUCT, 1, 1)
    DllStructSetData($tCOPYDATASTRUCT, 2, DllStructGetSize($tData))
    DllStructSetData($tCOPYDATASTRUCT, 3, DllStructGetPtr($tData))
    _SendMessage($hSciTE, $WM_COPYDATA, $hWnd, DllStructGetPtr($tCOPYDATASTRUCT))
    Return Number(Not @error)
EndFunc   ;==>_SciTE_Send_Command

Some Animated GIFS showing how it works

NewSciTEScript_2.0.zip
 
NewSciTEScript_2.0.1.zip  update 16.12.2013
 
NewSciTEScript_2.0.1.zip  update 17.12.2013

Edited December 26, 2013 by l3ill

[Jos]

I would use the SciTE director interface to get the copied script into SciTE to avoid any conflict with the user trying to do something.

Examples are plenty in the Examples forum.

Jos

[l3ill]

Updated: Thanks Jos, guinness.

Zip file includes working exe and WM_COPYDATA.au3 needed to run au3 script.

Tip: this works with any text you can copy Web, Helpfile, Word Doc...etc

[guinness]

Func _SciTE_Send_Command($hWnd, $hSciTE, $sString)
    If StringStripWS($sString, $STR_STRIPALL) = '' Then
        Return SetError(2, 0, 0) ; String is blank.
    EndIf
    $sString = ':' & Dec(StringTrimLeft($hWnd, 2)) & ':' & $sString
    Local $tData = DllStructCreate('char[' & StringLen($sString) + 1 & ']') ; wchar
    DllStructSetData($tData, 1, $sString)

    Local Const $tagCOPYDATASTRUCT = 'ptr;dword;ptr' ; ';ulong_ptr;dword;ptr'
    Local $tCOPYDATASTRUCT = DllStructCreate($tagCOPYDATASTRUCT)
    DllStructSetData($tCOPYDATASTRUCT, 1, 1)
    DllStructSetData($tCOPYDATASTRUCT, 2, DllStructGetSize($tData))
    DllStructSetData($tCOPYDATASTRUCT, 3, DllStructGetPtr($tData))
    _SendMessage($hSciTE, $WM_COPYDATA, $hWnd, DllStructGetPtr($tCOPYDATASTRUCT))
    Return Number(Not @error)
EndFunc   ;==>_SciTE_Send_Command

Updated version of...