Set position of caret in GUICtrlEdit

[meisandy]

Hi,

I would like to be able to set the position of the caret in a GUICtrlEdit box. I have a function that inserts a placeholder into the text box at the current position (which I obtain using _GUICtrlEdit_GetSel) and I would like to move the caret to the end of the text inserted. Could somebody help me achieve this please?

Thanks in advance

Edited June 20, 2013 by meisandy

[guinness]

Cursor or caret? Caret is the 'blinky pipe'.

[meisandy]

Cursor or caret? Caret is the 'blinky pipe'.

Ah - it will be the caret I'm after. Thanks - I'll edit my post

[guinness]

Did you try_GUICtrlEdit_SetSel?

[meisandy]

Did you try_GUICtrlEdit_SetSel?

Yep, this is a snippet of my current code - it doesn't move the caret at all:

$position = _GUICtrlEdit_GetSel($txtEdit)
_GUICtrlEdit_InsertText($txtEdit $options[$i][0], $position[0])
_GUICtrlEdit_SetSel($txtEdit, $position[0] + StringLen($options[$i][0]), $position[0] + StringLen($options[$i][0]))

Edited June 20, 2013 by meisandy

[guinness]

Do you have a working example so I can then show what to do?

[meisandy]

Do you have a working example so I can then show what to do?

The only problem is my program is about 2000 lines long and the GUICtrlEdit parts are not all together. I could probably quickly make a program that mimics the part of the program I'm asking about though if it would be easier for you to show me how to set the position of the caret in the control.

I'll work on the 'condensed' program to show you what I want to achieve and post it as soon as I can. Meanwhile if there's a way for you to show me without an example - please do, it would be much appreciated.

[guinness]

As I am helping you, it would be polite if you could find that extra minute for creating a reproducer instead of me taking time out to code something that you don't quite understand.

Edited June 20, 2013 by guinness

[meisandy]

As I am helping you, it would be polite if you could find that extra minute for creating a reproducer instead of me taking time out to code something that you don't quite understand.

Ok - no problem. The following program is basically the part of my main program that isn't working properly. It's supposed to insert the text in the list at the current caret position and then move the caret to end of the text inserted:

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#include <GUIEdit.au3>
#Region ### START Koda GUI section ### Form=
$gui = GUICreate("GUICtrlEdit Set Caret", 433, 169, 192, 124)
$txtEdit = GUICtrlCreateEdit("", 24, 24, 233, 113, $ES_WANTRETURN)
GUICtrlSetData(-1, "txtEdit")
$lstVariables = GUICtrlCreateList("", 296, 24, 121, 110, BitOR($LBS_NOTIFY,$WS_VSCROLL, $LBS_EXTENDEDSEL))

#EndRegion ### END Koda GUI section ###

Dim $data[5] = ["Example 1", "Example 2", "Example 3", "Example 4", "Example 5"]

For $i = 0 To UBound($data)-1
    GUICtrlSetData($lstVariables, $data[$i])
Next

GUIRegisterMsg($WM_COMMAND, "WM_NOTIFY")

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func _insertPlaceholder()
    $indexes = _GUICtrlListBox_GetSelItems($lstVariables)
    If $indexes[0] = 1 Then
        $i = $indexes[1]
        $position = _GUICtrlEdit_GetSel($txtEdit)
        _GUICtrlEdit_InsertText($txtEdit, $data[$i], $position[0])
        _GUICtrlListBox_SetSel($lstVariables, $indexes[1])
        _GUICtrlEdit_SetSel($txtEdit, $position[0] + StringLen($data[$i]), $position[0] + StringLen($data[$i]))
    EndIf
    GUICtrlSetState($txtEdit, $GUI_FOCUS)
EndFunc

Func WM_NOTIFY($hWnd, $msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16) ; HiWord
    Local $nID = BitAND($wParam, 0xFFFF) ; LoWord
    Local Const $LBN_DBLCLK = 2
    Switch $nID
        Case $lstVariables
            Switch $nNotifyCode
                Case $LBN_DBLCLK
                   _insertPlaceholder()
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

[guinness]

Thanks. Before I continue here is the code tidied up a little, maybe you will learn something?

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>

