Ask group of radio buttons for checked value

[Myicq]

Given the following GUI part:

$Group1 = GUICtrlCreateGroup("Direction of label", 320, 216, 257, 73)
$radDirectionHorizontal = GUICtrlCreateRadio("Horizontal", 328, 240, 113, 17)
$radDirectionVertical = GUICtrlCreateRadio("Vertical", 328, 264, 113, 17)
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlCreateGroup("", -99, -99, 1, 1)

 

.. can I ask the group somehow (perhaps using a UDF) which radio button is selected ?

Something like

$selectedRadio = _RadioGroupGetSelected($Group1)

.. and have index value returned (here, 1 or 2 as last item is checked)

Or do I have to manually loop over each radioctrl ?

Btw: application is for generation of labels in a layout program.

[Melba23]

Myicq,

As you have only the 2 radios, all you need to do is check if one of them is checked - because if it is not then the other must be.

If GUICtrlRead($radDirectionHorizontal) = 1 Then
    $selectedRadio = 1 ; it is checked
Else
    $selectedRadio = 2 ; the other is checked
EndIf

Any help?

M23

[Myicq]

Well, that is true.

And I have to remember to always make sure to give illustrative and complete examples

It does not have to be just 2, this is obvious. But if I have 4, 6 or more the "if" codes can be pretty elaborate.

Sorry for posting such obvious example. And thank you for help so far, anyway.

[BrewManNH]

If you put the control IDs into an array, you can loop through the array to see which one is checked.

[guinness]

Use an array to store the controlids and the enumerate through the array.

[Melba23]

Myicq,

I have lost count of the number of times I have asked people to give a FULL explanation of their problem so that we do not waste time offering solutions which do not match the actual state of affairs!

This example shows 2 ways of getting the checked radio from a larger group:

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $aRadio[5]

$hGUI = GUICreate("Test", 500, 500)

GUIStartGroup()
For $i = 0 To 4
    $aRadio[$i] = GUICtrlCreateRadio(" Radio " & $i, 10, 10 + (20 * $i), 100, 20)
Next
GUICtrlSetState($aRadio[Random(0, 4, 1)], $GUI_CHECKED)

$cButton = GUICtrlCreateButton("Read", 10, 200, 80, 30)

GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            For $i = 0 To 4
                If GUICtrlRead($aRadio[$i]) = 1 Then
                    ConsoleWrite("Radio " & $i & " selected" & @CRLF)
                    ExitLoop
                EndIf
            Next
        Case Else
            For $i = 0 To 4
                If $iMsg = $aRadio[$i] Then
                    ConsoleWrite("Radio " & $i & " selected" & @CRLF)
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd

I hope that helps.

M23

[guinness]

  On 5/29/2013 at 12:50 PM, Myicq said:

Well, that is true.

And I have to remember to always make sure to give illustrative and complete examples

Posting 'runnable' code is a huge help, which hopefully you can understand.  9 times out of 10 when we say "do this and that" the response is "show me!" It's a lot less time consuming to add to what you have, instead of starting from scratch. Which Melba23 had to do on this occasion.

[Myicq]

Melba,

thank you so much! I should have known better, I face same problem with customer from time to time.

Credits to you and guiness for helping out!  I will make sure to learn lesson and post better code.

[guinness]

No harm done.