[SOLVED] How to check if there is some number in a string?

[michaelslamet]

Is it possible to check if there is AT LEAST few numbers (digit) in a string AND AT LEAST few hypen ("-") in a string?

For example:

$at_least_number = 4

$at_least_hypen = 2

then

"abcde812" --> false, because there are only 3 numbers on the string AND there is no hypen ("-") in the string

"abcde8112" --> false, because even there are 4 numbers (or more) in the string, the hypen is <= 2

"abcd-e8112-11" --> true, because there are 4 numbers (or more) in the string and there are 2 (or more) "-" in the string

"---43" --> false, because even there are only 2 (or more) "-" in the string, there are only 2 numbers in the string

Thanks in advance

Edited May 9, 2013 by michaelslamet

[Melba23]

michaelslamet,

Something like this should do the trick:

Global $aTest[4] = ["abcde812", "abcde8112", "abcd-e8112-11", "---43"]

$iDigits = 4
$iHyphens = 2

For $i = 0 To 3

    $sTest = $aTest[$i]
    $fValid = True

    ; Count digits
    StringRegExpReplace($sTest, "[0-9]", "")
    If @extended < $iDigits Then
        $fValid = False
    EndIf

    ; Count hyphens
    StringReplace($sTest, "-", "", 0, 2)
    If @extended < $iHyphens Then
        $fValid = False
    EndIf

    If $fValid Then
        MsgBox(0, $sTest, "Valid!")
    Else
        MsgBox(0, $sTest, "Not valid")
    EndIf

Next

All clear?

M23

[michaelslamet]

Wow, thanks a lot, Melba, works like a charm!

Need to learn how its work

Thanks again!

[Melba23]

michaelslamet,

As always, please ask if you have any questions.

M23

[UEZ]

Here another method:

ConsoleWrite(Check("abcde812") & @LF)
ConsoleWrite(Check("abcde8112") & @LF)
ConsoleWrite(Check("abcd-e8112-11") & @LF)
ConsoleWrite(Check("---43") & @LF)


Func Check($sString, $iDigits = 4, $iHyphens = 2)
    Local $a = StringRegExp($sString, "[\d]", 3)
    Local $b = StringRegExp($sString, "[-]", 3)
    Return BitAND((UBound($a) >= $iDigits), (UBound($b) >= $iHyphens))
EndFunc

Br,

UEZ

[michaelslamet]

UEZ, thanks for providing another way to doing this!