Input + UpDown + ReadOnly + NoFocus ?

[Edano]

sometimes i feel so stupid to ask trivial questions, but how can i get the inputbox with updown clean and white, without blue highlight focus or caret in it? i mean, it is readonly, but still looks like editable. it should not do anything.

.

#include <EditConstants.au3>


GUICreate("")

GUICtrlCreateInput(640,15,88,70,20,BitOR($ES_NUMBER,$ES_CENTER,$ES_READONLY))
GUICtrlSetBkColor(-1,0xFFFFFF)
GUICtrlSetFont(-1,-1,1000)

GUICtrlCreateUpdown(-1)
GUICtrlSetCursor(-1,0)

GUISetState()

Do

Until GUIGetMsg()=-3

.

from >here i learned that this is not a trivial question, but it is still unsolved.

thx

E.

 

edit: melba's subclassing fails with updown control:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <EditConstants.au3>


;Global subclass vars
Global Const $GCL_WNDPROC = -24
Global $hNew_ControlProc = 0, $pOriginal_EditProc

; Must be run before any input controls are created
_ControlGlobalSubclass()
; All subsequently created inputs will be subclassed - individual controls original wndproc cannot be restored

; Create GUI
$hGUI = GUICreate("Subclassed Input Control without Highlight", 500, 210)

$hInput = GUICtrlCreateInput(640, 10, 10, 80, 20,BitOR($ES_NUMBER,$ES_CENTER,$ES_READONLY))
GUICtrlSetBkColor(-1,0xFFFFFF)
GUICtrlSetFont(-1,-1,1000)

GUICtrlCreateUpdown(-1)
GUICtrlSetCursor(-1,0)

$hButton = GUICtrlCreateButton("Dummy", 10, 50, 80, 30)

GUISetState()

Sleep(2000)

; Remove initial HighLight from input
GUICtrlSendMsg($hInput, 0xB1, 0, 0)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ; Must delete subclassed controls before freeing DLLCallbacks
            GUIDelete($hGUI)
            ; Now free DLLCallbacks - not strictly necessary, but "good idea" according to Help file
            DllCallbackFree($hNew_ControlProc)
            Exit
    EndSwitch
WEnd

Func _ControlGlobalSubclass()

    ; Check we have not done it already
    If $hNew_ControlProc <> 0 Then Return SetError(1, 0, 0)

    ; Create temp GUI
    Local $hGUITemp = GUICreate("", 1, 1, -10, -10)

    ; Create temporary edit
    Local $hEditTemp = GUICtrlGetHandle(GUICtrlCreateEdit("", -10, -10, 1, 1))

    ; Create callback
    $hNew_ControlProc = DllCallbackRegister("_WndProc", "int", "hwnd;uint;wparam;lparam")
    Local $pCallbackPtr = DllCallbackGetPtr($hNew_ControlProc)

    ; Subclass Edit class - which means replace the original wndproc with our own
    $pOriginal_EditProc = DllCall("User32.dll", "dword", "SetClassLongW", "hwnd", $hEditTemp, "int", $GCL_WNDPROC, "ptr", $pCallbackPtr)
    $pOriginal_EditProc = $pOriginal_EditProc[0]

    ; Destroy temporary GUI
    GUIDelete($hGUITemp)

    Return SetError(0, 0, 1)

EndFunc   ;==>_ControlGlobalSubclass

; And this is the new wndproc which we set when we subclass
Func _WndProc($hWnd, $iMsg, $wParam, $lParam)

    Switch _WinAPI_GetClassName($hWnd)
        Case "Edit"
            ; Intercept the SETSEL message
            If $iMsg = $EM_SETSEL And $lParam <> -1 Then
                ConsoleWrite("SETSEL msg intercepted" & @CRLF)
                Return 0
            EndIf
            ; Pass other messages to original wndproc
            Return _WinAPI_CallWindowProc($pOriginal_EditProc, $hWnd, $iMsg, $wParam, $lParam)
        Case Else
            Return 0

    EndSwitch

EndFunc   ;==>_WndProc

Edited June 12, 2013 by Edano

[BrewManNH]

How about faking it like this.

 

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>



; Create GUI
$hGUI = GUICreate("Subclassed Input Control without Highlight", 500, 210)
$hInput = GUICtrlCreateInput(640, 90, 10, 16, 20, BitOR($ES_NUMBER, $ES_CENTER, $ES_READONLY))
$hLabel = GUICtrlCreateLabel(640, 10, 10, 80, 20, BitOR($SS_CENTER, $GUI_SS_DEFAULT_LABEL, $SS_SUNKEN))
GUICtrlSetBkColor($hLabel, 0xFFFFFF)
GUICtrlSetColor($hLabel, 0x000000)
$hUpDown = GUICtrlCreateUpdown($hInput)
$hButton = GUICtrlCreateButton("Dummy", 10, 50, 80, 30)

GUISetState()


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            GUIDelete($hGUI)
            Exit
        Case $hUpDown
            GUICtrlSetData($hLabel, GUICtrlRead($hInput))
    EndSwitch
WEnd

[Edano]

i thought of the same.

it's nicer than the original for sure. if there's no other way ...

E