Copying from one date time field results in time change

[gritts]

I searched for this oddity for a while but found no results. If I missed it, my apologies.

I have an app that I am building that will eventually search a SQL database for results within a specified range of time. To collect the range of time required but the user, I have 2 fields I created, one for start and the other for end times. They are formatted "yyyy/MM/dd HH:MM:ss" for entry.

The fields are created with this:

$dpStartDate = GUICtrlCreateDate(_NowCalc(), 112, 88, 146, 24)
$dpEndDate = GUICtrlCreateDate(_NowCalc(), 416, 88, 146, 24)

I am setting the format of the fields with this code:

$DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
$style = "yyyy/MM/dd  hh:mm:ss"
GUICtrlSendMsg($dpStartDate, $DTM_SETFORMAT_, 0, $style)
GUICtrlSendMsg($dpEndDate, $DTM_SETFORMAT_, 0, $style)

What I am attempting to do is when the start field is updated, compare it with the end time field. If the end time is less than the start time, make both fields match. When I attempt to do so with the function below, The end time date is copied correctly but the time (hour) is reset to 1, no matter the time entered. Am I going about updating the field incorrectly?

As an example, I set the date in the start field to "2013/08/23 11:47:38", the end time field gets set to "2013/08/23 01:00:00"

Func dpStartDateChange()
    Local $stDT = GUICtrlRead($dpStartDate), $edDT = GUICtrlRead($dpEndDate)
    If $edDT < $stDT Then
        MsgBox(0,"Change Needed","End Time: "&$edDT&@CRLF&"Start Time: "&$stDT) ;Shows correct time
        GUICtrlSetData($dpEndDate,$stDT)
    EndIf
EndFunc

There is no code for SQL in place yet. I am working on some of the GUI logic for now. Let me know if there is enough code here or you need more.

[abberration]

You had the answer with your 2nd box of code. Example:

#include <GUIConstants.au3>
#include <date.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 352, 82)
$dpStartDate = GUICtrlCreateDate(_NowCalc(), 16, 16, 186, 21)
$dpEndDate = GUICtrlCreateDate(_NowCalc(), 16, 40, 186, 21)
$DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
$style = "yyyy/MM/dd  hh:mm:ss"
GUICtrlSendMsg($dpStartDate, $DTM_SETFORMAT_, 0, $style)
GUICtrlSendMsg($dpEndDate, $DTM_SETFORMAT_, 0, $style)
$Button1 = GUICtrlCreateButton("Read", 232, 24, 75, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            Local $stDT = GUICtrlRead($dpStartDate), $edDT = GUICtrlRead($dpEndDate)
            If $edDT < $stDT Then
                MsgBox(0,"Change Needed","End Time: "&$edDT&@CRLF&"Start Time: "&$stDT) ;Shows correct time
;~                 GUICtrlSetData($dpEndDate,$stDT) ; Do not use
                GUICtrlSendMsg($edDT, $DTM_SETFORMAT_, 0, $style) ; correct way
            EndIf
    EndSwitch
WEnd

[gritts]

Thank you for the reply.

I tried the suggestion you made and the field does not update with the change. I also tried running your sample code and it had the same effect. The value from the start time is not copied to the end time. Here is my function as it stands now...

Func dpStartDateChange()
    Local $stDT = GUICtrlRead($dpStartDate), $edDT = GUICtrlRead($dpEndDate)
    If $edDT < $stDT Then
        MsgBox(0,"Change Needed","End Time: "&$edDT&@CRLF&"Start Time: "&$stDT)
        GUICtrlSendMsg($dpEndDate,$DTM_SETFORMAT_,0,$style)
    EndIf
EndFunc

I'm still trying to wrap my head around the "GUICtrlSendMsg" function...

[abberration]

I did not fully understand what you were trying to accomplish. Now I do. I have tried several things even after reading this part of the help file on GuiCtrlSetData:

The "data" date format is "yyyy/mm/dd".

Therefore, if you include the time afterwards, it does not accept it. Since the _NowCalc() function was able to set the date and time, I thought maybe the data needed to be encoded as a date format instead of a string. I tried using _Date_Time_EncodeSystemTime, but that did not work. All it did was to set the end time back to the current time.

Sorry I could not find a solution.

[jchd]

Try this, it works for me. You may want to change the time format if your locale uses AM/PM (which mine doesn't). See msdn details.

#include <GUIConstants.au3>
#include <date.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 352, 82)
$dpStartDate = GUICtrlCreateDate(_NowCalc(), 16, 16, 186, 21)
$dpEndDate = GUICtrlCreateDate(_NowCalc(), 16, 40, 186, 21)
$DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
$style = "yyyy'/'MM'/'dd' 'HH':'mm':'ss"
GUICtrlSendMsg($dpStartDate, $DTM_SETFORMAT_, 0, $style)
GUICtrlSendMsg($dpEndDate, $DTM_SETFORMAT_, 0, $style)
$Button1 = GUICtrlCreateButton("Read", 232, 24, 75, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            Local $stDT = GUICtrlRead($dpStartDate), $edDT = GUICtrlRead($dpEndDate)
            If $edDT < $stDT Then
                MsgBox(0,"Change Needed","End Time: "&$edDT&@CRLF&"Start Time: "&$stDT) ;Shows correct time
                GUICtrlSetData($dpEndDate,$stDT)
            EndIf
    EndSwitch
WEnd

As the page says, non-format characters need to be enclosed in single quotes.

[gritts]

@abberration, thank you for your help, You gave me some ideas when searching for the solution.

@jchd, I ran your sample script and it worked fine. After a time of "stare and compare" between what you posted and what I had, I could not figure what the difference was aside from the single tick quotes for non-format characters. I copied your "$style" line into my script and it worked. To cut a long story short, I discovered my version had an extra space between the date format and the time format.

Here are the two lines for comparison...

$style = "yyyy'/'MM'/'dd'  'HH':'mm':'ss" ;my version
$style = "yyyy'/'MM'/'dd' 'hh':'mm':'ss" ;new version

The field seems to update fine whether I use the 24hour or 12hour formatting ("HH" or "hh"). Funny what having one extra space can do. Thank you both again for your help!