Making sure string is a number

[Malkey]

Midnight, the start of the day, is 0000hrs.
And because 2400 hrs is sometimes used to indicate midnight, the end of the day, 2400 is allowed.
Some 24hr time systems have ":" separating hours and minutes, so ":"  in this example is optional.
 

expandcollapse popup

#include <WindowsConstants.au3>
#include <StaticConstants.au3>

Global $hInput, $sDataInInput
Local $iTimeToConvert

Do
    $iTimeToConvert = _InputBox('Enter the time in military time', 'Please enter the time in military time (0-24)! ')
Until @error = 1


Func _InputBox($Title, $Prompt)
    Local $hGui, $OK, $Cancel
    Local $hGui = GUICreate($Title, 259, 190, Default, Default, $WS_THICKFRAME)
    GUICtrlCreateLabel($Prompt, 5, 10, 249, Default, $SS_CENTER)
    $hInput = GUICtrlCreateInput("", 10, 96, 223, 20);, $ES_NUMBER)
    Local $OK = GUICtrlCreateButton("Ok", 28, 121, 75, 23)
    Local $Cancel = GUICtrlCreateButton("Cancel", 140, 121, 75, 23)
    GUISetState()
    GUIRegisterMsg(0x0111, 'WM_COMMAND') ; 0x0111 = $WM_COMMAND (Windows Message code for WM_COMMAND)
    Do
        Switch GUIGetMsg()
            Case -3, $Cancel
                Return SetError(1)
            Case $OK
                MsgBox(0, "", "24hr time input is " & $sDataInInput, 3)
                Return SetError(0, 0, $sDataInInput)
        EndSwitch
    Until 0
EndFunc   ;==>_InputBox

Func WM_COMMAND($hWnd, $imsg, $iwParam, $ilParam)
    #forceref $hWnd, $imsg, $iwParam, $ilParam
    Local $nNotifyCode = BitShift($iwParam, 16)
    Local $sRE = "(^([01][0-9]|2[0-3])\:?[0-5][0-9]$)|(^24\:?00$)"
    Local $sEg = "1200" ; - Because 24:00 is allowed, $sEg must end with "00".
    ;                       So that the partial input string, "24" will be accepted.

    ; Work on the $hInput control that changed.
    If $ilParam = GUICtrlGetHandle($hInput) And $nNotifyCode = 0x300 Then ; $EN_CHANGE = 0x300
        Local $iFlag, $sText = GUICtrlRead($hInput)

        ; Loop through concatenated partially entered input string with a reducing $sEg, checking for a RegExp match.
        For $j = 0 To StringLen($sEg)
            $iFlag = 1
            ;ConsoleWrite($sText & StringTrimLeft($sEg, $j) & @LF) ; Use to see if RE pattern and $sEg work together correctly.
            If StringRegExp($sText & StringTrimLeft($sEg, $j), $sRE) Then ExitLoop ; Goto "If $iFlag = 1 Then"
            $iFlag = 0
        Next
        If $iFlag = 1 Then
            $sDataInInput = $sText ; Valid character. Update storage variable.
        Else
            GUICtrlSetData($hInput, $sDataInInput) ; Update input control text which will remove invalid character.
        EndIf
    EndIf
    Return 'GUI_RUNDEFMSG' ; $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Edited September 23, 2013 by Malkey