Is there a "shorter" way?

[MariusN]

Hi guys...Is there a shorter way of coding the following code --->

If $read1 = 4 And $read2 = 4 And $read3 = 4 And $read4 = 4 And $read5 = 4 And $read6 = 4 Then

...tia

[water]

If you have to check 4 variables you have to check 4 variables.

No shorter way I can think of.

[Melba23]

MariusN,

Depending on the possible values of the variables you might be able to use:

If ($read1 + $read2 + $read3 + $read4 + $read5 + $read6) = 24 Then

Obviously that will only work if the values are always numeric AND the value of each variable cannot be more than 4.

M23

[DatMCEyeBall]

Depending on the script $read could be an array.

Global $read[6]
; ... code to set values here
$fCondition = True
For $i = 0 to 5
    If $read[$i] <> 4 then
        $fCondition = False
        Exitloop
    EndIf
Next
If $fCondition then
    ; Code here
EndIf

Of course that's not shorter...

Edited October 12, 2013 by DatMCEyeBall

[Guest]

i also want shorter way for this:

If $TerminateKey = "OFF" Or $TerminateKey = "F1" Or $TerminateKey = "F2" Or $TerminateKey = "F3" Or $TerminateKey = "F4" Or $TerminateKey = "F5" Or $TerminateKey = "F6" Or $TerminateKey = "F8" Or $TerminateKey = "F8" Or $TerminateKey = "F9" Or $TerminateKey = "F10" Or $TerminateKey = "F11" Or $TerminateKey = "F12" Then

[DatMCEyeBall]

Global $sTerminateKeys[13] = ; Keys here
For $i = 0 To 12
    If $TerminateKey = $sTerminateKeys[$i] Then
        ; Do something
        Exitloop
    EndIf
Next

Same solution as above.

Edited October 12, 2013 by DatMCEyeBall

[Guest]

more shorter way :

this is my Function

expandcollapse popup

; Example 1
If _IfAndOr("a","a|a|a|a","and") = 1 Then ; This equal to - if a = a And a = a And a = a And a = a
    MsgBox(0,"","Condition exist")
Else
    MsgBox(0,"","Condition Not exist")
EndIf

; Example 2
If _IfAndOr("a","a|a|a|b","and") = 1 Then ; This equal to - if a = a And a = a And a = a And a = b
    MsgBox(0,"","Condition exist")
Else
    MsgBox(0,"","Condition Not exist")
EndIf

; Example 3
If _IfAndOr("a","a|b|c|d","or") = 1 Then ; This equal to - if a = a Or a = b Or a = c Or a = b
    MsgBox(0,"","Condition exist")
Else
    MsgBox(0,"","Condition Not exist")
EndIf


Func _IfAndOr($MainVariable,$Variables,$mode)
    Local $Output = 0 , $count = 0
    $var = StringSplit($Variables,"|",1)
    For $a = 1 To $var[0]
        If $mode = "or" Then
            If $MainVariable = $var[$a] Then
                $Output = 1
                ExitLoop
            EndIf
        ElseIf $mode = "and" Then
            If $MainVariable = $var[$a] Then $count = $count+1
            If $count = $var[0] Then $Output = 1
        EndIf
    Next
    Return $Output
EndFunc

[dragan]

$TerminateKey = "F10"
MsgBox(0, $TerminateKey, _IsTerminateKeyOK($TerminateKey))

$TerminateKey = "OFF"
MsgBox(0, $TerminateKey, _IsTerminateKeyOK($TerminateKey))

$TerminateKey = "F13"
MsgBox(0, $TerminateKey, _IsTerminateKeyOK($TerminateKey))

Func _IsTerminateKeyOK($trmKey)
    Switch $trmKey
        Case "OFF", "F1", "F2", "F3", "F4", "F5", "F6", "F7", "F8", "F9", "F10", "F11", "F12"
            Return True
    EndSwitch
    Return False
EndFunc

;================================================

