Parsing and Removal

[houston08]

I'm parsing a list of ip's with ports.

in this format:

255.255.255.255:12345

How would I go about removing the colon and the port, leaving just the ip so that I may save it?

Thanks!

[BrewManNH]

If it's just the IP address a colon and the port number, use something like this.

$sString = "255.255.255.255:12345"
$sNewString = StringLeft($sString, StringInStr($sString, ":") - 1)
Consolewrite( $sNewString & @CRLF)

[Nessie]

Or you can try something like that:

#include <Array.au3>
$sString = ""

For $i = 0 To 9999
    $sString &= "255.255.255.255:12345" & @CRLF
Next

$int = TimerInit()
$aRegex = StringRegExp($sString, "(.*?):", 3) ;This is all you really need, all the rest is just to debug purpose
$end = TimerDiff($int)
ConsoleWrite("Execution time: " & $end & @CRLF)

_ArrayDisplay($aRegex)

Hi!

[BrewManNH]

Playing with Nessie's code a little, this will make it only find 4 groups of digits 1 - 3 digits in length followed by a dot, except for the last digits before the colon.

#include <Array.au3>
$sString = ""

For $i = 0 To 9999
    $sString &= "IP = 255.255.255.255:12345" & @CRLF
Next

$int = TimerInit()
$aRegex = StringRegExp($sString, "(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}):", 3) ;This is all you really need, all the rest is just to debug purpose
$end = TimerDiff($int)
ConsoleWrite("Execution time: " & $end & @CRLF)

_ArrayDisplay($aRegex)

Anything that's in the string before the colon that's not a digit or digits less than 4 followed by a dot will be rejected.

[Malkey]

And another example of the same.

#include <Array.au3>

Local $sString = ""

For $i = 0 To 9999
    $sString &= "IP = 255.255.255.255:12345" & @CRLF
Next
$sString = StringTrimRight($sString, 2) ; Remove trailing @CRLF

Local $int = TimerInit()
Local $sRegex = StringRegExpReplace($sString, "(:\d+)", "") ; Remove colon and trailing digits per line.

Local $end = TimerDiff($int)
ConsoleWrite("Execution time: " & $end & " to a string." & @CRLF)
; ---------- End Script here if string result needed --------------

; Continue to split string for an array result.
Local $aRegex = StringSplit($sRegex, @CRLF, 3)
$end2 = TimerDiff($int)
ConsoleWrite("Execution time2: " & $end2 & " into an array." & @CRLF)

MsgBox(0, "String Result", $sRegex)
_ArrayDisplay($aRegex, "Array Result")

[AZJIO]

#include <Array.au3>

$sText = ''
$max = 1000
For $i = 0 To 9999
    $sText &= 'IP = ' & Random(1, $max, 1) & '.' & Random(1, $max, 1) & '.' & Random(1, $max, 1) & '.' & Random(1, $max, 1) & ':12345' & @CRLF
Next

$Array = StringRegExp($sText, '(?:(?:2(?:[0-4]\d|5[0-5])|1?\d{1,2})\.){3}(?:(?:2(?:[0-4]\d|5[0-5])|1?\d{1,2}))', 3)
_ArrayDisplay($Array, 'Array')

Edited May 22, 2013 by AZJIO

[guinness]

AZJIO,

Don''t use autoit tags anymore. Select the blue A in the full editor to add code. Thanks.

[mikell]

AZJIO,

Brewman's way works with your stress-test 

#include <Array.au3>
$sString = '09:34:34 Connected to 192.168.30.195:12345 fghsfgfg' & @CRLF & _
'10:43:15 Connected to 192.168.30.98:12345fgh' & @CRLF & _
'11:13:19 Connected to 10.80.30.152:12345' & @CRLF & _
'255.255.255.255:12345'

$int = TimerInit()
$aRegex = StringRegExp($sString, "(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}):", 3) ;This is all you really need, all the rest is just to debug purpose
$end = TimerDiff($int)
ConsoleWrite("Execution time: " & $end & @CRLF)

