_IsPressed problems

[Sparky90ful]

Hy all i have a problem with this code 

While 1
    If _IsPressed("64", $hDLL) Then
        Sleep(100)
          While _IsPressed("65", $hDLL) = 0
           Sleep(3050)
            Send ("{NUMPAD6}")
            Sleep(100)
            Send ("{NUMPAD4}")
        WEnd

        EndIf

Sleep(100)

WEnd

When i press numpad 5 the script doesn't exit from loop is the same if

While 1
    If _IsPressed("64", $hDLL) Then
        Sleep(100)

        Do 
           Sleep(3050)
            Send ("{NUMPAD6}")
            Sleep(100)
            Send ("{NUMPAD4}")
        Until _IsPressed("65", $hDLL) = 1

        EndIf

Sleep(100)

WEnd

[Melba23]

Sparky90ful,

Because of the long Sleep times when your script is unresponsive you have to keep the keys pressed untitl they are checked - this makes it look as if you are stuck in the loop. Better to check as the script waits like this:

expandcollapse popup

#include <Misc.au3>

HotKeySet("{ESC}", "On_Exit")

$hDLL = DllOpen("user32.dll")

While 1
    If _IsPressed("64", $hDLL) Then

        ConsoleWrite("Starting loop" & @CRLF)

        Sleep(100)

        While 1
            $nBegin = TimerInit() ; get a timestamp
            While TimerDiff($nBegin) < 3050 ; Until the delay expires
                If _IsPressed("65", $hDLL) = 1 Then ; Check for the key
                    ExitLoop 2 ; Exit both loops
                EndIf
            WEnd
            ConsoleWrite("NP6" & @CRLF)
            ;Send ("{NUMPAD6}")
            $nBegin = TimerInit()
            While TimerDiff($nBegin) < 100
                If _IsPressed("65", $hDLL) = 1 Then
                    ExitLoop 2
                EndIf
            WEnd
            ConsoleWrite("NP4" & @CRLF)

        WEnd

        ConsoleWrite("Ending Loop" & @CRLF)
    EndIf

    Sleep(100)

WEnd

Func On_Exit()
    DllClose($hDLL)
    Exit
EndFunc   ;==>On_Exit

That works fine for me.  How about you?

M23

[Sparky90ful]

yes it is working but i am a noob in programing it would take some time to understand but if i want to do this in a notepad?Like the script write 6 and 4 Thanks very much for help

Edited August 2, 2013 by Sparky90ful

[Melba23]

Sparky90ful,

I just used the ConsoleWrite lines to show what was happening. All you need do is remove them and uncomment the original Send lines - then you can paste the key strokes into "Notepad" as you wish.

M23

[Sparky90ful]

Thanks , :thumbsup: