Wallpaper Changer

[GreenCan]

I'm not!

I learned something today.

I didn't know the _WinAPI_SystemParametersInfo function

Thanks

[guinness]

Most 'common' API calls can be found in WinAPI and WinAPIEx.

[GreenCan]

Most 'common' API calls can be found in WinAPI and WinAPIEx.

I still have many things to learn...

[guinness]

Seems I have a lot of code around the Forum. This is something of interest maybe >>

[Nessie]

Seems I have a lot of code around the Forum. This is something of interest maybe >>

Thanks for the link, ahhh if only you had posted this link an hour ago...

Here is my version:

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name ..........: _ImageSaveToBMP
; Description ...: Convert an image to bmp format
; Syntax ........: _ImageSaveToBMP($sPath[, $sDestPath = @ScriptDir[, $sName = Default[, $bOverwrite = False]]])
; Parameters ....: $sPath               - A string value.
;                  $sDestPath           - [optional] A string value. Default is @ScriptDir.
;                  $sName               - [optional] A string value. Default is Default.
;                  $bOverwrite          - [optional] A binary value. Default is False.
; Return values .: On Success - Return True
;                  On Failure -
;                               @error = 1 The file to be converted doesn't not exist
;                               @error = 2 The image is already a bmp file
;                               @error = 3 Invalid file extension
;                               @error = 4 The destination path doesn't not exist
;                               @error = 5 Invalid file name
;                               @error = 6 The destination file already exist
;                               @error = 7 Unable to overwrite the destination file
;                               @error = 8 Unable to save the bmp file
; Author ........: Nessie
; Example .......: _ImageSaveToBMP(@DesktopDir & "\nessie.jpg")
; ===============================================================================================================================
Func _ImageSaveToBMP($sPath, $sDestPath = @ScriptDir, $sName = Default, $bOverwrite = False)
    Local $bCheckExt = False

    If Not FileExists($sPath) Then Return SetError(1, 0, "")

    Local $sImageExt = StringLower(StringTrimLeft($sPath, StringInStr($sPath, '.', 0, -1)))

    If $sImageExt = "bmp" Then SetError(2, 0, "")

    Local $aAllowedExt[5] = ['gif', 'jpeg', 'jpg', 'png', 'tiff']

    For $i = 0 To UBound($aAllowedExt) - 1
        If $sImageExt = $aAllowedExt[$i] Then
            $bCheckExt = True
            ExitLoop
        EndIf
    Next

    If $bCheckExt = False Then  Return SetError(3, 0, "")

    If Not FileExists($sDestPath) Then Return SetError(4, 0, "")

    If $sName = Default Then
        $sName = StringTrimLeft($sPath, StringInStr($sPath, '\', 0, -1))
        $sName = StringTrimRight($sName, 4)
    Else
        If $sName = "" Then Return SetError(5, 0, "")
    EndIf

    If Not $bOverwrite Then
        If FileExists($sDestPath & "\" & $sName & ".bmp") Then
            Return SetError(6, 0, "")
        EndIf
    Else
        FileDelete($sDestPath & "\" & $sName & ".bmp")
        If @error Then
            Return SetError(7, 0, "")
        EndIf
    EndIf

    _GDIPlus_Startup()

    Local $hImage = _GDIPlus_ImageLoadFromFile($sPath)
    Local $sCLSID = _GDIPlus_EncodersGetCLSID("BMP")

    _GDIPlus_ImageSaveToFileEx($hImage, $sDestPath & "\" & $sName & ".bmp", $sCLSID)

    If @error Then
        _GDIPlus_Shutdown()
        Return SetError(8, 0, "")
    EndIf

    _GDIPlus_Shutdown()

    Return True
EndFunc   ;==>_ImageSaveToBMP

[guinness]

Not bad. Gets the same job done I suppose.

[Nessie]

Not bad. Gets the same job done I suppose.

Exactly the same job as the script that you post

Edit:

New versione release:

Changelog

;=====================================================
v.1.1.0 (07/05/2013)
Fixed Inetclose causes crash under some circumstances
Fixed Some code cleanup
Added New Style ;Thanks GreenCan for the documentation
Added Support to 'gif', 'jpeg', 'jpg', 'png', 'tiff' format
Added php code completely rewritten

Hi!

Edited May 7, 2013 by Nessie

[GreenCan]

I'm not!

; Though I have a feeling this will work too: http://www.autoitscript.com/forum/topic/19370-autoit-wrappers/page__st__280#entry652536
    Return _WinAPI_SystemParametersInfo($SPI_SETDESKWALLPAPER, 0, $sImageFile, BitOR($SPIF_UPDATEINIFILE, $SPIF_SENDCHANGE))

guinness,

I was able to test the changed script only this morning. Unfortunately, the background does not change with _WinAPI_SystemParametersInfo.

I will have to investigate why, meanwhile I will have to stick with the old code. Did it work on your PC?

[guinness]

I will give it a go later on today.

[GreenCan]

I will give it a go later on today.

It is defintely the _WinAPI_SystemParametersInfo function that does not function, this one works fine:

;~ _WinAPI_SystemParametersInfo($SPI_SETDESKWALLPAPER, 0, $sImageFile, BitOR($SPIF_UPDATEINIFILE, $SPIF_SENDCHANGE))
Return DllCall("user32.dll", "int", "SystemParametersInfo", _
"int", $SPI_SETDESKWALLPAPER, _
"int", 0, _
"str", $sImageFile, _
"int", BitOR($SPIF_UPDATEINIFILE, $SPIF_SENDCHANGE))

I see some differences in the dllcall contained in the _WinAPI_SystemParametersInfo function.

Local $aResult = DllCall("user32.dll", "bool", "SystemParametersInfoW", "uint", $iAction, "uint", $iParam, "ptr", $vParam, "uint", $iWinIni)

it should be like this to function correctly for background change

Local $aResult = DllCall("user32.dll", "bool", "SystemParametersInfo", "uint", $iAction, "uint", $iParam, "str", $vParam, "uint", $iWinIni)

SystemParametersInfoW and "str" (for $vParam) are the guilty ones and the working function should be

Func _WinAPI_SystemParametersInfo2($iAction, $iParam = 0, $vParam = 0, $iWinIni = 0)
Local $aResult = DllCall("user32.dll", "bool", "SystemParametersInfo", "uint", $iAction, "uint", $iParam, "str", $vParam, "uint", $iWinIni)
;~ Local $aResult = DllCall("user32.dll", "bool", "SystemParametersInfoW", "uint", $iAction, "uint", $iParam, "ptr", $vParam, "uint", $iWinIni)
ConsoleWrite(@ScriptLineNumber & " " & @error & @CR)
If @error Then Return SetError(@error, @extended, False)
Return $aResult[0]
EndFunc ;==>_WinAPI_SystemParametersInfo2

Edit: And why the hell do you put a .bmp filter in line 20 causing @error 2, this is definitely NOT required

Edited May 7, 2013 by GreenCan

[guinness]

Those changes would break Unicode support. I know what has to be changed, give me a while and I will come back to you all.

[guinness]

Works on Windows 7 x64.

#include <APIConstants.au3> ; Found in WinAPIEx by Yashied.
#include <WinAPI.au3>

; #FUNCTION# ====================================================================================================================
; Name ..........: _ChangeDestopWallpaper
; Description ...: Update the desktop wallpaper.
; Syntax ........: _ChangeDestopWallpaper($sImageFile[, $iStyle = 0])
; Parameters ....: $sImageFile          - Full path to the bitmap file.
;                  $iStyle               - [optional] 0 = Centered, 1 = Tiled, 2 = Stretched, 4 = Screen Width. Default is 0.
; Return values .: Success - True
;                  Failure - Sets @error to non-zero and returns False
; Author ........: FlyingBoz
; Modified ......: Larry - DllCall Example - Tested and Working under XPHome and W2K Pro.
;                  Greencan - Added Style 4.
;                  guinness - Tidied up the code and adding error checking.
; Example .......: No
; ===============================================================================================================================
Func _ChangeDestopWallpaper($sImageFile, $iStyle = Default)
    If FileExists($sImageFile) = 0 Then Return SetError(1, 0, False)

    $iStyle = Int($iStyle)
    If $iStyle < 0 Or $iStyle > 4 Then $iStyle = 0
    Local Const $sREG_DESKTOP = 'HKEY_CURRENT_USER\Control Panel\Desktop'
    If $iStyle = 1 Then
        RegWrite($sREG_DESKTOP, 'TileWallPaper', 'REG_SZ', 1)
        RegWrite($sREG_DESKTOP, 'WallpaperStyle', 'REG_SZ', 0)
    Else
        RegWrite($sREG_DESKTOP, 'TileWallPaper', 'REG_SZ', 0)
        RegWrite($sREG_DESKTOP, 'WallpaperStyle', 'REG_SZ', $iStyle)
    EndIf
    ; Idea from here: http://www.autoitscript.com/forum/topic/19370-autoit-wrappers/page__st__280#entry652536
    Local $tBuffer = DllStructCreate('wchar Text[' & StringLen($sImageFile) + 1 & ']')
    DllStructSetData($tBuffer, 'Text', $sImageFile)
    Return _WinAPI_SystemParametersInfo($SPI_SETDESKWALLPAPER, 0, DllStructGetPtr($tBuffer), BitOR($SPIF_UPDATEINIFILE, $SPIF_SENDCHANGE))
EndFunc   ;==>_ChangeDestopWallpaper

Edit: And why the hell do you put a .bmp filter in line 20 causing @error 2, this is definitely NOT required

Why the unnecessary hostility?

I've fixed the exclusion issue as Windows 7 has zero issue with jpgs.

Edited May 7, 2013 by guinness

[GreenCan]

Edit:

New versione release:

Changelog

;=====================================================
v.1.1.0 (07/05/2013)
Fixed Inetclose causes crash under some circumstances
Fixed Some code cleanup
Added New Style ;Thanks GreenCan for the documentation
Added Support to 'gif', 'jpeg', 'jpg', 'png', 'tiff' format
Added php code completely rewritten

Hi!

Nessie,

Prima: I am sorry but you still compress images that are larger than the screen resolution. The problem is that you don't check the size of the bitmap and act according to it.

Secunda: What is the benefit of you converting the .jpg (or other formats) file to a .bmp and then throwing it to Windows while Windows does it for you? Filling up disk space? Have you tried FlyingBoz _ChangeDestopWallpaper() ?

I don't want to sound negative, you still do what you like of course.

GreenCan

[GreenCan]

Why the unnecessary hostility?

I've fixed the exclusion issue as Windows 7 has zero issue with jpgs.

Don't worry, I have no hostility at all against nobody and in particular against you .. sorry if I shocked you.

The fix works on my W7 x64 too.

Thanks

Edited May 7, 2013 by GreenCan

[guinness]

The fix works on my W7 x64 too.

You're welcome.

I believe this is the first time I've seen the WinAPI function used, others call the Dll directly using the incorrect types. But I must admit the MSDN article for SystemParametersInfo can cause headaches, me included.

[Nessie]

Nessie,

Prima: I am sorry but you still compress images that are larger than the screen resolution. The problem is that you don't check the size of the bitmap and act according to it.

Secunda: What is the benefit of you converting the .jpg (or other formats) file to a .bmp and then throwing it to Windows while Windows does it for you? Filling up disk space? Have you tried FlyingBoz _ChangeDestopWallpaper() ?

I don't want to sound negative, you still do what you like of course.

GreenCan

Hi i have tried the function that you posted with a jpg but it doesnt work, after the launche on Windows XP there is no wallpaper at all.

As i have read with windows xp you have to always convert the jpg or other format to bmp. With Win 7 you have no problem to use a directly jpg image.

Have you tested your that function on Windows XP? Because here it doesn't work. I will wait for your response.

Hi!

[GreenCan]

Have you tested your that function on Windows XP? Because here it doesn't work. I will wait for your response.

You are right, this is not supported feature in XP, and I don't have XP anymore here. Sorry.

You've got a point!

[Nessie]

You are right, this is not supported feature in XP, and I don't have XP anymore here. Sorry.

You've got a point!

Now i will include an exclusion to the function, so if the os is Vista and later there is no need to convert a jpg image to bmp. Just for security i will also test what kind of image format can handle the os >= Vista.

Now another curiosity about this styles n°4, i really can't find any documention on this, and even the link of the c++ programm that you linked to me a couple of post ago seems not to mention it:

expandcollapse popup

// Set the wallpaper style and tile.
// Two registry values are set in the Control Panel\Desktop key.
// TileWallpaper
// 0: The wallpaper picture should not be tiled
// 1: The wallpaper picture should be tiled
// WallpaperStyle
// 0: The image is centered if TileWallpaper=0 or tiled if TileWallpaper=1
// 2: The image is stretched to fill the screen
// 6: The image is resized to fit the screen while maintaining the aspect
// ratio. (Windows 7 and later)
// 10: The image is resized and cropped to fill the screen while
// maintaining the aspect ratio. (Windows 7 and later)

// Open the HKCU\Control Panel\Desktop registry key.
HKEY hKey = NULL;
hr = HRESULT_FROM_WIN32(RegOpenKeyEx(HKEY_CURRENT_USER,
L"Control Panel\\Desktop", 0, KEY_READ | KEY_WRITE, &hKey));
if (SUCCEEDED(hr))
{
PWSTR pszWallpaperStyle;
PWSTR pszTileWallpaper;

switch (style)
{
case Tile:
pszWallpaperStyle = L"0";
pszTileWallpaper = L"1";
break;

case Center:
pszWallpaperStyle = L"0";
pszTileWallpaper = L"0";
break;

case Stretch:
pszWallpaperStyle = L"2";
pszTileWallpaper = L"0";
break;

case Fit: // (Windows 7 and later)
pszWallpaperStyle = L"6";
pszTileWallpaper = L"0";
break;

case Fill: // (Windows 7 and later)
pszWallpaperStyle = L"10";
pszTileWallpaper = L"0";
break;
}

EDIT: Also setting the WallpaperStyle to 4 on Windows XP doesn't work, will test on Win 7 in a couple of hour.

Hi!

Edited May 7, 2013 by Nessie

[GreenCan]

Now i will include an exclusion to the function, so if the os is Vista and later there is no need to convert a jpg image to bmp. Just for security i will also test what kind of image format can handle the os >= Vista.

That sounds like a good idea.

Now another curiosity about this styles n°4, I really can't find any documention on this, and even the link of the c++ programm that you linked to me a couple of post ago seems not to mention it

EDIT: Also setting the WallpaperStyle to 4 on Windows XP doesn't work, will test on Win 7 in a couple of hour.

Yes, it is very strange, I agree, I don't know where I found it exactly, and still I assure you that style 4 works very well. If the image is bigger the the screen resolution, Windows shrinks the image to perfectly fit on screen without changing the aspect ratio of the image. By the way, I tried style 6 and 10, and the image keeps it's original size, does not function on W7. It's really strange....

And yes, it's again a W7 feature... You don't have W7 where you could test it?

GreenCan

Edited May 7, 2013 by GreenCan

[Nessie]

That sounds like a good idea.

Yes, it is very strange, I agree, I don't know where I found it exactly, and still I assure you that style 4 works very well. If the image is bigger the the screen resolution, Windows shrinks the image to perfectly fit on screen without changing the aspect ratio of the image. By the way, I tried style 6 and 10, and the image keeps it's original size, does not function on W7. It's really strange....

And yes, it's again a W7 feature... You don't have W7 where you could test it?

GreenCan

I can test it on W7, i will test that in a couple of minutes

By the way i have found something that talk about this style n°4

http://www.rtwincustomize.net/index.php?option=com_content&view=article&id=3358:how-to-change-wallpaper-style-view-in-theme-file&catid=59:windows-seven-tutorials&Itemid=143

But he doesn't explain too much what excatly do. Do you use style n°4 with TileWallpaper=1?

EDIT: I have tried to set as a wallpaper an image with a resolution higher than the the screen resolution. I have used the style n°4 with TileWallpaper=1 and doesn't work, the image just simply does not look good.

EDIT 2: Style n°10 seems to do what you are telling for style n°4, with style 10 if an imagehas an higher resolution than screen, windows will automatically resize de wallpaper.

Hi!

Edited May 7, 2013 by Nessie