RestrictEdit_SRE (UDF)

[PhoenixXL]

RESTRICT EDIT UDF

Restrict the text that can be entered in an editbox through a String Regular Expression.

The UDF works be subclassing the control. >Here is a similar UDF based on Windows Message.

 

Functions

• The UDF is pretty simple and could be modified with ease.
• User can set their SRE pattern to block the text entered in the editbox
• Tooltips can be used in case of an error. The title of the Tooltip is Error_2 where the number(2) signifies the pattern that caused the error.
• The script is made to use function pointer variables rather than direct patterns, to make it more flexible and broader.
• Supports +ve and -ve SRE pattern matches. See example for better understanding.

 

Note : The Pattern should be made such that every phase of typing is met,

Example, if the user wants The second letter should be always a digit. Then he should make sure that the pattern is also satisfied when user enters the first character, as through the process of typing.

Index

; #INDEX# =======================================================================================================================
; Title .........: RestrictEdit
; Version........: 1.0
; AutoIt Version : 3.3.8.0++
; Language ......: English
; Author(s)......: Phoenix XL
; Librarie(s)....: WinAPI, Array and GUIEdit
; Description ...: Functions for restricting the text typed in an Edit control through SRE.
;                  The edit control is subclassed and the original processing is blocked when pattern isn't satisfied.
; ===============================================================================================================================

; #CURRENT# =====================================================================================================================
;_Restrict_Edit
; ===============================================================================================================================

; #INTERNAL_USE_ONLY# ===========================================================================================================
; HideToolTip_Edit
;_NewWnd_Proc_
;_SubClass_
; ===============================================================================================================================

ChangeLog

v1.0 - First Release

v2.0 - Replaced the SRE pattern parameter(2nd parameter) with function pointer parameter[A script Breaking change]. Added support for positive and negative pattern matches

Download

v2.0 RestrictEdit(UDF).7z

Previous downloads : 161

Edited March 5, 2014 by PhoenixXL

[Danyfirex]

Really Usefull .

thank you. 

[guinness]

NIce example of sub-classing..

[mLipok]

Thanks PhoenixXL

Very nice UDF

 

Unfortunately something disappoints me today my mind, 

I try to add restrictions to the text type: 

m121/12,1231/12,p1/12,2/13,s1/14,o121/10

here is an example what I want to achieve:

#include <array.au3>
$sText = 'm121/12,1231/12,p1/12,2/13,s1/14,o121/10'
$aItems = StringRegExp($sText,'[mpson]?\d+\/\d\d,?',3)
_ArrayDisplay($aItems)

I wonder how to use your UDFa to exclude erroneous data entered by a human.

[PhoenixXL]

You will have to use conditionals,

Example

expandcollapse popup

#include <GUIConstants.au3>
#include <RestrictEdit.au3>

#cs
    [0]|m121/12,
    [1]|1231/12,
    [2]|p1/12,
    [3]|2/13,
    [4]|s1/14,
    [5]|o121/10
#ce

Func _Main()

    #cs Pattern in text that should follow

        the first character can be any of 'm' 'p' 's' 'o' 'n' or a no. of digits
        followed by a "/" and then followed by two digits.
        Then if comma again the above pattern is expected otherwise, if EOL the pattern is satisfied.

    #ce

    Local Const $sPattern = "^([mpson]?(?(?=\d+)\d*\d(?(?=/)/(?(?=\d)\d{0,2}(,|$)|$)|$)|$))*$"

    ;our main GUI
    GUICreate("Restrict Edit | Phoenix XL", 200, 70)
    GUICtrlCreateLabel("Pattern : " & $sPattern, 10, 10, 200, 30)
    GUICtrlCreateInput("", 10, 30, 180, 20)

    ;subclass the control and set the SRE restriction.
    _Restrict_Edit(GUICtrlGetHandle(-1), $sPattern, "InCorrect Syntax.")
    If @error Then MsgBox(16, "Error Code: " &  @error, "Extended: " & @extended)

    GUISetState()

    Do
        Sleep(10)
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ;unsubclass the control
    _Restrict_Edit(GUICtrlGetHandle(-1))

EndFunc   ;==>_Main

_Main()

I'm not decoding the regex. I'm going to release the next version soon that comes with the support of multiple SRE's. Therefore such long patterns won't be required.

Regards

Edited February 15, 2014 by PhoenixXL

[mLipok]

Exactly what I meant.

Thanks a lot for that script example.

 

I'm going to release the next version soon that comes with the support of multiple SRE's. Therefore such long patterns won't be required.

 

Sounds promising. Already I can not wait to study your code 

