_FileInUse to check if file is in used or not (work on both local and network drive)

[michaelslamet]

This is my first thread in Example, so please easy with me

I found a function by Rogue5099 to check if a file is in used or not, but it only working great when

checking a file in local drive. I make a little change so it can also report a correct "file in used" status

for files that on network.

I hope this script can benefit for every of us

expandcollapse popup

$fFile = "c:\myscript.exe"

If _FileInUse($fFile) = 0 then
    Msgbox(64, "Info", $fFile & " is NOT in used")
Else
    Msgbox(64, "Info", $fFile & " is in used")
EndIf


;===============================================================================
;
; Function Name:    _FileInUse()
; Description:      Checks if file is in use
; Parameter(s):     $sFilename = File name
; Return Value(s):  1 - file in use (@error contains system error code)
;                   0 - file not in use or file not exists
; Create by:         Rogue5099
; Modified by:        michaelslamet
;
;===============================================================================

Func _FileInUse($sFilename)
    ;note: dword", 0x40000000, _  ---> jalan bagus jika $sFilename ada di hdd local, tapi jika $sFilename ada di network drive, gunakan dword", 0x80000000, _
    Local $aRet, $hFile
    If StringUpper(DriveGetType($sFilename)) = "NETWORK" Then
        $aRet = DllCall("Kernel32.dll", "hwnd", "CreateFile", _
                                    "str", $sFilename, _ ;lpFileName
                                    "dword", 0x80000000, _ ;dwDesiredAccess = GENERIC_READ
                                    "dword", 0x00000004, _ ;dwShareMode = DO NOT SHARE
                                    "dword", 0, _ ;lpSecurityAttributes = NULL
                                    "dword", 3, _ ;dwCreationDisposition = OPEN_EXISTING
                                    "dword", 128, _ ;dwFlagsAndAttributes = FILE_ATTRIBUTE_NORMAL
                                    "hwnd", 0) ;hTemplateFile = NULL
    Else
            $aRet = DllCall("Kernel32.dll", "hwnd", "CreateFile", _
                                    "str", $sFilename, _ ;lpFileName
                                    "dword", 0x40000000, _ ;dwDesiredAccess = GENERIC_WRITE
                                    "dword", 0x00000004, _ ;dwShareMode = DO NOT SHARE
                                    "dword", 0, _ ;lpSecurityAttributes = NULL
                                    "dword", 3, _ ;dwCreationDisposition = OPEN_EXISTING
                                    "dword", 128, _ ;dwFlagsAndAttributes = FILE_ATTRIBUTE_NORMAL
                                    "hwnd", 0) ;hTemplateFile = NULL
    EndIf

    If NOT FileExists($sFilename) Then
        Return 0
    Else
        $hFile = $aRet[0]
        If $hFile = -1 Then ;INVALID_HANDLE_VALUE = -1
            $aRet = DllCall("Kernel32.dll", "int", "GetLastError")
            SetError($aRet[0])
            Return 1
        Else
            ;close file handle
            DllCall("Kernel32.dll", "int", "CloseHandle", "hwnd", $hFile)
            Return 0
        EndIf
    EndIf
EndFunc

[DatMCEyeBall]

I might use this for something...

Not sure if useful or not,

SetError($aRet[0])
Return 1

; Could be:
Return SetError($aRet[0], 0, 1)

Edited July 29, 2013 by DatMCEyeBall

[guinness]

You don't really need StringUpper as = is case-insensitive anyway. If you were using == then OK it would be valid, but it's not in this case.

For the purposes of learning the next generation of AutoIt, how does this work for you? You will need v3.3.9.6 and above. 

#include <APIErrorsConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>

; Works with v3.3.9.6+

Local $hFileOpen = FileOpen(@ScriptFullPath, $FO_READ)
MsgBox($MB_SYSTEMMODAL, '', 'Is the file in use: ' & _FileIsUsed(@ScriptFullPath) & @CRLF)
FileClose($hFileOpen)

Func _FileIsUsed($sFilePath) ; By Nessie. Modified by guinness.
    Local Const $hFileOpen = _WinAPI_CreateFile($sFilePath, $CREATE_ALWAYS, (DriveGetType($sFilePath)) = 'NETWORK' ? $FILE_SHARE_READ : $FILE_SHARE_WRITE)
    Local $fReturn = True
    If $hFileOpen Then
        _WinAPI_CloseHandle($hFileOpen)
        $fReturn = False
    EndIf

    If $fReturn Then
        $fReturn = _WinAPI_GetLastError() = $ERROR_SHARING_VIOLATION
    EndIf
    Return $fReturn
EndFunc   ;==>_FileIsUsed

[Deye]

is there some process dependency that can cause the code not to work (I keep receiving a false return)
anyone got an idea what can cause this not to work, as I think this used to work before

for now I have tried a system reboot to avoid any system instabilities

i have tried locked and none locked files and got the same return.
 

Func _FileIsUsed($sFilePath) ; By Nessie. Modified by guinness.
    Local Const $hFileOpen = _WinAPI_CreateFile($sFilePath, $CREATE_ALWAYS, (DriveGetType($sFilePath)) = 'NETWORK' ? $FILE_SHARE_READ : $FILE_SHARE_WRITE)
    Local $fReturn = True

;~     $hFileOpen is allways = 0

    If $hFileOpen Then
        _WinAPI_CloseHandle($hFileOpen)
        $fReturn = False
    EndIf

;~      $fReturn is allways = True

    If $fReturn Then
        $fReturn = _WinAPI_GetLastError() = $ERROR_SHARING_VIOLATION
    EndIf

;~     fReturn = is allways False
    
EndFunc   ;==>_FileIsUsed

 

Edited May 21, 2015 by Deye

[argumentum]

I've tested

Local $hFileOpen = FileOpen(@ScriptFullPath, $FO_READ)
MsgBox($MB_SYSTEMMODAL, '', 'Is the file in use: ' & _FileInUse(@ScriptFullPath) & @CRLF)
FileClose($hFileOpen)

and shows to work just fine. Old DLL call and new_WinAPI_ , share a bit more of your code, maybe we can help better

[Deye]

Thanks for the reply

I have used the same code to test on a nother computer with sucsess

but wondering what is causing it fail here , I guess it needs some WinAPI error checking workaround 
to determine if this will run correctly at run-time 
so other steps in the script can be taken if this yields nothing