Duplicate mouse clicks

[Hintman]

Hi guys,

I have searched but have found nothing, and my programming skills are like...never seen the light of the world. 

My intention is to duplicate the mouse pointer, to execute two simultaneously clicks on different buttons on my screen. How do you suggest to write such a script?

Best regards

Michael

[FireFox]

Hi,

Welcome to the autoit forum

What do you need this script for?

There may be more reliable ways to automate what you're trying to achieve.

Br, FireFox.

[Hintman]

Hi,

and thank you for the quick response. A brief description:

I am testing online brokers, how reliable they are with their execution of my orders. So I want to press the "Buy"- or "Sell"-Button for at least two different brokers in two different platforms at the same time. 

[mLipok]

online ?

try HELPFILE >>> _IE.... functions

Try it and if necessary, go back to the forum with a more detailed description of the problem.
I'm sure someone can help.

[mikell]

I would do this in 2 steps

- first use a hotkey to grab into an array the coords of the pointer when positioned on the buttons

- then loop into this array and use MouseClicks at speed 0

[JohnOne]

For sake of clarity, you cannot do simultaneous clicks in AutoIt3.

[Hintman]

For sake of clarity, you cannot do simultaneous clicks in AutoIt3.

Oh, ok...damn

[Mat]

You can't do truly simultaneous clicks on windows at all.  You could get the time gap to be very small though. Certainly small enough that most software wouldn't know the difference.

[Morthawt]

#RequireAdmin
AutoItSetOption('TrayAutoPause', 0)
Global $iFirstRun = 1, $aMousePosList[1][2]
HotKeySet('{CAPSLOCK}', '_GatherPositions')
HotKeySet('{SCROLLLOCK}', '_AllClicksBulletin')

While 1
    Sleep(20)
WEnd

Func _GatherPositions()
    If Not $iFirstRun Then
        ReDim $aMousePosList[UBound($aMousePosList) + 1][2]
    EndIf
    $aMousePosList[UBound($aMousePosList) - 1][0] = MouseGetPos(0)
    $aMousePosList[UBound($aMousePosList) - 1][1] = MouseGetPos(1)
    $iFirstRun = 0
EndFunc   ;==>_GatherPositions

Func _AllClicksBulletin()
    BlockInput(1)
    For $a = 0 To UBound($aMousePosList) - 1
        MouseClick('main', $aMousePosList[$a][0], $aMousePosList[$a][1], 1, 0)
    Next
    Global $aMousePosList[1][2]
    BlockInput(0)
EndFunc   ;==>_AllClicksBulletin

Here is my little script. It will request UAC access to be able to temporarily block accidental mouse movements while performing the automated clicks. Once running just point over the areas you want to click and press CAPSLOCK button, once per click. So if you have 2 buttons on screen that need clicking one time each then hover over each button and press CAPSLOCK once. Once you have pressed that for each button on screen you want to click then press SCROLLLOCK once and it will block all user inputs and immediately click those things as fast as it possible and then free user inputs back to normal again.

Edit: While this isn't simultaneous, it is actually extremely fast. Way faster than you could ever do manually. It will only be a few single digit miliseconds most likely between the clicks.

Edited September 17, 2013 by Morthawt

[DW1]

My take on cloning the mouse.  Was bored at the end of my day at work.

This would not work for anything other than a single click.

Note: This is not at all a good solution to what you were asking for, just though it was neat so I went with it.  I would recommend using the _IE functions for what you are discussing, or recording all of the positions as Morthawt showed.

expandcollapse popup

#include<WindowsConstants.au3>
#include<WinAPI.au3>
#include<Misc.au3>

SplashTextOn("Clone mouse", "Click to place new cursor" & @CRLF & "Middle (scroll) click to exit once running", 400, 75)
MouseWaitClick()
SplashOff()
Local $aMouse = MouseGetPos()

Local $hGUI = GUICreate("", 25, 25, $aMouse[0], $aMouse[1], $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TRANSPARENT, $WS_EX_TOOLWINDOW, $WS_EX_TOPMOST))
GUISetBkColor(0xABCDEF, $hGUI)
_WinAPI_SetLayeredWindowAttributes($hGUI, 0xABCDEF)

;Replace with your cursor
GUICtrlCreateIcon(StringReplace(RegRead("HKEY_CURRENT_USER\Control Panel\Cursors", "Arrow"), "%SystemRoot%", @WindowsDir), 10, 0, 0)
GUISetState()

SplashTextOn("Clone mouse", "Click to set offset between cloned mouse and current mouse", 400, 75)
MouseWaitClick()
SplashOff()
Local $aMouse2 = MouseGetPos()
Local $aOffset[2] = [$aMouse[0] - $aMouse2[0], $aMouse[1] - $aMouse2[1]]

While 1
    Local $aMouseMove = MouseGetPos()
    WinMove($hGUI, '', $aMouseMove[0] + $aOffset[0], $aMouseMove[1] + $aOffset[1])
    WinSetOnTop($hGUI, '', 1)
    If _IsPressed(01) Then
        While _IsPressed(01)
            Sleep(10)
        WEnd
        MouseClick("left", $aMouseMove[0] + $aOffset[0], $aMouseMove[1] + $aOffset[1], 1, 0)
        MouseMove($aMouseMove[0], $aMouseMove[1], 0)
    EndIf
    If _IsPressed(02) Then
        While _IsPressed(02)
            Sleep(10)
        WEnd
        MouseClick("right", $aMouseMove[0] + $aOffset[0], $aMouseMove[1] + $aOffset[1], 1, 0)
        MouseMove($aMouseMove[0], $aMouseMove[1], 0)
    EndIf
    If _IsPressed(04) Then Exit
    Sleep(10)
WEnd

Func MouseWaitClick()
    ;Wait for mouse down
    While _IsPressed(01) <> 1
        Sleep(10)
    WEnd
    ;Wait for mouseup
    While _IsPressed(01) = 1
        Sleep(10)
    WEnd
EndFunc   ;==>MouseWaitClick