dim $Read[7] = [0, 4, 4, 4, 4, 4, 4];$Read[1] = 4, $Read[2] = 4, $Read[3] = 4, $Read[4] = 4, $Read[5] = 4, $Read[6] = 4
MsgBox(0, 'Array equal to 4', _IsReadArrayEqualTo($Read, 4))

Func _IsReadArrayEqualTo($theArray, $theNumber)
    for $i = 1 to UBound($theArray)-1
        if $theArray[$i] <> $theNumber Then Return False
    Next
    Return True
EndFunc

[jchd]

Hi guys...Is there a shorter way of coding the following code --->

If $read1 = 4 And $read2 = 4 And $read3 = 4 And $read4 = 4 And $read5 = 4 And $read6 = 4 Then

...tia

 

If by "shorter" you mean "easier to shoot myself in the foot", then yes there are a fair number of ways.

Among them:

If $read1 & $read2 & $read3 & $read4 & $read5 & $read6 = "444444" Then

But of course there are many other ways to setup creative bugs.

[Guest]

for you:

; Example 1
Local $read1 = 4 , $read2 = 4 , $read3 = 4 , $read4 = 1 , $read5 = 4
If _IfAndOr(4,$read1&"|"&$read2&"|"&$read3&"|"&$read4&"|"&$read5,"and") = 1 Then ; This equal to - if a = a And a = a And a = a And a = a
    MsgBox(0,"","Condition exist")
Else
    MsgBox(0,"","Condition Not exist")
EndIf

; Example 2
Local $read1 = 4 , $read2 = 4 , $read3 = 4 , $read4 = 4 , $read5 = 4
If _IfAndOr(4,$read1&"|"&$read2&"|"&$read3&"|"&$read4&"|"&$read5,"and") = 1 Then ; This equal to - if a = a And a = a And a = a And a = a
    MsgBox(0,"","Condition exist")
Else
    MsgBox(0,"","Condition Not exist")
EndIf


Func _IfAndOr($MainVariable,$Variables,$mode)
    Local $Output = 0 , $count = 0
    $var = StringSplit($Variables,"|",1)
    For $a = 1 To $var[0]
        If $mode = "or" Then
            If $MainVariable = $var[$a] Then
                $Output = 1
                ExitLoop
            EndIf
        ElseIf $mode = "and" Then
            If $MainVariable = $var[$a] Then $count = $count+1
            If $count = $var[0] Then $Output = 1
        EndIf
    Next
    Return $Output
EndFunc

[junkew]

is the intention really shorter or more readable?

if $read1=4 and _
   $read2=4 and _
   $read3=4 and _
   $read4=4 and _
   $read5=4 _
Then
     consolewrite("All are four")
EndIf

for the functionkeys you just could do

$TerminateKey="F111"

if stringregexp($TerminateKey,"(OFF)|(F[0-9])",0)=1 Then
    consolewrite("We matched 1" & @CRLF)
EndIf

If stringinstr("OFF,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12", $TerminateKey) > 0 Then
    consolewrite("We matched 2" & @CRLF)
EndIf