Best regards 

mLipok

 

 

btw.

Thanks for this tutorial link, is very instructive. Somehow I have not landed on him before.

[mLipok]

I worked a bit on it. 

The first thing I made a minor amendment. 

changing this: 

Local Const $sPattern = "^([mpson]?(?(?=\d+)\d*\d(?(?=/)/(?(?=\d)\d{0,2}(,|$)|$)|$)|$))*$"

on, something like this:

Local Const $sPattern = "^([mpson]?(?(?=\d+)\d+(?(?=/)/(?(?=\d)\d{0,2}(,|$)|$)|$)|$))*$"

d*d    >>>   d+

---

Then I remembered one problem: 

below a description of how to achieve the same problem: 

 

type 

1234/56

Now back to the beginning, before the digit 1, and now try to add the letter s 

 

tooltip "Incorrect Syntax." Appear. 

 

but when you clear input and start writing again 

s1234/56 

in this case no message does not appear

 

Then I did some more tests. 

 

I noticed another similar problem: 

below a description of how to achieve this problem: 

 

type 

1234/56

Now back before the character /, and now try to add the letter s   (trying to do this 1234s/56  )

 

tooltip "Incorrect Syntax." Appear. 

 

but when set at the end of the entered text, and add a comma character

and now you come back in front of the sign / 

it now can easily add the letter s

 

---

I wonder if this is errors in $sPattern , or have found a bug?

EDIT: nevertheless, the script is already very useful.

---

I have an additional question / issue, but that does not stir too much, so I wait for a possible answer.

 

Best Regards

mLipok

Edited March 2, 2014 by mLipok

[PhoenixXL]

Yes all the problems is due to a bug in the UDF.

I will clear it with the new version, would be released by tomorrow.

Edited March 4, 2014 by PhoenixXL

[mLipok]

Thank you for the information.
In the evening, I will explain this further case which I mentioned earlier.

Perhaps it will help to improve the UDF.

Regards

mLIpok

[PhoenixXL]

v2.0 released

-+Replaced the SRE pattern parameter(2nd parameter) with function pointer parameter[A script Breaking change].

+Added support for positive and negative pattern matches

[PhoenixXL]

mLipok,

with the new version your example could be modified as follows (three regexes)

expandcollapse popup

#include <GUIConstants.au3>
#include <RestrictEdit.au3)
#include <MsgBoxConstants.au3>

#cs
    [0]|m121/12,
    [1]|1231/12,
    [2]|p1/12,
    [3]|2/13,
    [4]|s1/14,
    [5]|o121/10
#ce

_Main()

Func _Main()

    #cs Pattern in text that should follow

        the first character can be any of 'm' 'p' 's' 'o' 'n' or a no. of digits
        followed by a "/" and then followed by two digits.
        Then if comma again the above pattern is expected otherwise, if EOL the pattern is satisfied.

    #ce

    ;our main GUI
    GUICreate("Restrict Edit | Phoenix XL", 200, 70)
    GUICtrlCreateLabel("Test", 10, 10, 200, 30)
    GUICtrlCreateInput("", 10, 30, 180, 20)

    ;subclass the control and set the SRE restriction.
    _Restrict_Edit(GUICtrlGetHandle(-1), SRE_Array, "InCorrect Syntax.")
    If @error Then MsgBox($MB_ICONERROR, "Error Code: " & @error, "Extended: " & @extended)

    GUISetState()

    Do
        Sleep(10)
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ;unsubclass the control
    _Restrict_Edit(GUICtrlGetHandle(-1))

EndFunc   ;==>_Main

