Array, ComboBox and _IsPressed

[bazinga]

Hello guys,

as the title says, i have a problem with array, combobox and the IsPressed function.

i try to pass the selected item to the _IsPressed function but its not working the way i do it. a little hint what to search for or a code snippet to learn from would be really nice.

thanks in advance.

Global $Array[3][2] = [ ["X", 58], ["C", 43], ["V", 56] ]

$Combo = GUICtrlCreateCombo($Array[0][0], 130, 100, 50, 20, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL))
For $i = 0 To Ubound($Array) - 1
    GUICtrlSetData($Combo, $Array[$i][0], True)
Next

$Key = GUICtrlRead($Combo)


While 1
    If _IsPressed($Key) Then
        Do
            Send ("{0}")
        Until Not _IsPressed($Key)
    EndIf
WEnd

Edited September 3, 2013 by bazinga

[Melba23]

bazinga,

I would do something like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ComboConstants.au3>
#include <Array.au3>
#include <Misc.au3>

Global $aKeys[3][2] = [ ["X", 58], ["C", 43], ["V", 56] ]
$hDLL = DllOpen("user32.dll") ; You are calling _IsPressed in a loop - so use the DLL handle
$iKeyCode = 0 ; You need to declare this

$hGUI = GUICreate("Test", 500, 500)

; Do not set a default value in the combo - then you react to the first selection
$cCombo = GUICtrlCreateCombo("", 130, 100, 50, 20, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL))
For $i = 0 To Ubound($aKeys) - 1
    GUICtrlSetData($cCombo, $aKeys[$i][0])
Next

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            DllClose($hDLL)
            Exit
        Case $cCombo
            ; Combo selection changed - get index of new selection
            $iIndex = _ArraySearch($aKeys, GUICtrlRead($cCombo))
            ; Set keycode to the correct vlaue
            $iKeyCode = $aKeys[$iIndex][1]
    EndSwitch

    If _IsPressed($iKeyCode, $hDLL) Then
        Do
            Send ("0") ; No need for {}
        Until Not _IsPressed($iKeyCode, $hDLL)
    EndIf
WEnd

All clear?

M23

[FireFox]

The _IsPressed function takes hexadecimal numbers, 58 <> 0x58. Either turn your integers into strings or put directly the hexadecimal numbers in your array.

Br, FireFox.

[bazinga]

oh yea, its working thanks alot Melba23!

well, one more question: why do i have to use "user32.dll" when using _IsPressed in a loop? any disadvantages if i dont do? i ask, because i cant see a difference :S

[Melba23]

bazinga,

If you do not open the DLL and use the handle in the function call you are opening and closing the DLL each time. In this case there is not a huge penalty as the user32 DLL is almost certainly open anyway - but the principle still holds that it is better to get a handle and use it if you call the function in a loop.

M23

Edited September 3, 2013 by Melba23
Typo

[bazinga]

aah ok. thank you very much