How to enable windows high contrast mode with autoit?

[Neutro]

Hey guys,

I'm trying to use an autoit script to enable or disable the windows 7 high contrast mode.

When I use this command in cmd.exe :

sethc 251

it enables or disables the high contrast mode properly.

But if I use:

Run("sethc 251")
run("C:\Windows\System32\sethc.exe 251")
Shellexecute("C:\Windows\System32\sethc.exe", "251")
RunWait(@ComSpec & " /c " & "sethc.exe 251")

the confirmation window shows up but if I press "yes", nothing happens.

I also tried with #requireadmin but same problem.

I tried launching a bat file that runs sethc 251 with autoit but once again, the window shows up but pressing OK does nothing.

Any ideas?

Thanks!

Edited August 20, 2013 by Neutro

[dragan]

How about this:
 

#RequireAdmin
Local $RunDLLexe = 'rundll32.exe'
Local $Parameters = @WindowsDir & '\system32\shell32.dll,Control_RunDLL ' & _
                    @WindowsDir & '\system32\desk.cpl desk,@Themes /Action:OpenTheme /file:"' & _
                    @WindowsDir & '\Resources\Ease of Access Themes\hc1.theme"'
ShellExecuteWait($RunDLLexe, $Parameters, @SystemDir)
Local $winClass = "[CLASS:CabinetWClass]"
WinWait($winClass, '', 5)
If NOT @error then WinClose($winClass)

[Neutro]

That works perfectly, thanks a lot dragan!

[mLipok]

How about this:

#RequireAdmin
Local $RunDLLexe = 'rundll32.exe'
Local $Parameters = @WindowsDir & '\system32\shell32.dll,Control_RunDLL ' & _
                    @WindowsDir & '\system32\desk.cpl desk,@Themes /Action:OpenTheme /file:"' & _
                    @WindowsDir & '\Resources\Ease of Access Themes\hc1.theme"'
ShellExecuteWait($RunDLLexe, $Parameters, @SystemDir)
Local $winClass = "[CLASS:CabinetWClass]"
WinWait($winClass, '', 5)
If NOT @error then WinClose($winClass)

 

You can provide a similar example, but for the composition "Windows Classic" ?

[dragan]

just replace hc1.theme with classic.theme, like this:

@WindowsDir & '\Resources\Ease of Access Themes\classic.theme"'

And to restore back to aero, this line:

@WindowsDir & '\Resources\Ease of Access Themes\hc1.theme"'

should look like this:

@WindowsDir & '\Resources\Themes\aero.theme"'

Edited August 21, 2013 by dragan

[mLipok]

Do You, give me your system parameters.

 

Mine is this: Win7Pro 64bit.

 

ps.

Your example for me not to work properly.

I have corrected it, I want it to still work out and to share results.

But first I would like to know what your computer stations that will allow me to prepare a solution.

[mLipok]

I made a few changes.

The script is not yet complete and fully tested.

But I think it's worth it right to share.

Maybe someone will pay attention to any errors or additional options

expandcollapse popup

#RequireAdmin
_ChangeWindowsThem('classic')
Func _ChangeWindowsThem($sTheme) ; like 'basic' or 'classic' or 'hcblack' or 'hcwhite' or 'hc1' or 'hc2'
    Local $RunDLLexe = 'rundll32.exe'
    Local $hResourceDir = ''
    Local $sResourceName = ''
    Local $hResource = ''
    Switch @OSVersion
        Case "WIN_7"
            $hResourceDir = @WindowsDir & '\Resources\Ease of Access Themes\'
            Switch $sTheme
                Case "classic"
                    $sResourceName = 'classic.theme'
                Case Else
                    Return -1
            EndSwitch
        Case "WIN_XP"
            $hResourceDir = @WindowsDir & '\Resources\Themes\'
            Switch $sTheme
                Case "classic"
                    $sResourceName = 'Windows Classic.theme'
                Case Else
                    Return -1
            EndSwitch
        Case Else
            Return -1
    EndSwitch

    Local $Parameters = @WindowsDir & '\system32\shell32.dll,Control_RunDLL ' & _
            @WindowsDir & '\system32\desk.cpl desk,@Themes /Action:OpenTheme /file:"' & _
            $hResourceDir & $sResourceName & '"'

;~ "c:\windows\Resources\Ease of Access Themes\classic.theme"
    AdlibRegister("MyAdlib")
    ShellExecuteWait($RunDLLexe, $Parameters, @SystemDir)
    AdlibUnRegister("MyAdlib")
EndFunc   ;==>_ChangeWindowsThem

Func MyAdlib()
    Local $winClass = "[TITLE:Właściwości: Ekran; CLASS:#32770]" ; Here you can enter the name of the properties window according to the language which is set in windows. In my case it is Polish.
    If WinExists($winClass) = 1 Then
        ControlClick($winClass, '', '[CLASS:Button; TEXT:OK]')
    EndIf
EndFunc   ;==>MyAdlib