Func SRE_Array($hEdit, $s_CurrentText)

    ;return an non-array non zero to block processing
    ;return zero to block restriction

    Local $aPatterns[3][2] = [ _
            ["(^|(?<=/\d{2}),)[mpson]?\d*(/|$)", True], _                       ;here True signifies +ve match, the string should match the pattern
            ["((\D)\2|/\d{3}|/\d?\D|/\d{2}[^,]|(?<=\D)/)", False], _            ;here False signifies -ve match, the string should NOT match the pattern
            ["[^mpson\d,/]", False]]

    ;Lets decode the above patterns
    #cs
        First Pattern +ve match
            1st Capturing group
                (^|(?<=/\d{2}),) : by start of string or comma( that too should be preceeded by a slash and two digits [look-behind assertion])

            [mpson]? : if present should be preceeded by 1st capturing group.

            \d* : any no. of digits

            2nd Capturing group
                ((/|$) : Either the end of the string, or a slash

            If the above pattern is not satisfied, processing is blocked.

        Second Pattern -ve match
            1st Capturing group
                ((\D)\2|/\d{3}|/\d?\D|/\d{2}[^,]) : consists of five different patterns nested. When either of the three is satisfied the pattern is matched
                1st NestedPattern
                    (\D)\2 : second capturing group, the first char is any non-digit, the second char is the same non-digit
                2nd NestedPattern
                    /\d{3} : after slash three digits are present.
                3rd NestedPattern
                    /\d?\D : after slash a non-digit is there or after slash a digit and then a non digit is present
                4th NestedPattern
                    /\d{2}[^,] : after slash two digits and anything other than comma is present.
                5th NestedPattern
                    (?<=\D)/ : slash preceeded by any non-digit

            If the above pattern is satisfied, processing is blocked.

        Third Pattern -ve match
            [^mpson\d,/] : match anything other than     m p s o n digit , /
            if the above is satisfied, processing is blocked
    #ce

    ;You can also block processing using this function.
    ;Say you don't want characters to exceed 20 then
    If StringLen($s_CurrentText) > 20 Then Return 1

    Return $aPatterns

EndFunc   ;==>SRE_Array

Though the straight away method is more simple and better conceptualized with nested conditionals, it modifies as follows

expandcollapse popup

#include <GUIConstants.au3>
#include <RestrictEdit.au3>
#include <MsgBoxConstants.au3>

#cs
    [0]|m121/12,
    [1]|1231/12,
    [2]|p1/12,
    [3]|2/13,
    [4]|s1/14,
    [5]|o121/10
#ce

_Main()

Func _Main()

    #cs Pattern in text that should follow

        the first character can be any of 'm' 'p' 's' 'o' 'n' or a no. of digits
        followed by a "/" and then followed by two digits.
        Then if comma again the above pattern is expected otherwise, if EOL the pattern is satisfied.

    #ce

    ;our main GUI
    GUICreate("Restrict Edit | Phoenix XL", 200, 70)
    GUICtrlCreateLabel("Test", 10, 10, 200, 30)
    GUICtrlCreateInput("", 10, 30, 180, 20)

    ;subclass the control and set the SRE restriction.
    _Restrict_Edit(GUICtrlGetHandle(-1), SRE_Array, "InCorrect Syntax.")
    If @error Then MsgBox($MB_ICONERROR, "Error Code: " & @error, "Extended: " & @extended)

    GUISetState()

    Do
        Sleep(10)
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ;unsubclass the control
    _Restrict_Edit(GUICtrlGetHandle(-1))

EndFunc   ;==>_Main

Func SRE_Array($hEdit, $s_CurrentText)

    ;return an non-array non zero to block processing
    ;return zero to block restriction

    Local $aPatterns[1][2] = [ ["^([mpson]?(?(?=\d+)\d+(?(?=/)/(?(?=\d)\d{0,2}(,|$)|$)|$)|$))*$", True]]

    Return $aPatterns

EndFunc   ;==>SRE_Array

Regards

Phoenix XL

Edited March 5, 2014 by PhoenixXL

[mLipok]

First I want to thank you.

Now it works excelent.

---

I rember that I need to restrict more complicated pattern

Here is an example what I want to achieve:

#include <array.au3>
$sText = 'm121/12,1231/12,p1a/12,2/13,s1/14,o121/10'
$aItems = StringRegExp($sText,'[mpson]?\d+[a-zA-Z]{0,3}\/\d\d,?',3)
_ArrayDisplay($aItems)

so I modyfied example by using this:

Func SRE_Array($hEdit, $s_CurrentText)

    ;return an non-array non zero to block processing
    ;return zero to block restriction

    Local $aPatterns[1][2] = [ ["^([mpson]?(?(?=\d+)\d+[a-zA-Z]{0,3}(?(?=/)/(?(?=\d)\d{0,2}(,|$)|$)|$)|$))*$", True]]

    Return $aPatterns

EndFunc   ;==>SRE_Array

And now it works perfectly, at least temporarily, I think it works perfectly

Again, many thanks for your help.

 

Best Regards

mLipok

[mLipok]

Hi

please add inside Func _Restrict_Edit($ControlHwnd, $pFunc = "", $s_ToolTip = "")

Local declaration for 

Local $Index = _ArraySearch($ai_ControlHwnd, $ControlHwnd)

Cheers

mLipok

[ijourneaux]

I am not very knowledge with RegEx expressions so I am having difficulty using the Restric Edit UDF to control limit the user to a HH:MM am/pm formatted entry.

Is there a source of examples? that I would be able to model after?

For the purposes of REstrict Edit what would the correct regex string be?

Ian