How to do word wrap in ListBox?

[AndreyS]

Hello everyone!

Maybe someone knows. Is it possible to make long items listboks transferred / broken into multiple lines?

[Artisan]

Need a little clarification before I can help you.

Is it just an issue of display?  If so, look at GUICtrlListView - it automatically includes a horizontal scroll bar and resizable column headers.

Do you want Word Wrap applied to longer strings so that one long entry is more than one line?  I think GUICtrlListView can do that too.

Do you want to break a long string into multiple single-line entries?  That's easy to do with a few String...() functions.

[AndreyS]

Thank you for having responded to that!

Will explain. I saw the need to fully long elements without using the horizontal scroll is. Items consist of a few sentences so that they fit only 3-4 lines. When you click on an item must be allocated all of the rows of the item.

[Artisan]

Sounds like you want this:

Specifically, post #17.  It's an Outlook style ListView which should do the trick for you.  Very customizable!

Edited August 22, 2013 by Artisan

[AndreyS]

If such a ListView control of foliage in the settings that will be possible to set it up on a multi-line then that is what you need!

Thanks Artisan for the link! 

I will try!

[PhoenixXL]

Is it possible to make long items listboks transferred / broken into multiple lines?

Then there would be two different items and selection of both the items at the same time won't be possible.

Rather when strings are long, a hover tip could be used to display( >if interested )

Best regards

[AZJIO]

#include <WindowsConstants.au3>
$sText = 'This is a very long string . But that''s not the problem. The line will be divided by the length of no more than 35 characters.'
$hGui = GUICreate('My Program', 250, 260)
$iList = GUICtrlCreateList('', 10, 10, 230, 240, $WS_BORDER + $WS_VSCROLL)
GUICtrlSetData($iList, StringRegExpReplace($sText, '(.{35,}?)\h', '$1|'))
GUISetState()
Do
Until GUIGetMsg() = -3

[AndreyS]

Thanks for the option Azjio!

In this embodiment, obtained as a result of three elements, it is necessary that there was one. And that when clicked immediately stood out all the lines.

 

 

Edited September 7, 2013 by AndreyS

[TheSaint]

Word Wrap or more correctly Text Wrap (for unbroken text) will occur if you don't use any Horizontal Scroll parameters during ListBox creation. At least, that's how it works for me with AutoIt v3.3.0.0 .... not sure for current AutoIt. In that same version, you cannot set this after ListBox creation using GUICtrlSetStyle ... not without deleting and recreating the control.

This behavior can be seen in my WebPad program, currently available in the most recent listings of Examples section of forum.

Text Wrap is a menu item.

[PhoenixXL]

This behavior can be seen in my WebPad program, currently available in the most recent listings of Examples section of forum.

Text Wrap is a menu item.

But it is an edit control and we are speaking about ListBox, can you provide an example for a listbox ?

[AndreyS]

Yes, I would like to see your solution, TheSaint, or if you can link to.

 

By the way, dear developers, you can even without spaces between items that are visible on my preview.

[PhoenixXL]

This is what I've got for the moment.

If you are interested in it tell me for any modifications.

Added a lot more of code and functions

Features

• Add, Insert or Delete(one or all) Item
• Call function when item is clicked
• Support of scrolling with arrow buttons
• VScroll Bar is now included
• Enter is also taken as an event
• Set your own cursor
• Multiple EditLists could be used at a time.

 

EditList.au3

expandcollapse popup

#include-once
#include <Array.au3>
#include <WinAPISys.au3>
#include <WinAPIRes.au3>
#include <APISysConstants.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

; = = = = = = .  . . . Private UDF Global Variables ===========================================================

Global $aItems[1] ;stores Item indexes
Global $sAppend ;stores Item delimited
Global $__hCur ;stores the handle to the cursor
Global $h_ControlHwnd ;stores the handle of the control.
Global $p_Original_WindowProc ;stores the original window procedure(WndProc) of the edit control.

Global $h_NewWndProc = DllCallbackRegister("_NewWnd_Proc_", "int", "hwnd;uint;wparam;lparam") ;hanlde to the new WndProc
Global $p_NewWndProc = DllCallbackGetPtr($h_NewWndProc) ;pointer to the new WndProc.

Global $s_OnEventFunc ;string storing the name of the func to call upon click.