_ArrayDisplay($aRegex)

[guinness]

This is a more optimised version of BrewMan's.

#include <Array.au3>

Local $sString = '09:34:34 Connected to 192.168.30.195:12345 fghsfgfg' & @CRLF & _
        '10:43:15 Connected to 192.168.30.98:12345fgh' & @CRLF & _
        '11:13:19 Connected to 10.80.30.152:12345' & @CRLF & _
        '255.255.255.255:12345'

Local $hTimer = TimerInit()
Local $aSRE = StringRegExp($sString, '[\d.]{7,15}', 3)
ConsoleWrite('Execution time: ' & TimerDiff($hTimer) & @CRLF)
_ArrayDisplay($aSRE)

[mikell]

Will work in this particular case, but less multipurpose than Brewman's one because it matches 123456.50

[AZJIO]

Local $sString = _
        '999.999.999.999:12345' & @CRLF & _
        '333.333.333.333:12345' & @CRLF & _
        '999.10.10.10:12345' & @CRLF & _
        '10.999.10.10:12345' & @CRLF & _
        '10.10.999.10:12345' & @CRLF & _
        '10.10.10.999:12345'

Check with this.

I've simplified the previous script.

 

[houston08]

Thanks for the many Responses. Brewmans first answer was great, I'll read them all though just I can learn more, ie, the finding the 4 sets of numbers separated by the periods.

[guinness]

Will work in this particular case, but less multipurpose than Brewman's one because it matches 123456.50

True, but I was only using the output provided by AZJIO.

This version is slightly optimised and hopefully you've learn a bit more about regular expressions.

#include <Array.au3>

Local $sString = '09:34:34 Connected to 192.168.30.195:12345 fghsfgfg' & @CRLF & _
        '10:43:15 Connected to 192.168.30.98:12345fgh' & @CRLF & _
        '11:13:19 Connected to 10.80.30.152:12345' & @CRLF & _
        'This isn''t an IP address 123456.50' & @CRLF & _
        '255.255.255.255:12345'

Local $hTimer = TimerInit()
Local $aSRE = StringRegExp($sString, '((?:\d{1,3}\.){3}\d{1,3})', 3)
ConsoleWrite('Execution time: ' & TimerDiff($hTimer) & @CRLF)
_ArrayDisplay($aSRE)

[AZJIO]

I now understand where is the problem. You don't need a port. I have updated, now there is no port.
 

[guinness]

I would say AZJIO's version is better, due to the fact mine & BrewMan's will recognise 999.999.999.999 and his won't.

Give credit where credit is due, his version is accurate.

[Gianni]

another simple way :

$sString = "255.255.255.255:12345"

$sNewString = StringSplit($sString,":",2) ; separate IP from port number

ConsoleWrite("IP = " & $sNewString[0] & @CRLF)
ConsoleWrite("port = " & $sNewString[1] & @CRLF)

; and to separate the 4 sets of numbers

$IP_octet = StringSplit($sNewString[0],".",2) ; 4 parts of IP in an array

ConsoleWrite($IP_octet[0] & @CRLF)
ConsoleWrite($IP_octet[1] & @CRLF)
ConsoleWrite($IP_octet[2] & @CRLF)
ConsoleWrite($IP_octet[3] & @CRLF)

bye

[guinness]

Pincopanco,

You misunderstood the original problem, this isn't an alternative I'm afraid.

[Gianni]

I understood that in post #1 he wants simply to extract only the ip address from the couple IPaddress: portnumber;

and in post #12 he also wants to separate the individual octets from the entire IP address

I think I am not mistaken ...

[guinness]

Please test the examples to see the difference in output.

[Gianni]

I tried all the examples,

of course are all high level examples with raffinate regular-expression techniques

maybe they are better than expected......

However, sometime even a simpler example can be useful..... (I hope...  )