Detect Shutdown/Reboot

[MadaraUchiha]

Hey,

It got asked already a couple of times, but I never found a clear solution.

So let's ask it again, well explained.

When Windows is about to Shutdown or reboot, I want AutoIt to display a message box. How can I do this?

I already did some research, and I found this:

http://msdn.microsoft.com/en-us/library/aa376889(VS.85).aspx

And these events:

• ENDSESSION_CLOSEAPP 0x1

• ENDSESSION_CRITICAL 0x40000000

• ENDSESSION_LOGOFF 0x80000000

But how to use them when one of those events occurs?

[BrewManNH]

I would assume you would use a GUIRegisterMsg function with the $WM_ENDSESSION variable and a function to point it to if your GUI receives this message.

[guinness]

Also search for WM_QUERYENDSESSION.

[MadaraUchiha]

In this case my script has no GUI. So GuIGetMsg is no option...

[guinness]

Where did you get the idea you need to use GUIGetMsg().

[MadaraUchiha]

U mean GUIRegisterMsg....

[guinness]

But you just need to create a GUI only. There is no need to monitor messages via GUIGetMsg().

[MadaraUchiha]

Is it also possible if my script has no GUI? I mean it should only detect when the system is about to reboot/shutdown and then show a messagebox...

[guinness]

No. You need to create a hidden GUI.

[MadaraUchiha]

Ok, then. How would it look like if I create the GUI and set the event to $WM_ENDSESSION ?

[MadaraUchiha]

I found this snippet:

Const $PM_NOREMOVE = 0
Const $WM_QUERYENDSESSION = 17

$handle=DllOpen("user32.dll")

Dim $dummy[200], $ret[200]

while 1
; (lpMsg As MSG, ByVal hwnd As Long, ByVal wMsgFilterMin As Long, ByVal wMsgFilterMax As Long, ByVal wRemoveMsg As Long) As Long
    $ret=DllCall($handle, "long", "PeekMessage", "ptr", $dummy, "long" , 0, "long" , $WM_QUERYENDSESSION, "long", $WM_QUERYENDSESSION, "long", $PM_NOREMOVE)
    If $ret[0] <> 0 Then
        MsgBox(64, "Bye", "Time to go..", 2)
        Exit
    EndIf
    Sleep(100)
WEnd

from here: '?do=embed' frameborder='0' data-embedContent>>

but it won't work, I got no msgbox when trying to shutdown the system while the application is running...

[DatMCEyeBall]

Like this:

#include <WindowsConstants.au3>

$hGUI = GuiCreate("") ; Create a GUI and don't show it
GuiRegisterMsg($WM_ENDSESSION, "WM_ENDSESSION")

; Do stuff here...
While 1 ; Loop does nothing
    Sleep(100)
WEnd

Func WM_ENDSESSION($hWnd, $Msg, $wParam, $lParam)
    FileWrite("Test.txt", @HOUR & ":" & @MIN & ":" & @SEC & @TAB & "WM_ENDSESSION: " & $hWnd & ", " & $Msg & ", " & $wParam & ", " & $lParam & @CRLF)
EndFunc

I haven't tested it yet. Should work, I wrote it right here in the browser.

Maybe the parameters mean something...

EDIT:

Added #include.

Edited October 29, 2013 by DatMCEyeBall

[MadaraUchiha]

Thanks for your reply, but in my case, nothing happens...

When I shutdown nothing happens, no file created?

[BrewManNH]

The script below creates a hidden GUI that when closed will trigger the msgbox in the Test function. It might work for what you're attempting to do.

#include <WindowsConstants.au3>

HotKeySet("{ESC}", "QUIT")
GUICreate("")
;~ GUISetState()
GUIRegisterMsg($WM_DESTROY, "Test")
While 1
    Sleep(100)
WEnd
Func Test()
    MsgBox(0, "", "Test")
    Sleep(100)
EndFunc   ;==>Test
Func QUIT()
    GUIDelete()
    Exit
EndFunc   ;==>QUIT

Run the script, hit ESC to exit it, you should see the Test message box show up. Then try it using when shutting down to see if a message box shows up.

[MadaraUchiha]

The script below creates a hidden GUI that when closed will trigger the msgbox in the Test function. It might work for what you're attempting to do.

#include <WindowsConstants.au3>

HotKeySet("{ESC}", "QUIT")
GUICreate("")
;~ GUISetState()
GUIRegisterMsg($WM_DESTROY, "Test")
While 1
    Sleep(100)
WEnd
Func Test()
    MsgBox(0, "", "Test")
    Sleep(100)
EndFunc   ;==>Test
Func QUIT()
    GUIDelete()
    Exit
EndFunc   ;==>QUIT

Run the script, hit ESC to exit it, you should see the Test message box show up. Then try it using when shutting down to see if a message box shows up.

The msgbox appears when I hit the ESC key, but when I try to reboot or shutdown while the app is running nothing happens?

[BrewManNH]

Try changing the MsgBox to a filewrite and see if that makes any difference. Perhaps the act of shutting down prevents the msgbox from appearing.

[MadaraUchiha]

Tried it. No sucess

[MadaraUchiha]

Anyone have an idea why this script does not work?

[BrewManNH]

Change the $WM_DESTROY to $WM_QUERYENDSESSION, you should get the MsgBox at that point.

[MadaraUchiha]

Yo, thanks. 

This works now perfectly fine:

#include <WindowsConstants.au3>

GUICreate("")
GUIRegisterMsg($WM_QUERYENDSESSION, "HandleShutdown")
While 1
    Sleep(100)
WEnd
Func HandleShutdown()
    MsgBox(64, "Shutdown", "System will now shut down.")
    GUIDelete()
    Sleep(100)
EndFunc