Func _Edit_List_Create($iX, $iY, $iWidth, $iHeight, $hWin, $sAppendString = -1)

    $h_ControlHwnd = _GUICtrlRichEdit_Create($hWin, "", $iX, $iY, $iWidth, $iHeight, BitOR($WS_VSCROLL, $ES_AUTOVSCROLL, $ES_MULTILINE, $ES_NOHIDESEL))
    OnAutoItExitRegister("Destroy")

    $p_Original_WindowProc = _Subclass_($h_ControlHwnd, $p_NewWndProc)

    _GUICtrlRichEdit_SetText($h_ControlHwnd, "")

    If $sAppendString = -1 Then $sAppendString = @LF
    $sAppend = $sAppendString
    $aItems[0] = -StringLen($sAppend)

    Return $h_ControlHwnd ;

EndFunc   ;==>_Edit_List_Create

Func _Edit_List_Suspend()

    Local $aRet[6] = [$aItems, $sAppend, $__hCur, $h_ControlHwnd, $p_Original_WindowProc, $s_OnEventFunc]
    ReDim $aItems[1]
    $sAppend = ""
    $__hCur = 0
    $h_ControlHwnd = 0
    $p_Original_WindowProc = 0
    $s_OnEventFunc = ""
    Return $aRet

EndFunc   ;==>_Edit_List_Suspend

Func _Edit_List_Restore($aData)
    If IsArray($aData) = 0 Then Return
    $aItems = $aData[0]
    $sAppend = $aData[1]
    $__hCur = $aData[2]
    $h_ControlHwnd = $aData[3]
    $p_Original_WindowProc = $aData[4]
    $s_OnEventFunc = $aData[5]

EndFunc   ;==>_Edit_List_Restore

Func _Edit_List_GetActive()
    Return $h_ControlHwnd
EndFunc   ;==>_Edit_List_GetActive

Func _Edit_List_InsertItem($s_Text, $iIndex = -1)

    Local $sEdit_Text = _GUICtrlRichEdit_GetText($h_ControlHwnd)
    Local $iMaxLen = StringLen($sEdit_Text)

    If IsInt($iIndex) = 0 Then Return SetError(2, 0, 0) ;bad $iIndex
    $s_Text = StringRegExpReplace($s_Text, "\v+", @LF)

    If $iIndex >= UBound($aItems) Then Return SetError(3, 0, 0)

    If $iIndex >= 1 Then

        Local $iUbound = UBound($aItems)
        If $iIndex > $iUbound Then Return SetError(3, 0, 0) ;bad $iIndex

        _GUICtrlRichEdit_GotoCharPos($h_ControlHwnd, $aItems[$iIndex - 1] + StringLen($sAppend))
        _GUICtrlRichEdit_InsertText($h_ControlHwnd, $s_Text & $sAppend)

        Local $Change = StringLen($s_Text & $sAppend)

        _ArrayInsert($aItems, $iIndex - 1, $aItems[$iIndex - 1])
        ;reset the array
        For $i = $iIndex To $iUbound
            $aItems[$i] += $Change
        Next


    ElseIf $iIndex = -1 Then

        _ArrayAdd($aItems, StringLen($sEdit_Text & $s_Text))
        _GUICtrlRichEdit_AppendText($h_ControlHwnd, $s_Text & $sAppend)

    Else
        Return SetError(1, 0, 0) ;$iIndex parameter is wrong.
    EndIf

    Return 1

EndFunc   ;==>_Edit_List_InsertItem

Func _Edit_List_GetItemText($iIndex = -1) ;by default gets the selected items text
    If $iIndex = -1 Then Return _GUICtrlRichEdit_GetSelText($h_ControlHwnd)
    If $iIndex <= 0 Or IsInt($iIndex) = 0 Then Return SetError(1, 0, 0)
    If $iIndex >= UBound($aItems) Then Return SetError(3, 0, 0)
    Return _GUICtrlRichEdit_GetTextInRange($h_ControlHwnd, $aItems[$iIndex - 1] + StringLen($sAppend), $aItems[$iIndex])
EndFunc   ;==>_Edit_List_GetItemText

