Request for mentoring on SRE

[DxMxS]

Hello Guys,

I recently discovered PCRE thanks to AutoIt.

Yesterday a couple fellows from this board taught me how to find a specific string, keep it and get rid of the rest of the content in an edit control.

Local $fwlID = StringRegExpReplace($eContent, '(?s).*?((FWLd*)|$)', '$2' & @crlf)

 

(In this case the strings I wanted to keep start with FWL followed by numbers).

Today I have a new challenge, there are duplicate FWL codes. I want to keep one ocurrence of each code and get rid of all duplicates.

I have done some research on the web and this forum but have not been able to find a solution.

Can someone please assist me and explain his/her proposed regEx for our future reference?

Thanks in advance!

[Melba23]

DxMxS,

No need for a RegEx. Get the values into an array as I did in the code I posted and use _ArrayUnique to remove duplicates.

M23

[DxMxS]

Thanks Melba, I will definitely give that approach a try. However, I still would like to learn how to get the task done using a RegEx 

[Melba23]

DxMxS,

Beware of the facination of RegExes. As GEOSoft (who introduced me to them several years ago) used to say - one of the things you need to learn is when NOT to use them. RegExes are, by definition, used to to detect regularly occuring patterns in data - they are not designed to be a complete toolbox. In this case finding all lines that start "FWL" is exactly what they are meant for - detecting duplicates is another thing altogether.

That said, one of the RegEx gurus will no doubt come along and post a solution in a minute!

M23

[DxMxS]

Thanks Melba,

It is really good for me and my coding to learn in which scenarios a given approach is optimal and in which it is not.

I appreciate your comment.

[mikell]

DxMxS,
The regex Melba posted meant "find all matches" , the regexreplace I wrote meant "fire all but matches" , in both cases the approach is similar
Maybe what you want is possible using regex, but this looks like a headache to come while the simplest way is usually the best one
In this case Melba's solution does the job perfectly

#include <Array.au3>

$array = StringRegExp($text, 'FWL\d*', 3)
$new_array = _ArrayUnique($array)

Edit

Nonetheless ...

#include <GUIConstantsEx.au3>

$sText = "xxxxxxxxxxxxxxxxxxxxxxxxxxxx" & @CRLF & _
        "FWL12345" & @CRLF & _
        "FWL9875632" & @CRLF & _
        "yyyyyyyyyyyyyyyyyyyyyyyyyyyy" & @CRLF & _
        "FWL12345" & @CRLF & _
        "zzzzzzzzzzzzzzzzzzzzzzzzzzzz" & @CRLF & _
        "" & @CRLF & _
        "" & @CRLF & _
        "FWL45678965" & @CRLF & _
        "FWL12345" & @CRLF & _
        "FWL985612565" & @CRLF & _
        "bbbbbbbbbbbbbbbbbbbbbbbbb"

$hGUI = GUICreate("Test", 500, 500)
$cEdit = GUICtrlCreateEdit($sText, 10, 10, 480, 400)
$cButton = GUICtrlCreateButton("Filter", 10, 450, 80, 30)
GUICtrlSetState($cButton, $GUI_FOCUS)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            Filter()
    EndSwitch
WEnd

Func Filter()
    $ret = StringStripWS(StringRegExpReplace(GuiCtrlRead($cEdit), '(?s).*?((FWL\d*)(?!.*\2.*)|$)', '$2' & @crlf), 3)
    GuiCtrlSetData($cEdit, $ret)
EndFunc

Edited November 13, 2013 by mikell

[DxMxS]

Understood. Thank you guys 

[mikell]

Sorry I forgot the explanation in my edit for the regex to remove duplicates

(?!.*2.*)  is a negative lookahead which means : "if the rest of the string doesn't contain the backreference #2 (that to say : the part matched)"
So the one retained among the duplicates will be the last one found

Edited November 13, 2013 by mikell

[AZJIO]

http://autoit-script.ru/index.php/topic,4861.msg35295.html#msg35295
 

#include <GUIConstantsEx.au3>
#include <Array.au3>

$sText = "xxxxxxxxxxxxxxxxxxxxxxxxxxxx" & @CRLF & _
        "FWL12345" & @CRLF & _
        "FWL9875632" & @CRLF & _
        "yyyyyyyyyyyyyyyyyyyyyyyyyyyy" & @CRLF & _
        "FWL12345" & @CRLF & _
        "zzzzzzzzzzzzzzzzzzzzzzzzzzzz" & @CRLF & _
        "" & @CRLF & _
        "" & @CRLF & _
        "FWL45678965" & @CRLF & _
        "FWL12345" & @CRLF & _
        "FWL985612565" & @CRLF & _
        "bbbbbbbbbbbbbbbbbbbbbbbbb"

$aText = StringSplit($sText, @CRLF, 3)
_ArrayDisplay($aText, 'aText')
$aText = _ArrayRemoveDuplicates($aText)
_ArrayDisplay($aText, '_ArrayRemoveDuplicates')

Func _ArrayRemoveDuplicates(Const ByRef $aArray)
    If Not IsArray($aArray) Then Return SetError(1, 0, 0)
    Local $oDict = ObjCreate("Scripting.Dictionary")
    $oDict.CompareMode = 0 ; Flag to indicate if the operations should be case sensitive
    For $i In $aArray
        $oDict.Item($i) ; shown by wraithdu
    Next
    Return $oDict.Keys()
EndFunc   ;==>_ArrayRemoveDuplicates

Edited November 13, 2013 by AZJIO

[kylomas]

AZJIO - The 3RD parm for stringsplit should be "3" to use the whole split argument.

edit: How does the dictionary get connected to the array?

Edited November 13, 2013 by kylomas

[DxMxS]

Thank you all guys!

Mikell, I tried your code - it is awesome!. Thanks!