Disabling specific day in DatePicker

[continyu]

Hi there,

I have a kind of weird problem. 

I would like to have a "GUICtrlCreateDate" element on my gui for date selection. 

But i don't want my users to pick "Sundays". I know that i can put an error if sundays picked. But i would like to know that it could be disabled totaly? Like grayed out or sth.

Thanks in advance.

[kylomas]

continyu,

This is as close to what you want as I could get.

expandcollapse popup

#include <StaticConstants.au3>
#include <DateTimeConstants.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

#AutoIt3Wrapper_Add_Constants=n

local $gui010   =   guicreate('Date Time Example',300,300)
local $DTctl    =   GUICtrlCreateDate('',20,20,200,20)
local $status   =   guictrlcreatelabel('',20,280,260,20,$SS_SUNKEN)
                    GUICtrlSetColor(-1,0xaa0000)
                    guisetstate()

GUIRegisterMsg($WM_NOTIFY,'WM_NOTIFY')

while 1
    switch guigetmsg()
        case $GUI_EVENT_CLOSE
            Exit
        case $DTctl
            ConsoleWrite('date selected = ' & guictrlread($DTctl)  & @LF)
    EndSwitch
wend

func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMDATETIMECHANGE

    $tNMDATETIMECHANGE  = dllstructcreate($tagNMDATETIMECHANGE, $ilParam)
    $hWndFrom           = HWnd(DllStructGetData($tNMDATETIMECHANGE, "hWndFrom"))
    $iIDFrom            = DllStructGetData($tNMDATETIMECHANGE, "IDFrom")
    $iCode              = DllStructGetData($tNMDATETIMECHANGE, "Code")
    local $DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW

    switch $hWndFrom
        case guictrlgethandle($DTctl)
            switch $iCode
                case $DTN_DATETIMECHANGE
                    if dllstructgetdata($tNMDATETIMECHANGE, 'DOW') = 0 then
                        guictrlsetdata($status,'  Invalid Selection - Re-pick Date')
                        GUICtrlSendMsg($DTctl, $DTM_SETFORMAT_, 0, '  SUNDAY_INVALID - REPICK')
                    endif
                case $DTN_DROPDOWN
                    guictrlsetdata($status,'')
                    guictrlsendmsg($DTctl, $DTM_SETFORMAT_, 0, "dddd, MMMM dd, yyyy")
            EndSwitch
    EndSwitch

    return $GUI_RUNDEFMSG

endfunc

kylomas

[Melba23]

kylomas,

Very nice.

M23

[continyu]

kylomas,

thank you very much for your time,

i've implemented something like that to my script.

I was wondering that if i can disable selecting this day in calendar. Appearently i can't. IF anyone knows another solution i'm accepting that it can't be done better than this.

[Chantaro]

Hello

Sorry to open such an old thread again, but is it possible to have this date selector return that invalid date for saturdays as well? I cannot figure out how the dll stuff works and I have trouble figuring out how kylomas gets sunday out of this in the first place

[Melba23]

Chantaro,

No DLL magic required - just check for DOW being 0 or 6 like this:

Switch $hWndFrom
        Case GUICtrlGetHandle($DTctl)
            Switch $iCode
                Case $DTN_DATETIMECHANGE
                    Switch DllStructGetData($tNMDATETIMECHANGE, 'DOW')
                        Case 0, 6
                            GUICtrlSetData($status, '  Invalid Selection - Re-pick Date')
                            GUICtrlSendMsg($DTctl, $DTM_SETFORMAT_, 0, '  DAY_INVALID - REPICK')
                    EndSwitch

M23

[Chantaro]

Thanks a bunch Melba23!