_FilePrefix/SRE - Append a prefix before the extension of a filepath.

[guinness]

I haven't posted anything in the examples section for about 6-7 weeks, so felt it was that time again. This shows how to use the string functions of AutoIt and regular exp<b></b>ressi&#111;ns. The header pretty much explains what the function(s) do.

 

expandcollapse popup

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

MsgBox($MB_SYSTEMMODAL, '', _FilePrefix(@ScriptFullPath)) ; Append _ thus creating C:\Example\Test_.exe
MsgBox($MB_SYSTEMMODAL, '', _FilePrefixSRE(@ScriptFullPath & '.text')) ; Append _ thus creating C:\Example\Test_.exe

; #FUNCTION# ====================================================================================================================
; Name ..........: _FilePrefixSRE
; Description ...: Append a prefix before the file extension.
; Syntax ........: _FilePrefixSRE($sFilePath[, $sPrefix = Default])
; Parameters ....: $sFilePath           - Filepath or name to append a prefix before the file extension.
;                  $sPrefix             - [optional] A string value. Default is '_'.
; Return values .: Success - Filepath with the intended prefix.
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func _FilePrefixSRE($sFilePath, $sPrefix = Default)
    If $sPrefix = Default Or StringStripWS($sPrefix, $STR_STRIPALL) == '' Then $sPrefix = '_'
    Return StringRegExpReplace($sFilePath, '^(.+?)(\.\w+)?$', '${1}' & $sPrefix & '${2}')
EndFunc   ;==>_FilePrefixSRE

; #FUNCTION# ====================================================================================================================
; Name ..........: _FilePrefix
; Description ...: Append a prefix before the file extension.
; Syntax ........: _FilePrefix($sFilePath[, $sPrefix = Default])
; Parameters ....: $sFilePath           - Filepath or name to append a prefix before the file extension.
;                  $sPrefix             - [optional] A string value. Default is '_'.
; Return values .: Success - Filepath with the intended prefix.
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func _FilePrefix($sFilePath, $sPrefix = Default)
    If $sPrefix = Default Or StringStripWS($sPrefix, $STR_STRIPALL) == '' Then $sPrefix = '_'
    Local $iDot = StringInStr($sFilePath, '.', Default, -1) - 1
    If $iDot <= 0 Then $iDot = StringLen($sFilePath)
    Return StringLeft($sFilePath, $iDot) & $sPrefix & StringTrimLeft($sFilePath, $iDot)
EndFunc   ;==>_FilePrefix

Edited February 23, 2014 by guinness

[wraithdu]

The SRE fails on a path like this

@ScriptFullPath & ".append.txt"

I think this might work

StringRegExpReplace($sFilePath, '^(.+?)(\.\w+)?$', '\1' & $sPrefix & '\2')

[guinness]

True, I did think about adding ? for the smallest possible match, but didn't for some reason. Thanks wraithdu.

Note: Don't think, just do.

[wraithdu]

No problem. I had SRE on the brain from last night. I was playing around with it to parse CSV lines. I came up with something, but even so it would require multiple passes to clean up the returned data, so decided to do it char by char. CSV kinda sucks by the way.

[guinness]

Updated with the suggestion by wraithdu. I thought I had all bases covered but seems I was wrong.

Edited February 23, 2014 by guinness

[guinness]

No problem. I had SRE on the brain from last night. I was playing around with it to parse CSV lines. I came up with something, but even so it would require multiple passes to clean up the returned data, so decided to do it char by char. CSV kinda sucks by the way.

Sometimes it's the only way.

[UEZ]

Here another way:

ConsoleWrite(_FilePrefix2("C:\autoit.rulez.exe") & @CRLF)

Func _FilePrefix2($sPath, $sInsert = "_")
    Local $iPos = StringInStr($sPath, ".", 0, -1)
    If Not $iPos Then Return $sPath & $sInsert
    Return StringLeft($sPath, $iPos - 1) & $sInsert &  StringMid($sPath, $iPos, StringLen($sPath) - $iPos + 1)
EndFunc

Br,

UEZ

Edited April 5, 2013 by UEZ

[PhoenixXL]

You should use '${1}' & $sPrefix & '${2}'. Otherwise if the prefix is a number, it would cause an error

[guinness]

Thanks UEZ. My function returns with the prefix if there isn't a dot present.

True PhoenixXL. I will fix this.

[UEZ]

Added same feature.

Br,

UEZ

[guinness]

Thanks.

[DXRW4E]

Script in the first post works very well, however in each case as already mentioned here the h in the end solves everything in this case

maybe it's better to use

StringRegExpReplace($sFilePath & " ", "(\.[^\.\/\\]*)?(\h)$", $sPrefix & "$1")

Ciao.

Edited April 5, 2013 by DXRW4E

[guinness]

Script in the first post works very well, however in each case as already mentioned here the h in the end solves everything in this case

maybe it's better to use

StringRegExpReplace($sFilePath & " ", "(\.[^\.\/\\]*)?(\h)$", $sPrefix & "$1")

Ciao.

 

Thanks as well.

[guinness]

Optimised the following snippets and includes.