How to fully change user agent?

[EmptySpace]

Long ago I tried to make program where I could fastly change user agent for IE embedded object in GUI.

Now when I need to change it again I found that my user agent string is full of unneeded strings:

Mozilla/4.0 (c; MSIE 7.0; cx; Trident/4.0; BTRS123646; GTB7.4; Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1) ; SIE-ME75/22 UP.Browser/7.0.2.2.d.7(GUI) MMP/2.0 Profile/MIDP-2.0 Configuration/CLDC-1.1)

With this method: http://www.door2windows.com/how-to-change-internet-explorer-user-agent-string-in-all-versions-of-internet-explorer-without-any-tool/ I added '; SIE-ME75/22 UP.Browser/7.0.2.2.d.7(GUI) MMP/2.0 Profile/MIDP-2.0 Configuration/CLDC-1.1)" but now cant delete leaving blank in custom string imputbox.

 

Also tried:

http://www.zytrax.com/tech/web/change-ua.html

Both ways wont work.

 

Ie addon http://www.iegallery.com/Addons/Details/2040  works how I want but it wont change UA in embedded object.

 

Any ideas? How I can restore my UA to default if that 2 ways dont work?

(Check your UA here http://www.useragentstring.com/)

Edited June 3, 2013 by SherminatoR

[guinness]

HttpSetUserAgent.

Search the Forum as I've documented a bit about the correct usage.

[DW1]

Can't you also just remove the additional information from the registry?

HKEY_LOCAL_MACHINESOFTWAREMicrosoftWindowsCurrentVersionInternet Settings5.0User AgentPost Platform

[EmptySpace]

HttpSetUserAgent.

Search the Forum as I've documented a bit about the correct usage.

"Sets the user-agent string sent with InetGet() and InetRead() requests."

Can I make it to work with _IECreateEmbedded() in direct browsing? not only for inet funcs?

 

Can't you also just remove the additional information from the registry?

HKEY_LOCAL_MACHINESOFTWAREMicrosoftWindowsCurrentVersionInternet Settings5.0User AgentPost Platform

 

Its empty

Edited June 3, 2013 by SherminatoR

[trancexx]

How about something like this:

Global Const $sLink = "http://whatsmyuseragent.com/"

Global $oObj = ObjCreate("Shell.Explorer.2")

GUICreate("Test User-Agent String", 700, 500)
GUICtrlCreateObj($oObj, 10, 10, 680, 480)

GUISetState()

$oObj.Navigate2($sLink, Default, Default, Default, 'User-Agent: "My super special user agent string."')

While GUIGetMsg() <> -3
WEnd

[EmptySpace]

 

How about something like this:

Global Const $sLink = "http://whatsmyuseragent.com/"

Global $oObj = ObjCreate("Shell.Explorer.2")

GUICreate("Test User-Agent String", 700, 500)
GUICtrlCreateObj($oObj, 10, 10, 680, 480)

GUISetState()

$oObj.Navigate2($sLink, Default, Default, Default, 'User-Agent: "My super special user agent string."')
sleep(1500)
_IENavigate($oIE,"http://www.useragentstring.com/")
While GUIGetMsg() <> -3
WEnd

 

I need my user agent changed all time. 

#include <IE.au3>

Global Const $sLink = "http://useragentstring.com/"

GUICreate("Test User-Agent String", 700, 500)
_IEErrorHandlerRegister()
$oIE = _IECreateEmbedded()
GUICtrlCreateObj($oIE, 10, 10, 680, 480)
_IENavigate($oIE,"http://www.useragentstring.com/")
sleep(1000)
GUISetState()

$oIE.Navigate2($sLink,Default, Default, Default, 'User-Agent: My super special user agent string.')

While GUIGetMsg() <> -3
WEnd

If I refresh page then I see my old ua..

Edited June 3, 2013 by SherminatoR

[mikell]

This should work

#include <IE.au3>

GUICreate("Test User-Agent String", 700, 500)
_IEErrorHandlerRegister()
$oIE = _IECreateEmbedded()
GUICtrlCreateObj($oIE, 10, 10, 680, 480)
_SetUserAgent('User-Agent: My super special user agent string.')
_IENavigate($oIE,"http://www.useragentstring.com/")
sleep(1000)
GUISetState()

While GUIGetMsg() <> -3
WEnd

Func _SetUserAgent($agent)
    $agentLen = StringLen($agent)
    Dim $tBuff = DllStructCreate("char["&$agentLen&"]")
    DllStructSetData($tBuff, 1, $agent)
    $chk_UrlMkSetSessionOption = DllCall("urlmon.dll", "long", "UrlMkSetSessionOption", "dword", 0x10000001, "ptr", DllStructGetPtr($tBuff), "dword", $agentLen, "dword", 0)
EndFunc

[EmptySpace]

 

This should work

#include <IE.au3>

GUICreate("Test User-Agent String", 700, 500)
_IEErrorHandlerRegister()
$oIE = _IECreateEmbedded()
GUICtrlCreateObj($oIE, 10, 10, 680, 480)
_SetUserAgent('User-Agent: My super special user agent string.')
_IENavigate($oIE,"http://www.useragentstring.com/")
sleep(1000)
GUISetState()

While GUIGetMsg() <> -3
WEnd

Func _SetUserAgent($agent)
    $agentLen = StringLen($agent)
    Dim $tBuff = DllStructCreate("char["&$agentLen&"]")
    DllStructSetData($tBuff, 1, $agent)
    $chk_UrlMkSetSessionOption = DllCall("urlmon.dll", "long", "UrlMkSetSessionOption", "dword", 0x10000001, "ptr", DllStructGetPtr($tBuff), "dword", $agentLen, "dword", 0)
EndFunc

It works! Thanks