Global $aData[5] = ['Example 1', 'Example 2', 'Example 3', 'Example 4', 'Example 5'], _ ; Don't use Dim!
        $__iEdit = -9999, $__iListBox = -9999

Example()

Func Example()
    Local $hGUI = GUICreate('GUICtrlEdit Set Caret', 435, 170)
    $__iEdit = GUICtrlCreateEdit('Example', 25, 25, 230, 115, $ES_WANTRETURN)
    $__iListBox = GUICtrlCreateList('', 295, 25, 120, 110, BitOR($LBS_NOTIFY, $WS_VSCROLL, $LBS_EXTENDEDSEL))
    ; _GUICtrlEdit_SetSel($__iEdit, _GUICtrlEdit_GetTextLen($__iEdit), _GUICtrlEdit_GetTextLen($__iEdit))

    For $i = 0 To UBound($aData) - 1
        GUICtrlSetData($__iListBox, $aData[$i])
    Next

    GUISetState(@SW_SHOW, $hGUI)
    GUIRegisterMsg($WM_COMMAND, 'WM_NOTIFY')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $iCode = _WinAPI_HiWord($wParam) ; HiWord
    Local $iControlID = _WinAPI_LoWord($wParam) ; LoWord

    Switch $iControlID
        Case $__iListBox
            Switch $iCode
                Case $LBN_DBLCLK
                    ; Function.
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Edited June 20, 2013 by guinness

[guinness]

Is this what you wanted?

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>

Global $aData[5] = ['Example 1', 'Example 2', 'Example 3', 'Example 4', 'Example 5'], _ ; Don't use Dim!
        $__iEdit = -9999, $__iListBox = -9999

Example()

Func Example()
    Local $sData = 'This is a long pice of text which should require wrapping in the edit control - ' & _
            'which is provided by the combination of $ES_WANTRETURN and $ES_MULTILINE styles'
    Local $hGUI = GUICreate('GUICtrlEdit Set Caret', 435, 170)
    $__iEdit = GUICtrlCreateEdit($sData, 25, 25, 230, 115, BitOR($ES_WANTRETURN, $ES_MULTILINE))
    $__iListBox = GUICtrlCreateList('', 295, 25, 120, 110, BitOR($LBS_NOTIFY, $WS_VSCROLL, $LBS_EXTENDEDSEL))

    For $i = 0 To UBound($aData) - 1
        GUICtrlSetData($__iListBox, $aData[$i])
    Next

    GUISetState(@SW_SHOW, $hGUI)
    GUIRegisterMsg($WM_COMMAND, 'WM_NOTIFY')

    ; Set the caret to 0, 0.
    _GUICtrlEdit_SetSel($__iEdit, 0, 0)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _EditInsert()
    Local $aListSelection = _GUICtrlListBox_GetSelItems($__iListBox)
    If $aListSelection[0] Then
        Local $aCaretPosition = _GUICtrlEdit_GetSel($__iEdit), _
                $iIndex = $aListSelection[1]
        _GUICtrlEdit_BeginUpdate($__iEdit)
        _GUICtrlEdit_InsertText($__iEdit, $aData[$iIndex], $aCaretPosition[0])
        _GUICtrlEdit_EndUpdate($__iEdit)

        _GUICtrlEdit_SetSel($__iEdit, $aCaretPosition[0] + StringLen($aData[$iIndex]), $aCaretPosition[0] + StringLen($aData[$iIndex]))
    EndIf
EndFunc   ;==>_EditInsert

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $iCode = _WinAPI_HiWord($wParam) ; HiWord
    Local $iControlID = _WinAPI_LoWord($wParam) ; LoWord

    Switch $iControlID
        Case $__iListBox
            Switch $iCode
                Case $LBN_DBLCLK
                    _EditInsert()
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

[meisandy]

Thank you guinness, however if I add GUICtrlSetState($__iEdit, $GUI_FOCUS) to the end of the _EditInsert() function, the caret is still at the beginning of the inserted text - so unfortunately problem not solved.

With regards to the tidied code, I only used the Koda Form Designer for quickness, but I have to ask why you declare the list box and edit control as -9999 and also whether I need to adopt your naming conventions? Also, is it better to put the GUI creation in a function and then call it; if so why?

