Dynamic Checkboxes

[Lcreager]

I am attempting to write script with a gui to install network printers.  I have it set up to read the printer names from an .ini file and to create check boxes for each printer.  I can't seem to figure out how to see what boxes are checked and do something with the printer name next to the checked box.  Clicking the button does pop up a message box so I know it goes to the function, but my IF statement is completely skipped and I'm not sure how to make this work.  All help is greatly appreciated.  

 

Current Script

expandcollapse popup

#include <GUIConstantsEx.au3>
Opt("GuiOnEventMode",1)
Opt("GUICoordMode",0)

Global $Printers = IniRead("settings.ini","Printers","PrinterList","NotFound")
Global $printarr = StringSplit ($Printers, ",")
Global $iPrinternumber = UBound($printarr) - 1
Global $box[$printarr[0] + 1]



GUICreate("Printer Installer", 400, 400)
GUISetOnEvent($GUI_EVENT_CLOSE, "_CLOSEClicked")

For $i = 1 To $iPrinternumber 
     
   $box[$i]= GUICtrlCreateCheckbox($printarr[$i],-1, 20)
     
Next

$InstallButton = GUICtrlCreateButton("Install Selected", 160, 30)
GUIctrlSetOnEvent($InstallButton, "_PrinterInstall")


GUISetState(@SW_SHOW)


While 1
   Sleep(1000)
WEnd

Func _CLOSEClicked ()
   Exit
EndFunc

Func _PrinterInstall ()

For $i = 1 To $iPrinternumber

   If GUICtrlGetState($box[$i]) = $GUI_CHECKED Then
      
      MsgBox(0,$box[$i],$box[$i] & " has been selected.")
      
   Else
      
      
   EndIf
   
     
next
 MsgBox(0,"Test", "Button has been clicked")

EndFunc

The .ini file contents

[Printers]

PrinterList = Printer 1, Printer 2, Printer3, Printer 4, New_Test_printer

[BrewManNH]

Try this change in your _PrinterInstall function

Func _PrinterInstall()
    For $i = 1 To $iPrinternumber
        If GUICtrlRead($box[$i]) = $GUI_CHECKED Then ;<<<<<<<<<<<<<<<<<<<<<<<<<<<
            MsgBox(0, $printarr[$i], $printarr[$i] & " has been selected."); <<<<<<<<<<<<<<<<
        Else
        EndIf
    Next
    MsgBox(0, "Test", "Button has been clicked")
EndFunc   ;==>_PrinterInstall

[Lcreager]

 

Try this change in your _PrinterInstall function

Func _PrinterInstall()
    For $i = 1 To $iPrinternumber
        If GUICtrlRead($box[$i]) = $GUI_CHECKED Then ;<<<<<<<<<<<<<<<<<<<<<<<<<<<
            MsgBox(0, $printarr[$i], $printarr[$i] & " has been selected."); <<<<<<<<<<<<<<<<
        Else
        EndIf
    Next
    MsgBox(0, "Test", "Button has been clicked")
EndFunc   ;==>_PrinterInstall

 

That did the Trick.  Thank You.

[BrewManNH]

You're welcome.