Delete set of lines from file ?

[COD3369]

i want to delete some lines from a text file.

i want to delete line number 1 to 57

any idea how?

[FireFox]

Hi,

This question was asked a dozen of times so yes you can.

Br, FireFox.

[Melba23]

verma123,

You could read the file into an array with _FileReadToArray and then write it back using FileWriteFromArray but setting the $iBase parameter to 58.

Or use_FileWriteToLine in a loop to delete the required lines - in this case you would either need to loop from line #57 up or continually delete just the first line.

M23

[czardas]

_FileWriteToLine() is the function you need.

Too late. M23 got there before me.

Edited August 6, 2013 by czardas

[COD3369]

Melba23 any example ?

1. autoit is cool
2. autoit is cool
3 autoit is cool
4 autoit is cool
5 autoit is cool
6 autoit is cool
7 autoit is cool
8 autoit is cool
9 autoit is cool

delete line number 4 to 7

[Melba23]

verma123,

And what have you tried that has not worked? I gave you enough hints.

M23

[COD3369]

#include <File.au3>
_FileReadToArray( @ScriptDir & "\log.html", $acontent

for $i = 1 to 56  

_FileWriteToLine( @ScriptDir & "\log.html", , "" , 0 )
Next

[Danyfirex]

Hi. maybe something like this.

#include <File.au3>
#include <Array.au3>

Local $aRecords
If Not _FileReadToArray("1.txt", $aRecords) Then
    MsgBox(4096, "Error", " Error reading log to Array     error:" & @error)
    Exit
EndIf
For $x = 1 To $aRecords[0]
    MsgBox(0, 'Record:' & $x, $aRecords[$x])
Next


_ArrayDelete($aRecords,4)
_ArrayDelete($aRecords,7-1)

_FileWriteFromArray("2.txt",$aRecords,1)

saludos

Edited August 6, 2013 by Danyfirex

[Melba23]

verma123,

And does that look like what I suggested? Go and read again what I wrote - I gave you 2 possible solutions and you have mixed them up in the same script.

First Solution: Read the file into an array and then rewrite it but not from the same start point.

Second Solution: Loop through the file using _FileWriteToLine and delete the lines in a loop. Have you even looked at the _FileWriteToLine page in the Help file? Does the syntax you have used look as if it will work? Where is the $iLine parameter? Are you sure that the $fOverWrite parameter should be set to 0 if you want to delete lines?

Over to you for a better effort!

M23

[Melba23]

verma123,

It is not that difficult. Save those few lines as "Cool.txt" and then run this:

#include <File.au3>
#include <Array.au3>

Local $aLines
_FileReadToArray("Cool.txt", $aLines)

; Delete first 3 lines
_FileWriteFromArray("Cool-Array-Start.txt", $aLines, 4)

; Delete lines from middle
For $i = 7 to 4 Step -1
    _ArrayDelete($aLines, $i)
Next
_FileWriteFromArray("Cool-Array-Mid.txt", $aLines, 1)

; Delete lines in a loop
FileCopy("Cool.txt", "Cool_WriteToLine.txt", $FC_OVERWRITE)
For $i = 7 to 4 Step -1
    _FileWriteToLine("Cool_WriteToLine.txt", $i, "", 1)
Next

I hope all that is clear enough for you to develop it to fit your requirements.

M23

[Malkey]

Here is a regular expression replace method.

Opt("WinTitleMatchMode", 2) ;1=start, 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase

; ------------- Create File --------------
Local $sFileName = "Test9Lines.txt"
Local $sFileContents
For $i = 1 To 9
    $sFileContents &= $i & ". autoit is cool" & @CRLF
Next
If FileExists($sFileName) Then
    FileDelete($sFileName)
EndIf
FileWrite($sFileName, StringTrimRight($sFileContents, 2))
ShellExecute($sFileName)
WinWaitActive($sFileName)
; ----------> End of Create File ---------

Local $sNewFileName = "TestMinusLines.txt"
Local $iStart = 4
Local $iTo = 7

If $iStart < 1 Then $iStart = 1 ; First line is line #1.
If FileExists($sNewFileName) Then
    FileDelete($sNewFileName)
EndIf
FileWrite($sNewFileName, StringRegExpReplace(FileRead($sFileName), "(?s)((\V*\v*){" & $iStart - 1 & "})(\V+\v*){" & ($iTo - $iStart + 1) & "}(.*$)", "\1\4"))

ShellExecute($sNewFileName)

;Tidy up files
WinWaitActive($sNewFileName)
FileDelete($sFileContents)
FileDelete($sNewFileName)

[Melba23]

Malkey,

I was having an internal wager whether it would be you or jchd who posted an SRE solution - my left hand won!

M23

[jchd]

I was away.

[COD3369]

Guys you rocked !!

Melba23 Malkey Danyfirex

 

its working flawlessly thank you very much guys love you all

[iahngy]

Hi Malky,

in this line,

FileWrite($sNewFileName, StringRegExpReplace(FileRead($sFileName), "(?s)((\V*\v*){" & $iStart - 1 & "})(\V+\v*){" & ($iTo - $iStart + 1) & "}(.*$)", "\1\4"))

what does {" & $iStart - 1 & "} mean?

and

((\V*\v*){" & $iStart - 1 & "})  ...does the outside parenthesis represent for \2 ?

[AZJIO]