Func _Edit_List_GetSelItemIndex()
    Local $iLowerIndex = _GUICtrlRichEdit_GetSel($h_ControlHwnd)
    If @error Then Return SetError(1, @error, 0)
    $iLowerIndex = $iLowerIndex[0]

    For $i = 1 To UBound($aItems) - 1
        Switch $iLowerIndex
            Case $aItems[$i - 1] + StringLen($sAppend) To $aItems[$i]
                Return $i
        EndSwitch
    Next

    Return SetError(2, 0, 0)
EndFunc   ;==>_Edit_List_GetSelItemIndex

;The Following function was works using the functions of the already present library.
;Therefore it would work with both OnEvent as well as MsgLoop methods.
;PS: The OnEvent macros won't work like @GUI_CTRLID, etc.
;Use _Edit_List_SetOnClick("") to deregister an already registered function.
;The function should not have any parameter.
Func _Edit_List_SetOnEvent($s_FuncName)
    $s_OnEventFunc = $s_FuncName
EndFunc   ;==>_Edit_List_SetOnEvent


Func _Edit_List_SetCursor($hCursor)
    $__hCur = $hCursor;_WinAPI_CopyCursor()
EndFunc   ;==>_Edit_List_SetCursor

Func _Edit_List_SetSel($iIndex, $iReverse = False)
    ;key: the index of the array is the length of the item,
    ;use the index of the previous item to get the initial position of the required item
    If IsInt($iIndex) = 0 Or $iIndex < 1 Or $iIndex >= UBound($aItems) Then Return SetError(1, 0, 0)

    Local $iAnchor = $aItems[$iIndex - 1] + StringLen($sAppend)
    Local $iActive = $aItems[$iIndex]

    If $iReverse Then _ArraySwap($iActive, $iAnchor)

    Return _GUICtrlRichEdit_SetSel($h_ControlHwnd, $iAnchor, $iActive)
EndFunc   ;==>_Edit_List_SetSel

Func _Edit_List_RemoveItem($iIndex)

    If $iIndex >= UBound($aItems) Then Return SetError(3, 0, 0)

    _GUICtrlRichEdit_SetSel($h_ControlHwnd, $aItems[$iIndex - 1] + StringLen($sAppend), $aItems[$iIndex] + 1)
    _GUICtrlRichEdit_ReplaceText($h_ControlHwnd, "", False)

    Local $Change = StringLen(_Edit_List_GetItemText($iIndex) & $sAppend)

    _ArrayDelete($aItems, $iIndex)
    ;reset the array
    For $i = $iIndex To UBound($aItems) - 1
        $aItems[$i] -= $Change
    Next

    _SendMessage($h_ControlHwnd, $WM_SETFOCUS)

EndFunc   ;==>_Edit_List_RemoveItem

Func _NewWnd_Proc_($hWnd, $iMsg, $wParam, $lParam)




    Switch $hWnd
        Case $h_ControlHwnd
            Switch $iMsg

                Case $WM_RBUTTONDOWN, $WM_CHAR
                    Return 0

                Case $WM_SETCURSOR
                    If $__hCur <> 0 And _WinAPI_LoWord($lParam) = 1 Then Return _WinAPI_SetCursor($__hCur) ;lparam = hittest = 1 = client area

                Case $WM_KEYDOWN

                    Local Const $VK_UP_ = 0x26
                    Local Const $VK_DOWN_ = 0x28
                    Local Const $VK_ENTER_ = 0x0D

                    Switch $wParam
                        Case $VK_UP_, $VK_DOWN_

                            _Edit_List_SetSel(_Edit_List_GetSelItemIndex() + $wParam - 0x27, $wParam - 0x28)
                            _GUICtrlRichEdit_ScrollToCaret($hWnd)

                        Case $VK_ENTER_

                            If IsFunc($s_OnEventFunc) Then $s_OnEventFunc($hWnd, 1)

                    EndSwitch
                    Return 0

                Case $WM_KILLFOCUS

                    $iRet = _WinAPI_CallWindowProc($p_Original_WindowProc, $hWnd, $iMsg, $wParam, $lParam)

                    DllCall("user32.dll", "int", "ShowCaret", "hwnd", $hWnd)

                    Return $iRet

                Case $WM_SETFOCUS
                    $iRet = _WinAPI_CallWindowProc($p_Original_WindowProc, $hWnd, $iMsg, $wParam, $lParam)

                    DllCall("user32.dll", "int", "HideCaret", "hwnd", $hWnd)

                    Return $iRet

                Case $WM_LBUTTONDOWN, $WM_LBUTTONDBLCLK

                    $iX = _WinAPI_LoWord($lParam)
                    $iY = _WinAPI_HiWord($lParam)
                    $iChar = _GUICtrlRichEdit_GetCharPosFromXY($hWnd, $iX, $iY);

                    For $n = 1 To UBound($aItems) - 1
                        Switch $iChar
                            Case $aItems[$n - 1] + StringLen($sAppend) To $aItems[$n]

                                _Edit_List_SetSel($n, 1)
                                _GUICtrlRichEdit_ScrollToCaret($hWnd)

                        EndSwitch
                    Next
                    If IsFunc($s_OnEventFunc) Then $s_OnEventFunc($hWnd, 0)

                    Return 0;

            EndSwitch
        Case Else
            Switch $iMsg

                Case $WM_LBUTTONDOWN, $WM_LBUTTONDBLCLK

                    If IsFunc($s_OnEventFunc) Then $s_OnEventFunc($hWnd, 0)
                    Return 0;
            EndSwitch

    EndSwitch
    ;go with the original processing.
    Return _WinAPI_CallWindowProc($p_Original_WindowProc, $hWnd, $iMsg, $wParam, $lParam)