I do not know if AutoIT can handle matrix comparison directly (for sure it will not be shorter

http://www.extremeoptimization.com/QuickStart/CSharp/MatrixVectorOperations.aspx

[junkew]

if bitor($read1,$read2,$read3,$read4,$read5,$read6)=4 Then
consolewrite("Yes its four")
endIf

[Guest]

is the intention really shorter or more readable?

if $read1=4 and _
   $read2=4 and _
   $read3=4 and _
   $read4=4 and _
   $read5=4 _
Then
     consolewrite("All are four")
EndIf

for the functionkeys you just could do

$TerminateKey="F111"

if stringregexp($TerminateKey,"(OFF)|(F[0-9])",0)=1 Then
    consolewrite("We matched 1" & @CRLF)
EndIf

If stringinstr("OFF,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12", $TerminateKey) > 0 Then
    consolewrite("We matched 2" & @CRLF)
EndIf

I do not know if AutoIT can handle matrix comparison directly (for sure it will not be shorter

http://www.extremeoptimization.com/QuickStart/CSharp/MatrixVectorOperations.aspx

 

Thank you.

But I developed myself this solution:

$TerminateKey="F6"
If _IfAndOr($TerminateKey,"OFF|F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12","or") = 1 Then
    MsgBox(0,"","Condition exist")
Else
    MsgBox(0,"","Condition Not exist")
EndIf


Func _IfAndOr($MainVariable,$Variables,$mode)
    Local $Output = 0 , $count = 0
    $var = StringSplit($Variables,"|",1)
    For $a = 1 To $var[0]
        If $mode = "or" Then
            If $MainVariable = $var[$a] Then
                $Output = 1
                ExitLoop
            EndIf
        ElseIf $mode = "and" Then
            If $MainVariable = $var[$a] Then $count = $count+1
            If $count = $var[0] Then $Output = 1
        EndIf
    Next
    Return $Output
EndFunc

It works great

Edited October 12, 2013 by Guest

[BrewManNH]

But that doesn't come close to answering the question of making a one liner shorter. Your code turned making toast in a toaster to making toast with something that Rube Goldberg would have shuddered to contemplate.

[jchd]

if bitor($read1,$read2,$read3,$read4,$read5,$read6)=4 Then
consolewrite("Yes its four")
endIf

A good example about how to shoot yourself in the foot.

Make $read1 = 4, $read2 to $read6 = 0 and you're set

[MariusN]

Ok thx guys...i came to the conclusion the one i used IS the shortest way, lol

Thx for all the replies and help though

[Guest]

But that doesn't come close to answering the question of making a one liner shorter. Your code turned making toast in a toaster to making toast with something that Rube Goldberg would have shuddered to contemplate.

 

I do not understand why.

 

this line:

If _IfAndOr($TerminateKey,"F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12","or") = 1 Then

does not seem to you shorter than this line ?:

  If $ TerminateKey = "OFF" Or $ TerminateKey = "F1" Or $ TerminateKey = "F2" Or $ TerminateKey = "F3" Or $ TerminateKey = "F4" Or $ TerminateKey = "F5" Or $ TerminateKey = "F6" Or $ TerminateKey = "F8" Or $ TerminateKey = "F8" Or $ TerminateKey = "F9" Or $ TerminateKey = "F10" Or $ TerminateKey = "F11" Or $ TerminateKey = "F12" Then

?

and this line (Suggested by junkew) :

If stringinstr("OFF,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12", $TerminateKey) > 0 Then

is a bad Idea. At first it seemed a good idea. But on second thought, it will also work when $TerminateKey = "," or

$TerminateKey = "OFF,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12"

or $TerminateKey = "F" or $TerminateKey = Number from 1 to 12

or $TerminateKey = "F10,F11" ..

a lot of bugs can Happen with this line.

[MariusN]

MariusN,

Depending on the possible values of the variables you might be able to use:

If ($read1 + $read2 + $read3 + $read4 + $read5 + $read6) = 24 Then

Obviously that will only work if the values are always numeric AND the value of each variable cannot be more than 4.

M23

 

...good one...thx Melba

[Gianni]

Hi guys...Is there a shorter way of coding the following code --->

If $read1 = 4 And $read2 = 4 And $read3 = 4 And $read4 = 4 And $read5 = 4 And $read6 = 4 Then

...tia

 

Yes!,  there is a way to shorten:

If $read1=4 And $read2=4 And $read3=4 And $read4=4 And $read5=4 And $read6=4 Then

remove the spaces before and after the = sign .......

[Gianni]

MariusN,

Depending on the possible values of the variables you might be able to use:

If ($read1 + $read2 + $read3 + $read4 + $read5 + $read6) = 24 Then

Obviously that will only work if the values are always numeric AND the value of each variable cannot be more than 4.

M23

 

 

another similar way without the need to check the sum:

if ($read1 = 4) * ($read2 = 4) * ($read3 = 4) * ($read4 = 4) * ($read5 = 4) * ($read6 = 4) Then