Is there anything else I should have asked about your tidied code (what do I need to learn)?

[guinness]

So you need to set the state, well I will have to re-think then.

I initialise variables with a value (as in C/C++ if you don't, can cause error, whereas AutoIt is a little more forgiving), I chose -9999  just because it's a random number and isn't recognised by GUIGetMsg as an event. The naming convention is taken from here and variables should be declared where they are used, plus Global variables shouldn't be used if there is no requirement.

Edit: Click on Coding in my signature for good coding practices and examples.

Edited June 21, 2013 by guinness

[guinness]

The caret moves but $GUI_FOCUS re-focuses the caret back to the start. I can't seem to come up with a workaround.

[meisandy]

Ok, thank you. I will have a look at some of the links in your signature - very useful information.

Ideally, what I wanted to happen is that a user is typing; they then double click a variable in the list which is inserted into the text where they finished typing, and then they could continue typing after the inserted text, but if this can't be done I guess I can't do much about it.

[guinness]

Maybe it can, but it requires a lot of 'workaround' code.

[meisandy]

Maybe it can, but it requires a lot of 'workaround' code.

How much is a lot? And when you say 'workaround', is it likely to not work sometimes or effect other things?

[guinness]

I can't really give you a figure of how many lines it will be and it's really a cosmetic feature you're trying to 'workaround'.

Edited June 21, 2013 by guinness

[guinness]

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>

Global $aData[5] = ['Example 1', 'Example 2', 'Example 3', 'Example 4', 'Example 5'], _ ; Don't use Dim!
        $__hGUI = -9999, $__iEdit = -9999, $__iListBox = -9999

Example()

Func Example()
    Local $sData = 'This is a long pice of text which should require wrapping in the edit control - ' & _
            'which is provided by the combination of $ES_WANTRETURN and $ES_MULTILINE styles'
    $__hGUI = GUICreate('GUICtrlEdit Set Caret', 435, 170)
    $__iEdit = GUICtrlCreateEdit($sData, 25, 25, 230, 115, BitOR($ES_WANTRETURN, $ES_MULTILINE))
    $__iListBox = GUICtrlCreateList('', 295, 25, 120, 110, BitOR($LBS_NOTIFY, $WS_VSCROLL, $LBS_EXTENDEDSEL))

    For $i = 0 To UBound($aData) - 1
        GUICtrlSetData($__iListBox, $aData[$i])
    Next

    GUISetState(@SW_SHOW, $__hGUI)
    GUIRegisterMsg($WM_COMMAND, 'WM_NOTIFY')

    ; Set the caret to 0, 0.
    _GUICtrlEdit_SetSel($__iEdit, 0, 0)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    GUIDelete($__hGUI)
EndFunc   ;==>Example

Func _EditInsert()
    Local $aListSelection = _GUICtrlListBox_GetSelItems($__iListBox)
    If $aListSelection[0] Then
        Local $aCaretPosition = _GUICtrlEdit_GetSel($__iEdit), _
                $iIndex = $aListSelection[1]
        _GUICtrlEdit_InsertText($__iEdit, $aData[$iIndex], $aCaretPosition[0])
        _GUICtrlEdit_SetSel($__iEdit, $aCaretPosition[0] + StringLen($aData[$iIndex]), $aCaretPosition[0] + StringLen($aData[$iIndex]))

        ; Debugging only!
        $aCaretPosition = _GUICtrlEdit_GetSel($__iEdit)
        ConsoleWrite('Start: ' & $aCaretPosition[0] & @CRLF)
        ConsoleWrite('End: ' & $aCaretPosition[1] & @CRLF)

        ControlFocus($__hGUI, '', $__iEdit)
    EndIf
EndFunc   ;==>_EditInsert

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $iCode = _WinAPI_HiWord($wParam) ; HiWord
    Local $iControlID = _WinAPI_LoWord($wParam) ; LoWord

    Switch $iControlID
        Case $__iListBox
            Switch $iCode
                Case $LBN_DBLCLK
                    _EditInsert()
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Fixed it!

 

[meisandy]

Ah ha - absolutely perfect! Thank you and well done - who'd have thought it would be that simple!

Very much appreciated