EndFunc   ;==>_NewWnd_Proc_

Func _Subclass_($hWnd, $pNew_WndProc)

    ;substitute the WndProc of the control.
    Return _WinAPI_SetWindowLong($hWnd, $GWL_WNDPROC, $pNew_WndProc)

EndFunc   ;==>_Subclass_

Func Destroy()

    _Subclass_($h_ControlHwnd, $p_Original_WindowProc)
    _GUICtrlRichEdit_Destroy($h_ControlHwnd)
    _WinAPI_DestroyCursor($__hCur)

EndFunc   ;==>Destroy

Func _Edit_List_Clear()
    ReDim $aItems[1]
    Local $iRet = _GUICtrlRichEdit_SetText($h_ControlHwnd, "")
    _SendMessage($h_ControlHwnd, $WM_SETFOCUS)

    Return $iRet
EndFunc   ;==>_Edit_List_Clear

Test Script.au3

expandcollapse popup

;Note the script requries AutoIT v3.3.10++

#include <EditList.au3>
#include <WinAPIRes.au3>

If StringMid(@AutoItVersion, 3, 4) <> "3.10" Then Exit MsgBox(16, "Error", "The script requries AutoIT v3.3.10++" & @CRLF & "You have " & @AutoItVersion)

$hMain = GUICreate("Test", 700, 300)
Global $hRichEdit_1 = _Edit_List_Create(10, 10, 300, 280, $hMain)

_Edit_List_InsertItem("1. The usual high-level elements for functions, loops and expression-handling.")
_Edit_List_InsertItem("4. A staggering amount of string handling functions and a Perl Compatible Regular Expression Engine(PCRE)" & @CRLF)
_Edit_List_InsertItem("2. Call Win32 and Third-Party DLL APIs." & @CRLF, 2)
_Edit_List_InsertItem("3. COM support", 3)

Local $hCur = _WinAPI_LoadCursor(0, $IDC_HAND)
_Edit_List_SetCursor($hCur)
_WinAPI_DestroyCursor($hCur)

_Edit_List_SetOnEvent(OnEvent_Handler)

;Now before creating a new EditList we have to suspend the first EditList
Global $aData = _Edit_List_Suspend()


Global $hRichEdit_2 = _Edit_List_Create(390, 10, 300, 280, $hMain)

_Edit_List_InsertItem("The only things that evolve by themselves in an organization are disorder, friction and malperformance." & @CRLF)
_Edit_List_InsertItem("The mind is everything. What you think you become.  –Buddha" & @CRLF)
_Edit_List_InsertItem("There is only one way to avoid criticism: do nothing, say nothing, and be nothing. –Aristotle" & @CRLF)
_Edit_List_InsertItem("A person who never made a mistake never tried anything new. – Albert Einstein" & @CRLF)
_Edit_List_InsertItem("The battles that count aren’t the ones for gold medals. The struggles within yourself–the invisible battles inside all of us–that’s where it’s at. –Jesse Owens")

