[SOLVED] $WS_HSCROLL doesn't work on ListView

[michaelslamet]

I have a ListView that allow user to click and drag multiple files into it, but when the path+filename is too long, the listview doesn't display a horizontal scroll.

Tried this without result:

$list = GUICtrlCreateListView('Files', 10, 10, 380, 230, $LVS_REPORT + $WS_HSCROLL)      ; $LVS_REPORT allow mutiple files to be selected

Also

GUICreate($Title, 400, 320, -1, -1, -1, $WS_EX_ACCEPTFILES + $WS_HSCROLL)

What did I do wrong?

Thanks in advance

Edited May 9, 2013 by michaelslamet

[guinness]

Search scrollbars and Melba23 in the Examples section.

[Melba23]

michaelslamet,

You do not need any additional styles - you just need to make the column width wider than the ListView to get horizontal scrollbars:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("Test", 500, 500)

$cListView = GUICtrlCreateListView('Files', 10, 10, 380, 230)
_GUICtrlListView_SetColumnWidth($cListView, 0, 500) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
GUICtrlCreateListViewItem("This is a very long ListView item and therefore should require scrollbars to see it all", $cListView)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

You might think of using my StringSize UDF to calculate the length of the each ListView item and make sure you set the column width to be slightly greater than the longest.

M23

[michaelslamet]

Guinness and Melba, thanks for the clue and the example!

Using your StringSize UDF solve this!

#include <StringSize.au3>

Global $longest_filename_width = 0
Global $default_listview_width = 376

For $n = 0 to _GUICtrlListView_GetItemCount($list) - 1
      $aSize = _StringSize(_GUICtrlListView_GetItemTextString($list, $n), Default, Default, Default, Default, 0)
      If $aSize[2] > $longest_filename_width Then
         $longest_filename_width = $aSize[2]
      EndIf
Next

If $longest_filename_width > $default_listview_width Then
     _GUICtrlListView_SetColumnWidth($list, 0, $longest_filename_width + 20)
EndIf

Thanks again!

[Melba23]

michaelslamet,

Delighted that we could help.

M23

[BrewManNH]

Another way to have the ListView show the whole line in a column is this way.

_GUICtrlListView_SetColumnWidth($list, 0, $LVSCW_AUTOSIZE)

This will cause the ListView column to be as wide as the longest item in the column. Letting Windows figure out which one that is is a lot easier than trying to do the math yourself, and stringsize wouldn't be needed in this case.

[Melba23]

BrewManNH,

I tried that expecting the result you suggest and it did not work - all I got was a very narrow column:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("Test", 500, 500)

$cListView = GUICtrlCreateListView('Files', 10, 10, 380, 230)
_GUICtrlListView_SetColumnWidth($cListView, 0, $LVSCW_AUTOSIZE) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
GUICtrlCreateListViewItem("This is a very long ListView item and therefore should require scrollbars to see it all", $cListView)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Does it actually work for you?

M23

Edit: Brain fart on my part - see below.

Edited May 9, 2013 by Melba23

[michaelslamet]

Hi Melba and BrewManNH,

I tried it, it actually works :-)

Instead of

_GUICtrlListView_SetColumnWidth($cListView, 0, $LVSCW_AUTOSIZE) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
GUICtrlCreateListViewItem("This is a very long ListView item and therefore should require scrollbars to see it all", $cListView)

This is working:

GUICtrlCreateListViewItem("This is a very long ListView item and therefore should require scrollbars to see it all", $cListView)
_GUICtrlListView_SetColumnWidth($cListView, 0, $LVSCW_AUTOSIZE) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

[michaelslamet]

On my listview, I have 2 cols, so using $LVSCW_AUTOSIZE on short filename will display a vertical line in the middle of the listview.

Is there any way to tell autoit that this listview only has 1 col?

This is part of my code:

GUICreate($Title, 400, 320, -1, -1, -1, $WS_EX_ACCEPTFILES)
WinSetOnTop($Title, "", 1)                                        ; always stay on top
$list = GUICtrlCreateListView('Files:', 10, 10, 380, 230, $LVS_REPORT)                ; $LVS_REPORT allow mutiple files to be selected
GUICtrlSendMsg($list, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_GRIDLINES, -1)

[Melba23]

michaelslamet,

Obvious when you think about it!

M23

[michaelslamet]

Hi Melba,

I can check it using "If" but I wonder is there any shorter and quicker way, for example using defined style

[michaelslamet]

This is what I mean:

Let say on the listview we have 2 items:

first item's length is 200

second item's length is 500

our default col width is 400

when we delete first item and then execute $LVSCW_AUTOSIZE, it should be no problem because after that our col width become 500++ is the horizontal scroll is displayed.

the problem is when we delete second item then execute $LVSCW_AUTOSIZE, our list view will now display vertical lines in the middle of list view.

If we need to use "If" to calculate which item has the longest width and how width is that and compare it to our default col width (which is 400), we absolutely need Melba's StringSize UDF, BrewManNH's solution wont work.

Is it correct? Sorry for my noob analysis

[Melba23]

michaelslamet,

I understood you perfectly. I have an idea and I am trying to get it to work - give me a little while.

M23

[BrewManNH]

I would use _GUICtrlListView_GetColumnWidth after resizing it, see if the width is shorter than the width of your ListView control, and if it is narrower, set the width of the column to the width of the listview.

[michaelslamet]

Hi BrewmanNH,

Now I understand you perfectly!

This works great:

_GUICtrlListView_SetColumnWidth($list, 0, $LVSCW_AUTOSIZE)
If _GUICtrlListView_GetColumnWidth($list, 0) < $default_listview_width Then
      _GUICtrlListView_SetColumnWidth($list, 0, $default_listview_width)
EndIf

Thank you for providing another method/solution

Maybe Melba will come out with another ideas

[Melba23]

michaelslamet,

This seems to work. Set the column to the max size of the ListView when you create it - when you add/delete an item reset the column width to auto - read the resulting column width and if it is too short then reset the column to the max width:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Global $aItems[2] = ["This is a short line", "This is a very long ListView item and therefore should require scrollbars to see it all"]
$iLV_Width = 380
$iMax_Width = $iLV_Width - 17 ; Allow for a vertical scrollbar

$hGUI = GUICreate("Test", 500, 500)

$cListView = GUICtrlCreateListView('Files', 10, 10, $iLV_Width, 230)
; Set width to max
_GUICtrlListView_SetColumnWidth($cListView, 0, $iMax_Width)

GUISetState()

For $i = 0 To 1
    ; Create item
    GUICtrlCreateListViewItem($aItems[$i], $cListView)

    ; Just for testing
    ConsoleWrite("Added item" & @CRLF)
    Sleep(1000)

    ; Set autowidth
    _GUICtrlListView_SetColumnWidth($cListView, 0, $LVSCW_AUTOSIZE)
    ; How wide is it?
    $iCurr_Width = _GUICtrlListView_GetColumnWidth($cListView, 0)

    ; Just for testing
    ConsoleWrite("Set to auto" & @CRLF)
    Sleep(1000)

    ; Reset to max if it is now too small
    If $iCurr_Width < $iMax_Width Then
        _GUICtrlListView_SetColumnWidth($cListView, 0, $iMax_Width)
        ; Just for testing
        ConsoleWrite("Set to Max" & @CRLF)
    EndIf

    ; Just for testing
    Sleep(1000)

Next


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Any use?

M23

Edit: Once again we have come up with a similar solution!

Edited May 9, 2013 by Melba23

[michaelslamet]

Melba,

Yes, clear as always and even more clear with code/example

Thanks a lot!