Report Help file errors here (Part 2)

Jos · July 16, 2013

>Continuation of this topic Edited August 17, 2013 by Melba23

jchd · July 16, 2013

AZJIO,

A bit off topic but I believe you can benefit from the idea:

Local $str = "Je lis et je parle françaisຂ້ອຍອ່ານຂ້ອຍຂຽນພາສາລາວאני קורא ומדבר עבריתநான் தமிழ் படிக்க மற்றும் பேசЯ читал и говорить на русском"

Local $pat[5] = [ _
    "((?:[\p{Cyrillic}]\s?)+)", _
    "((?:[\p{Latin}]\s?)+)", _
    "((?:[\p{Lao}]\s?)+)", _
    "((?:[\p{Hebrew}]\s?)+)", _
    "((?:[\p{Tamil}]\s?)+)" _
]

Local $res
For $i = 0 to UBound($pat) - 1
    $res = StringRegExp($str, $pat[$i], 1)
    MsgBox(0, "", $str & @LF & $pat[$i] & @LF & $res[0])
Next

Works with the latest beta only.

guinness · July 17, 2013

So that isn't for me?

guinness · July 17, 2013

Completed -

guinness · July 17, 2013

Completed the following:

- AZJIO

- Melba23

- ChristophX086

- AZJIO