_Edit_List_SetOnEvent(OnEvent_Handler)


GUISetState()

_SendMessage($hRichEdit_2, $WM_SETFOCUS) ;required for initial hiding of the caret. The one created at last should be set the focus

Do
    Sleep(10)
Until GUIGetMsg() = -3 ;$GUI_EVENT_CLOSE = -3

Func OnEvent_Handler($hRichEdit, $iEvent)
    ;$hRichedit is the handle of the richedit from where the function is called
    ;$iEvent
    ;   1| OnEnterDown (received when it is the current editlist)
    ;   0| OnLeftClick
    Switch $iEvent
        Case 0  ;onmouse click
            If _Edit_List_GetActive() <> $hRichEdit Then
                Local $bData = _Edit_List_Suspend()
                _Edit_list_Restore($aData)
                $aData = $bData
                MouseClick('left', Default, Default, 1, 0)  ;simulate a click to set selection
            EndIf
    EndSwitch
    ConsoleWrite("Item Selected: " & _Edit_List_GetSelItemIndex() & @TAB & "  ItemText: " & _Edit_List_GetItemText() & @CRLF)

EndFunc   ;==>OnEvent_Handler


 

Let me know what you think.

Thumbs up if it helped

Regards

Edited March 5, 2014 by PhoenixXL

[mLipok]

Very interesting piece of code.

I began to wonder about other possible uses.

[AndreyS]

So so so so much!  I see the code that is something very similar to the one that I need!

 

It is true when you start I get errors:

 

D: Program Files AutoIt3 Include APIConstants.au3 (1989,41): ERROR: $ FR_DIALOGTERM previously declared as a 'Const'.

Global Const $ FR_DIALOGTERM = 0x00000040

~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~

D: Program Files AutoIt3 Include APIConstants.au3 (1991,41): ERROR: $ FR_ENABLEHOOK previously declared as a 'Const'.

Global Const $ FR_ENABLEHOOK = 0x00000100

~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~ ~

... and so on.

 

How to fix it?

I'd like to see the results!

Edited September 9, 2013 by AndreyS

[mLipok]

it works on latest beta

but not on AutoIt 3.3.8.1

[AndreyS]

Ahh that's it!

Thank mlipok!

Then I see that you have to switch to this version. It is very necessary to implement this functionality.

[AndreyS]

Soooo PhoenixXL! Experienced! A great solution! It was then that I had! That's it!

Finally! Not easy but you did it!

Thank you so much!

Edited September 9, 2013 by AndreyS

[TheSaint]

But it is an edit control and we are speaking about ListBox, can you provide an example for a listbox ?

Doh! 

(insert facepalm here)

Where was my brain? 

Sorry AndreyS - I think my brain was taking a vacation on another planet. 

Haven't been myself, since the damn AUS election went to the Immoral party.

P.S. To be fair to my brain though, Word Wrap in a ListBox is a little out of the ordinary ... traditionally you just use a horizontal scrollbar to see the entire entry in a line. ListBox isn't dynamic like an Excel spreadsheet, and I only see trouble spreading things over more than one line. That said, I haven't really looked at the proposals you've been given so far ... certainly not in detail anyway.

For myself, I have always used a Tooltip to display what may be a long entry. I also often use a long Input, that is wider than the Listbox ... when feasible. Another way, is to show a shorter List version, linked to an ini file entry, that displays the full entry over two or more Inputs or a multiline Edit ... done that before too. Obviously they are just for the selected entry in the ListBox.

EDIT

Noticing your Thumbnail again, I can see why my mind thought Edit.

Edited September 10, 2013 by TheSaint

[PhoenixXL]

How to fix it?

I'd like to see the results!

I made it on Autoit 3.3.8.1, the problem arises due to the errors in the APIConstants.au3 that you may not have rectified/updated.

I replaced the includes and it would work without APIConstants w/o any problem on the stable release. Check the code again in the stable release.

Edited September 22, 2013 by PhoenixXL

[guinness]

Guys,

Try to refrain from using -3 and opt for $GUI_EVENT_CLOSE instead. Also I'm not getting any errors with APIIConstants.au3. What version of then beta are you using please PhoenixXL?