copy from one array to another

[tempman]

I need to copy Harry, Dick and Tom from $aArray to $bArray

 

#include <Array.au3>

Local $aArray[4]

$aArray[0] = "Harry"
$aArray[1] = "Dick"
$aArray[2] = "Jon"
$aArray[3] = "Tom"

_ArrayDisplay($aArray, "")

Dim $bArray[3]

_ArrayDisplay($bArray, "")

How?

[Melba23]

tempman,

Do you know which numerical elements of teh first array contain the values or do you need to check the value of each element against a list?

M23

[tempman]

Long story short, I got txt file with bunch of names, one name, one line and let say 4-5 names and then "-----" and I need to seperate in differnt txt files.

name.txt

-----

name1

name2

name3

-----

name4

name5

-----

name6

name7

name8

-----

1.txt

name1

name2

name3

2.txt

name4

name5

3.txt

name6

name7

name8

[Melba23]

tempman,

This is how I would go about it:

#include <Array.au3> ; Just for display

; Simulate reading the file into an array
Global $aInitial_Array[12] = ["-----", "name1", "name2", "name3", "-----", "name4", "name5", "-----", "name6", "name7", "name8", "-----"]

; Declare an array large enough to hold all possible items
Global $aTemp_Array[UBound($aInitial_Array)]
; And a counter
Global $iCount = 0

For $i = 0 To UBound($aInitial_Array) - 1

    ; Loop through the array looking for the next name
    If $aInitial_Array[$i] = "-----" Then
        ; Have we found any names?
        If $iCount Then
            ; Display them
            _ArrayDisplay($aTemp_Array, $iCount)
            ; Then write the file using _FileWriteFromArray - $iCount gives you the $iUbound parameter

            ; Finally reset the temp array and count for the next section
            Global $aTemp_Array[UBound($aInitial_Array)]
            $iCount = 0
        EndIf
    Else
        ; Add the item to the temp array
        $aTemp_Array[$iCount] = $aInitial_Array[$i]
        ; Increase the count
        $iCount += 1
    EndIf
Next

All clear?

M23