I actually will take a look at your brackets function, as this might be useful to me. The MsgBox I did myself by converting MsgBox(4096, -> MsgBox($MB_SYSTEMMODAL,.

- AZJIO

guinness · July 17, 2013

AZJIO,

Nice code for the brackets. I just ran it on the txt files and found not all the UDFs were correctly formatted. Thanks.

Edit: Here is the code I used to change the MsgBox constants.

#include <APIConstants.au3>
#include <Array.au3>
#include <WinAPIEx.au3>

Global $ASCII_BEL = Chr(7)

Local $aSearch = _FileSearch(@ScriptDir, '*.au3')
For $i = 1 To $aSearch[0]
    MsgBoxZap($aSearch[$i])
Next

Func MsgBoxZap($sFilePath)
    Local Const $PARSE_UNIQUEID = 'WGKJZXKZIVN', _
            $sStringsAfter = '_' & $PARSE_UNIQUEID & '_STRINGS', $sStringsBefore = 'STRINGS_' & $PARSE_UNIQUEID & '_'

    Local $sData = FileRead($sFilePath)
    If StringRegExp($sData, 'MsgBox\(\d+') = 0 Then Return False

    ; Find includes in the script.
    Local $sIncludeString = ''
    _GetIncludes($sFilePath, $sData, $sIncludeString)
    $sData = FileRead($sFilePath)

    ; Remove blanks lines at the end of file.
    $sData = StringRegExpReplace($sData, '^\v+', '')

    Local $iIncludeCount = UBound(StringRegExp($sData, '(?im)^#include\h*[<"'']', 3))

    ; Parsing Au3 Script strings.
    Local $aStrings = 0, _
            $hStrings = 0, _
            $sStringsPattern = '(([''"])\V*?\2)'
    _AssociativeArray_Startup($hStrings, True)
    __PreProcessor_SRE($sData, $aStrings, $hStrings, $sStringsPattern, $sStringsBefore, $sStringsAfter)

    ; Parsing Au3 Script comments.
    Local Const $sCommentsBefore = 'COMMENTS_' & $PARSE_UNIQUEID & '_', $sCommentsAfter = '_' & $PARSE_UNIQUEID & '_COMMENTS', _
            $sCommentsPattern = '(;[^\r\n]*)'
    Local $aComments = 0, _
            $hComments = 0
    _AssociativeArray_Startup($hComments, True)
    __PreProcessor_SRE($sData, $aComments, $hComments, $sCommentsPattern, $sCommentsBefore, $sCommentsAfter, Default, '(?=[\r\n])', Default, 1)

    If Not _IsConstantsUDF($sIncludeString) Then ; Add Constants.au3 to the file.
        Local $aSplit = StringSplit($sData, @CRLF, 1), _
                $iIncludeCountUp = 0, $iInsert = 1
        If $iIncludeCount Then
            For $i = 1 To $aSplit[0]
                If StringRegExp($aSplit[$i], '(?im)^#include\h*') Then
                    $iIncludeCountUp += 1
                EndIf
                If $iIncludeCount = $iIncludeCountUp Then
                    $iInsert = $i + 1
                    ExitLoop
                EndIf
            Next
        Else
            $iInsert = 1
        EndIf
        _ArrayInsert($aSplit, $iInsert, '#include <Constants.au3>')
        _ArrayInsert($aSplit, $iInsert + 1, '')
        $aSplit[0] += 2
        $sData = ''
        For $i = 1 To $aSplit[0]
            $sData &= $aSplit[$i] & @CRLF
        Next
    EndIf

    $sData = StringReplace($sData, 'MsgBox(4096,', 'MsgBox($MB_SYSTEMMODAL,') ; Replace 4096 with $MB_SYSTEMMODAL.

    If @extended > 0 Then ; If replaced then write to the file.
        ; Remove double blank lines and trailing whitespace.
        $sData = StringRegExpReplace($sData, '(?m)^\s*[\r\n]{2,}', @CRLF)
        $sData = StringRegExpReplace($sData, '\h+(?=[\r\n])', '') ; Trailing whitespace. By DXRW4E.

        ; Converting comments back to their original state.
        __PreProcessor_SRE_Replace($sData, $aComments, $hComments)
        ; Converting strings back to their original state.
        __PreProcessor_SRE_Replace($sData, $aStrings, $hStrings)

        ; Remove blanks lines at the end of file.
        $sData = StringRegExpReplace($sData, '\v+$', '')
        Local $iFileEncoding = FileGetEncoding($sFilePath)
        _SetFile($sData, $sFilePath, $iFileEncoding + 1)

        ConsoleWrite($sFilePath & @CRLF)
    EndIf
    Return True
EndFunc   ;==>MsgBoxZap

#Obfuscator_Off
Func _AssociativeArray_Startup(ByRef $aArray, $fIsCaseSensitive = False) ; Idea from MilesAhead.
    $aArray = ObjCreate('Scripting.Dictionary')
    ObjEvent('AutoIt.Error', '__AssociativeArray_Error\\\')
    If IsObj($aArray) = 0 Then
        Return SetError(1, 0, 0)
    EndIf
    $aArray.CompareMode = Int(Not $fIsCaseSensitive)
EndFunc   ;==>_AssociativeArray_Startup
#Obfuscator_On

Func _FileSearch($sFilePath, $sFilter = '*.*')
    If _WinAPI_PathIsDirectory($sFilePath) = 0 Then
        Local Const $aError[2] = [1, $sFilePath]
        Return $aError
    EndIf

    $sFilePath = _WinAPI_PathAddBackslash($sFilePath)
    Local Const $iPID = Run(@ComSpec & ' /C DIR "' & $sFilePath & $sFilter & '" /B /A-D /S', $sFilePath, @SW_HIDE, $STDOUT_CHILD)
    Local $sOutput = ''
    While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then
            ExitLoop
        EndIf
    WEnd
    Return StringSplit(StringTrimRight(StringStripCR($sOutput), StringLen(@LF)), @LF)
EndFunc   ;==>_FileSearch

Func _GenerateUniqueStrings() ; By Beege, modified by guinness. 2011-2013.
    Local Static $fIsUniqueArray = False
    If Not $fIsUniqueArray Then
        $fIsUniqueArray = True
        Local Const $iSPUBound = 2
        Local $aArray = StringSplit('A|B|C|D|E|F|G|H|I|J|K|L|M|N|O|P|Q|R|S|T|U|V|W|X|Y|Z', '|', $iSPUBound)
    EndIf
    Local Static $aUnique = _ArrayCombinations($aArray, 4)
    Return $aUnique
EndFunc   ;==>_GenerateUniqueStrings

Func _GetIncludes($sFilePath, ByRef $sMerged, ByRef $sIncludeString)
    Local Static $iRecursionCall = 0, _
            $sIncludePath = _WinAPI_PathRemoveFileSpec(@AutoItExe) & '\Include', $sUserIncludePath = ''
    If Not $iRecursionCall Then
        _StripCommentLines($sMerged)
        _StripWhitespace($sMerged)
        _StripMerge($sMerged)

        If $sUserIncludePath = '' Then
            $sUserIncludePath = RegRead('HKEY_CURRENT_USER\SOFTWARE\AutoIt v3\AutoIt', 'Include')
            If $sUserIncludePath = '' Then
                $sUserIncludePath = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'Include')
            EndIf
            If Not ($sUserIncludePath = '') Then
                If StringLeft($sUserIncludePath, 1) == ';' Then
                    $sUserIncludePath = StringTrimLeft($sUserIncludePath, 1)
                EndIf
                If Not (StringRight($sUserIncludePath, 1) == ';') Then
                    $sUserIncludePath &= ';'
                EndIf
            EndIf
        EndIf
        $sIncludeString &= $sFilePath & '|'
    EndIf
    Local Const $sFileFolder = _WinAPI_PathRemoveFileSpec($sFilePath) ; StringLeft($sFilePath, StringInStr($sFilePath, '\', Default, -1) - 1)
    Local $fFileExists = False, _
            $iAutoItInclude = 1, _
            $sFilePathNonStripped = ''
    Local Const $aFilePaths[2] = [$sFileFolder, $sIncludePath]
    Local $sData = FileRead($sFilePath)
    Local $aArray = StringRegExp($sData, '(?im)^#include\h*([<"''][^*?"''<>|]+)', 3)

    For $i = 0 To UBound($aArray) - 1
        Switch StringLeft($aArray[$i], 1)
            Case '<' ; AutoIt includes, Registry, Relative path.
                $iAutoItInclude = 1
            Case '''', '"' ; Relative path, Registry, AutoIt includes.
                $iAutoItInclude = 0
        EndSwitch
        $sFilePathNonStripped = $aArray[$i]
        $aArray[$i] = StringStripWS(StringTrimLeft($aArray[$i], 1), $STR_STRIPLEADING + $STR_STRIPTRAILING)

        $fFileExists = FileExists($aArray[$i])
        If Not (StringMid($aArray[$i], 2, 2) == ':\') Or Not $fFileExists Then
            $fFileExists = FileExists($aFilePaths[$iAutoItInclude] & '\' & $aArray[$i])
            If $fFileExists Then
                $aArray[$i] = $aFilePaths[$iAutoItInclude] & '\' & $aArray[$i]
            Else
                $aIncludesSplit = StringSplit($sUserIncludePath & $aFilePaths[Int(Not $iAutoItInclude)], ';')
                For $j = 1 To $aIncludesSplit[0]
                    $aIncludesSplit[$j] = _WinAPI_PathRemoveBackslash($aIncludesSplit[$j])
                    $aArray[$i] = $aIncludesSplit[$j] & '\' & $aArray[$i]
                    $aArray[$i] = _WinAPI_GetFullPathName($aArray[$i])
                    $fFileExists = FileExists($aArray[$i])
                    If $fFileExists Then
                        ExitLoop
                    EndIf
                Next
            EndIf
        EndIf

        If $fFileExists And Not StringInStr('|' & $sIncludeString, '|' & $aArray[$i] & '|') Then
            $sData = FileRead($aArray[$i])
            _StripCommentLines($sData)
            _StripWhitespace($sData)
            _StripMerge($sData)
            $sMerged = StringRegExpReplace($sMerged, '(?im:^#include\h*' & $sFilePathNonStripped & '[>"''])', $ASCII_BEL, 1)
            If @extended Then
                ; ConsoleWrite('Insert: ' & _WinAPI_PathStripPath($aArray[$i]) & @CRLF)
                $sMerged = StringRegExpReplace($sMerged, $ASCII_BEL, StringReplace($sData, '\', '\\') & @CRLF)
            Else
                ; ConsoleWrite('Add: ' & _WinAPI_PathStripPath($aArray[$i]) & @CRLF)
                $sMerged &= $sData & @CRLF
            EndIf
            $sData = ''

            $sIncludeString &= $aArray[$i] & '|'
            $iRecursionCall += 1
            _GetIncludes($aArray[$i], $sMerged, $sIncludeString)
            $iRecursionCall -= 1
        EndIf
    Next
    If Not $iRecursionCall Then
        $sIncludeString = StringTrimLeft($sIncludeString, StringInStr($sIncludeString, '|', Default, 1)) ; Remove the main script file.
        $sIncludeString = StringTrimRight($sIncludeString, StringLen('|'))
        _StripRedundantMergedDirectives($sMerged)
        _StripEmptyLines($sMerged)
    EndIf
    Return Not ($sIncludeString == '')
EndFunc   ;==>_GetIncludes

Func _IsConstantsUDF($sIncludeString)
    Local Const $sIncludePath = _WinAPI_PathRemoveFileSpec(@AutoItExe) & '\Include'
    Return StringInStr('|' & $sIncludeString & '|', '|' & $sIncludePath & '\Constants.au3|') > 0
EndFunc   ;==>_IsConstantsUDF

Func _SetFile($sString, $sFile, $iOverwrite = 0)
    Local $hFileOpen
    $hFileOpen = FileOpen($sFile, $iOverwrite + 1)
    FileWrite($hFileOpen, $sString)
    FileClose($hFileOpen)
    If @error Then
        Return SetError(1, 0, $sString)
    EndIf
    Return $sString
EndFunc   ;==>_SetFile

Func _StringRegExpMetaCharacters($sString)
    Return StringRegExpReplace($sString, '([].|*?+(){}^$\\[])', '\\\1')
EndFunc   ;==>_StringRegExpMetaCharacters

Func _StripCommentLines(ByRef $sData, $sReplace = Default)
    If $sReplace = Default Then
        $sReplace = ''
    EndIf
    $sData = StringRegExpReplace($sData, '(?m)^((?:[^''";]*([''"]).*?\2)*[^;]*)(?:;?[^\r\n]*)', '\1') ; By ProgAndy. http://www.autoitscript.com/forum/topic/108728-stripcomments/#entry765712
    $sData = StringRegExpReplace($sData, '(?ims:^#(?:cs|comments-start)(?!\w).+?#(?:ce|comments-end)[^\r\n]*[\r\n]{1,2})', $sReplace) ; Strip comment blocks to avoid unintended matches. By Robjong
    $sData = StringRegExpReplace($sData, '(?im:^#(?:(?:end)?region)(?!\w)[^\r\n]+[\r\n]{1,2})', $sReplace) ; By DXRW4E. Fixed by guinness.
    $sData = StringRegExpReplace($sData, '(?im:^#(?!autoit|force(def|ref)|ignorefunc|include(-once)?|' & _
            'noautoit|notrayicon|onautoitstartregister|obfuscator|requireadmin|tidy)[^\r\n]*[\r\n]{1,2})', $sReplace) ; Strip user custom comments. By guinness.
EndFunc   ;==>_StripCommentLines

Func _StripEmptyLines(ByRef $sData)
    $sData = StringRegExpReplace($sData, '(?m:^\s*[\r\n])', '') ; Empty lines. By guinness.
EndFunc   ;==>_StripEmptyLines

Func _StripMerge(ByRef $sData)
    $sData = StringRegExpReplace($sData, '(?:_\h*[\r\n]{1,2}\h*)', '') ; Merge continuation lines that use _. By guinness.
EndFunc   ;==>_StripMerge

Func _StripRedundantMergedDirectives(ByRef $sData)
    $sData = StringRegExpReplace($sData, '(?im:^#(autoit3wrapper|include(-once)?|obfuscator_ignore_variables|obfuscator_parameters|tidy)[^\r\n]*[\r\n]*)', '')
EndFunc   ;==>_StripRedundantMergedDirectives

Func _StripWhitespace(ByRef $sData)
    $sData = StringRegExpReplace($sData, '\h+(?=[\r\n])', '') ; Trailing whitespace. By DXRW4E.
    $sData = StringRegExpReplace($sData, '[\r\n]\h+', @LF) ; Strip leading whitespace. By DXRW4E.
EndFunc   ;==>_StripWhitespace

Func __PreProcessor_SRE(ByRef $sData, ByRef $aArray, ByRef $hStrings, $sSREPattern, $sStringsBefore, $sStringsAfter, $sCheckBefore = Default, $sCheckAfter = Default, $iIndex = Default, $iStep = Default, $fExitFirstRound = Default)
    Local Enum $eStrings_Data, $eStrings_Index, $eStrings_Key, $eStrings_Max

    $iIndex = Int($iIndex)
    If $iIndex <= 0 Then
        $iIndex = 1
    EndIf
    If $iStep = Default Then
        $iStep = 2
    EndIf
    If $sCheckAfter = Default Then $sCheckAfter = ''
    If $sCheckBefore = Default Then $sCheckBefore = ''

    Local $aSRE = 0, $aUnique = _GenerateUniqueStrings(), _
            $aStrings[1][$eStrings_Max] = [[0, $eStrings_Max]], _
            $iCount = 1

    Local $hStringsTemp = 0
    _AssociativeArray_Startup($hStringsTemp, True)

    While 1
        $aSRE = StringRegExp($sData, $sSREPattern, 3)
        If UBound($aSRE) = 0 Then ExitLoop

        ReDim $aStrings[$aStrings[0][0] + UBound($aSRE) + 1][$aStrings[0][1]]
        $iCount = $aStrings[0][0] + 1
        For $i = 0 To UBound($aSRE) - 1 Step $iStep
            If Not $hStringsTemp.Exists($aSRE[$i]) Then
                $hStringsTemp($aSRE[$i]) = $aSRE[$i]
                $aStrings[0][0] += 1
                $aStrings[$aStrings[0][0]][$eStrings_Data] = $aSRE[$i]
                $aStrings[$aStrings[0][0]][$eStrings_Index] = 0
                $aStrings[$aStrings[0][0]][$eStrings_Key] = ''
            EndIf
        Next
        $hStringsTemp = 0
        _AssociativeArray_Startup($hStringsTemp, True)

        For $i = $iCount To $aStrings[0][0]
            $aStrings[$i][$eStrings_Index] = $aUnique[$iIndex]
            $aStrings[$i][$eStrings_Key] = $sStringsBefore & $aStrings[$i][$eStrings_Index] & $sStringsAfter

            ; Replace the quote strings with temporary strings.
            ; '\Q' & $aStrings[$i][$eStrings_Data] & '\E'
            $sData = StringRegExpReplace($sData, $sCheckBefore & _StringRegExpMetaCharacters($aStrings[$i][$eStrings_Data]) & $sCheckAfter, $aStrings[$i][$eStrings_Key])
            If @extended Then
                $hStrings($aStrings[$i][$eStrings_Key]) = $aStrings[$i][$eStrings_Data]
            Else
                $sData = StringReplace($sData, $aStrings[$i][$eStrings_Data], $aStrings[$i][$eStrings_Key]) ; For replacing \Q and \E.
                If @extended Then
                    $hStrings($aStrings[$i][$eStrings_Key]) = $aStrings[$i][$eStrings_Data]
                Else
                    $aStrings[$i][$eStrings_Data] = ''
                    $aStrings[$i][$eStrings_Index] = 0
                    $aStrings[$i][$eStrings_Key] = ''
                EndIf
            EndIf
            $iIndex += 1
        Next
        If $fExitFirstRound Then
            ExitLoop
        EndIf
    WEnd
    $aSRE = 0

    ReDim $aStrings[$aStrings[0][0] + 1][$aStrings[0][1]]
    $aArray = $aStrings
    Return $iIndex
EndFunc   ;==>__PreProcessor_SRE

Func __PreProcessor_SRE_Replace(ByRef $sData, ByRef $aStrings, ByRef $hStrings)
    Local Enum $eStrings_Data, $eStrings_Index, $eStrings_Key, $eStrings_Max
    #forceref $eStrings_Data, $eStrings_Max

    For $i = $aStrings[0][0] To 1 Step -1
        If $aStrings[$i][$eStrings_Index] And $hStrings.Exists($aStrings[$i][$eStrings_Key]) Then
            $sData = StringReplace($sData, $aStrings[$i][$eStrings_Key], $hStrings($aStrings[$i][$eStrings_Key]))
        EndIf
    Next
EndFunc   ;==>__PreProcessor_SRE_Replace

Edited July 17, 2013 by guinness

guinness · July 17, 2013

Completed the following:

- AZJIO

- BrewManNH

- AZJIO (that last part (IE functions) I didn't do as this has changed.)

- AZJIO

_WinAPI_CreateEvent
_WinAPI_SetEvent
_WinAPI_WaitForMultipleObjects
_WinAPI_WaitForSingleObject
These functions are dependent on each other?
###Related###
_WinAPI_GetParent
_WinAPI_SetParent
###Related###
_WinAPI_SetFont
_WinAPI_CreateFont
_WinAPI_CreateFontIndirect
###Related###
_WinAPI_SetCapture
_WinAPI_ReleaseCapture

You need to be clear please.

- Not Done. Upload the fixed example please.

guinness · July 17, 2013

Pages 17 to 19 in the last thread are left to check, ammend and commit.

AZJIO · July 17, 2013

guinness

should be corrected everything

AZJIO · July 17, 2013

_WinAPI_CreateEvent
_WinAPI_SetEvent
_WinAPI_WaitForMultipleObjects
_WinAPI_WaitForSingleObject
These functions are dependent on each other?
###Related###
_WinAPI_GetParent
_WinAPI_SetParent
###Related###
_WinAPI_SetFont
_WinAPI_CreateFont
_WinAPI_CreateFontIndirect
###Related###
_WinAPI_SetCapture
_WinAPI_ReleaseCapture

_WinAPI_GetParent

_WinAPI_SetParent

etc

Edited July 17, 2013 by AZJIO

guinness · July 17, 2013

guinness

should be corrected everything

Ha funny, you should see what I was about to post!

guinness · July 17, 2013

Completed the following:
- AZJIO
?do=embed' frameborder='0' data-embedContent>>?do=embed' frameborder='0' data-embedContent> - AZJIO
?do=embed' frameborder='0' data-embedContent>>?do=embed' frameborder='0' data-embedContent> - AZJIO

Just went through '?do=embed' frameborder='0' data-embedContent>> and most if not ALL problems have been fixed.
So, AZJIO I would say 90% of the issues you reported have been fixed so far. Thanks for reporting.

AZJIO,

Do you still have this >> ?p=985106'>?p=985106

Edited July 18, 2013 by guinness

guinness · July 17, 2013

_WinAPI_GetParent
Related
_WinAPI_GetAncestor
Related
_WinAPI_SetParent, _WinAPI_GetAncestor

etc

All I changed was _WinAPI_GetParent. Please be specific with what I should change please.

AZJIO · July 17, 2013

#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $iLabel, $msg, $bToggle = False

    GUICreate("My GUI position") ; will create a dialog box that when displayed is centered

    GUISetFont(16)
    $iLabel = GUICtrlCreateLabel("my moving label", 10, 20)

    GUISetState()

    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then Exit
        $bToggle = Not $bToggle
        If $bToggle Then
            GUICtrlSetPos($iLabel, 20, 20)
        Else
            GUICtrlSetPos($iLabel, 20, 30)
        EndIf
        Sleep(60)
    WEnd
EndFunc

Example2()

Func Example2()
    Local $iOldOpt, $icon1, $icon2, $hGUI, $a = 0, $b = 0
    $iOldOpt = Opt("GUICoordMode", 1)

    $hGUI = GUICreate("My GUI icon Race", 350, 74, -1, -1)
    GUICtrlCreateLabel("", 331, 0, 1, 74, 5)
    $icon1 = GUICtrlCreateIcon(@ScriptDir & '\Extras\dinosaur.ani', -1, 0, 0, 32, 32)
    $icon2 = GUICtrlCreateIcon(@ScriptDir & '\Extras\horse.ani', -1, 0, 40, 32, 32)

    GUISetState(@SW_SHOW)

    While ($a < 300) And ($b < 300)
        $a += Random(0, 1, 1)
        $b += Random(0, 1, 1)
        GUICtrlSetPos($icon1, $a, 0)
        GUICtrlSetPos($icon2, $b, 40)
        Sleep(10)
    WEnd
    Opt("GUICoordMode", $iOldOpt)
    If $a > $b Then
        MsgBox(0, 'Race results', 'The dinosaur won', 0, $hGUI)
    Else
        MsgBox(0, 'Race results', 'The horse won', 0, $hGUI)
    EndIf
EndFunc   ;==>Example2

Edited July 17, 2013 by AZJIO

guinness · July 17, 2013

I understood that much, I meant what functions? Like what you did >here in the spoiler tags was perfect, as I created a script to automate the process.

guinness · July 17, 2013

Added those examples as well.

AZJIO · July 17, 2013

http://my-soft-autoit.googlecode.com/files/Related.7z

Related.au3

#include <FileOperations.au3>

$sPath1 = @ScriptDir & '\txtLibFunctions'
$sPath2 = 'D:\autoit-docs-v3.3.9.7\autoit-docs-v3.3.9.7-src\autoit\english\txt2htm\txtLibFunctions'

$aFileList = _FO_FileSearch($sPath1, '*.txt*', True, 123, 2)
; _ArrayDisplay($aFileList)

$sOut = ''
$sOut1 = ''
$sOut2 = ''
$err = 0
$iCount = 0
For $i = 1 To $aFileList[0]
    $sText1 = FileRead($sPath1 & '\' & $aFileList[$i])
    $sText2 = FileRead($sPath2 & '\' & $aFileList[$i])
    $sText1 = StringRegExp($sText1, '(?s)###Related###\r\n([^\r\n]+)', 1)
    If @error Then ContinueLoop
    $sText2 = StringRegExp($sText2, '(?s).+?###Related###\r\n([^\r\n]+)', 1)
    If @error Then ContinueLoop
    ; MsgBox(0, '?', $sText1[0] &@CRLF&$sText2[0])
    If $sText1[0] <> $sText2[0] Then
        $aFileList[$i] = StringTrimRight($aFileList[$i], 4)
        $sOut1 &= $aFileList[$i] & @CRLF & $sText1[0] & @CRLF
        $sOut2 &= $aFileList[$i] & @CRLF & $sText2[0] & @CRLF
        $sOut &= $aFileList[$i] & @CRLF & $sText1[0] & @CRLF & $sText2[0] & @CRLF & @CRLF
        $iCount += 1
    EndIf
Next

; Записываем результирующий файл
$hFile = FileOpen(@ScriptDir & '\Out_Ru.txt', 2)
FileWrite($hFile, $sOut1)
FileClose($hFile)
$hFile = FileOpen(@ScriptDir & '\Out_v3.3.9.7.txt', 2)
FileWrite($hFile, $sOut2)
FileClose($hFile)
$hFile = FileOpen(@ScriptDir & '\Out_Ru+v3.3.9.7.txt', 2)
FileWrite($hFile, $sOut)
FileClose($hFile)
MsgBox(0, 'Done', 'Count = ' & $iCount, 2)

Edited July 17, 2013 by AZJIO

AZJIO · July 17, 2013

~~Return Value~~

None.

Remarks

None.

If sections empty, why them to add?

AZJIO,
Do you still have this >>

You need to copy the folder "menu" on the server. That's all.

For these functions, I made examples

_GUIToolTip_Activate
_GUIToolTip_AddTool
_GUIToolTip_Create
_GUIToolTip_DelTool
_GUIToolTip_GetBubbleHeight
_GUIToolTip_GetBubbleSize
_GUIToolTip_GetBubbleWidth
_GUIToolTip_GetDelayTime
_GUIToolTip_GetMargin
_GUIToolTip_GetMarginEx
_GUIToolTip_GetText
_GUIToolTip_GetTipBkColor
_GUIToolTip_GetTipTextColor
_GUIToolTip_GetToolCount
_GUIToolTip_SetDelayTime
_GUIToolTip_SetMargin
_GUIToolTip_SetMaxTipWidth
_GUIToolTip_SetTipBkColor
_GUIToolTip_SetTipTextColor
_GUIToolTip_SetTitle
_GUIToolTip_ToolExists
_GUIToolTip_TrackActivate
_GUIToolTip_TrackPosition
_GUIToolTip_UpdateTipText
_WinAPI_CopyIcon
_WinAPI_CreateBitmap
_WinAPI_CreateFontIndirect
_WinAPI_CreateSolidBitmap
_WinAPI_CreateSolidBrush
_WinAPI_CreateWindowEx
_WinAPI_DestroyWindow
_WinAPI_DrawEdge
_WinAPI_DrawFrameControl
_WinAPI_DrawIcon
_WinAPI_DrawIconEx
_WinAPI_EnableWindow
_WinAPI_FatalAppExit
_WinAPI_FillRect
_WinAPI_FindWindow
_WinAPI_FrameRect
_WinAPI_GetDeviceCaps
_WinAPI_GetLastError
_WinAPI_GetParent
_WinAPI_GetStockObject
_WinAPI_GetSysColorBrush
_WinAPI_GetSystemMetrics
_WinAPI_GetTextMetrics
_WinAPI_GetWindow
_WinAPI_GetWindowDC
_WinAPI_GetWindowHeight
_WinAPI_GetWindowLong
_WinAPI_GetWindowRect
_WinAPI_GetWindowText
_WinAPI_GetWindowThreadProcessId
_WinAPI_GetWindowWidth
_WinAPI_GetXYFromPoint
_WinAPI_GlobalMemoryStatus
_WinAPI_InProcess
_WinAPI_IsClassName
_WinAPI_IsWindow
_WinAPI_IsWindowVisible
_WinAPI_LoadBitmap
_WinAPI_LoadImage
_WinAPI_LoadLibrary
_WinAPI_LoadShell32Icon
_WinAPI_MAKELANGID
_WinAPI_MAKELCID
_WinAPI_MakeLong
_WinAPI_MessageBeep
_WinAPI_Mouse_Event
_WinAPI_MoveWindow
_WinAPI_MsgBox
_WinAPI_MulDiv
_WinAPI_MultiByteToWideChar
_WinAPI_MultiByteToWideCharEx
_WinAPI_OpenProcess
_WinAPI_PointFromRect
_WinAPI_PostMessage
_WinAPI_PrimaryLangId
_WinAPI_PtInRect
_WinAPI_ReadProcessMemory
_WinAPI_RectIsEmpty
_WinAPI_SetFocus
_WinAPI_SetFont
_WinAPI_SetLastError
_WinAPI_SetWindowLong
_WinAPI_SetWindowText
_WinAPI_ShowCursor
_WinAPI_ShowError
_WinAPI_ShowMsg
_WinAPI_ShowWindow
_WinAPI_SubLangId
_WinAPI_SystemParametersInfo
_WinAPI_TwipsPerPixelX
_WinAPI_TwipsPerPixelY
_WinAPI_WideCharToMultiByte
_WinAPI_WriteProcessMemory

Edited July 17, 2013 by AZJIO

guinness · July 17, 2013

http://my-soft-autoit.googlecode.com/files/Related.7z

Related.au3

#include <FileOperations.au3>

$sPath1 = @ScriptDir & '\txtLibFunctions'
$sPath2 = 'D:\autoit-docs-v3.3.9.7\autoit-docs-v3.3.9.7-src\autoit\english\txt2htm\txtLibFunctions'

$aFileList = _FO_FileSearch($sPath1, '*.txt*', True, 123, 2)
; _ArrayDisplay($aFileList)

$sOut = ''
$sOut1 = ''
$sOut2 = ''
$err = 0
$iCount = 0
For $i = 1 To $aFileList[0]
    $sText1 = FileRead($sPath1 & '\' & $aFileList[$i])
    $sText2 = FileRead($sPath2 & '\' & $aFileList[$i])
    $sText1 = StringRegExp($sText1, '(?s)###Related###\r\n([^\r\n]+)', 1)
    If @error Then ContinueLoop
    $sText2 = StringRegExp($sText2, '(?s).+?###Related###\r\n([^\r\n]+)', 1)
    If @error Then ContinueLoop
    ; MsgBox(0, '?', $sText1[0] &@CRLF&$sText2[0])
    If $sText1[0] <> $sText2[0] Then
        $aFileList[$i] = StringTrimRight($aFileList[$i], 4)
        $sOut1 &= $aFileList[$i] & @CRLF & $sText1[0] & @CRLF
        $sOut2 &= $aFileList[$i] & @CRLF & $sText2[0] & @CRLF
        $sOut &= $aFileList[$i] & @CRLF & $sText1[0] & @CRLF & $sText2[0] & @CRLF & @CRLF
        $iCount += 1
    EndIf
Next

; Записываем результирующий файл
$hFile = FileOpen(@ScriptDir & '\Out_Ru.txt', 2)
FileWrite($hFile, $sOut1)
FileClose($hFile)
$hFile = FileOpen(@ScriptDir & '\Out_v3.3.9.7.txt', 2)
FileWrite($hFile, $sOut2)
FileClose($hFile)
$hFile = FileOpen(@ScriptDir & '\Out_Ru+v3.3.9.7.txt', 2)
FileWrite($hFile, $sOut)
FileClose($hFile)
MsgBox(0, 'Done', 'Count = ' & $iCount, 2)

Thanks, but as I said before I already created a script, I wasn't asking for you to create one. Though nice you did.

What text files should I use? I guess the ones without My in them?

Edited July 17, 2013 by guinness

guinness · July 17, 2013

If sections empty, why them to add?

I don't know. That's what the the creators of the build scripts decided.

You need to copy the folder "menu" on the server. That's all.

OK, I'm quite sure what you mean here?

For these functions, I made examples

Great, but are they in English?

Sign In

Report Help file errors here (Part 2)

Recommended Posts

Jos

Top Posters In This Topic

Top Posters In This Topic

Popular Posts

JLogan3o13

guinness

trancexx

Posted Images

jchd

guinness

guinness

guinness

guinness

guinness

guinness

AZJIO

AZJIO

guinness

guinness

guinness

AZJIO

guinness

guinness

AZJIO

AZJIO

guinness

guinness

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta