Sort Functions Alphabetically, and Place them at the end of the Script

[ActualAkshay]

What I want to do is to place functions from a script at it ends in alphabetical order

EXAMPLE

Input au3

$var ="Sample au3"

Func _yo()

;some script 2

Endfunc

Func _akshay()

;some script 1

Endfunc

Output au3

$var ="Sample au3"

Func _akshay()

;some script 1

Endfunc

Func _yo()

;some script 2

Endfunc

can anyone help me out?

[jdelaney]

If you upgrade scite (download page), you can do an Alt+L to get a list of functions (sorted)...kind of removes the need for this, right?

Else:

fileread

stringregexp

_arraysort

_filecreate

filewrite in a loop

Edited April 4, 2013 by jdelaney

[BrewManNH]

Add this to your script

#Tidy_Parameters=/sf

[ActualAkshay]

@

If you upgrade scite (download page), you can do an Alt+L to get a list of functions (sorted)...kind of removes the need for this, right?

Else:

fileread

stringregexp

_arraysort

_filecreate

filewrite in a loop

I am talking about full functions, not only the "function names"

[ActualAkshay]

Add this to your script

#Tidy_Parameters=/sf

tried this before posting here, it doesnt seem to work, maybe functions are sorted before compiling the script, but I want au3 file with sorted functions

[BrewManNH]

Did you run Tidy on your script?

[ActualAkshay]

Did you run Tidy on your script?

Sure bro

[Malkey]

Here is one way to sort the functions of a .au3 file.

#include <Array.au3>

Local $sFileName, $File, $aArr, $sFuncless, $sSortedFuncs, $sNewFileName

$sFileName = "Input.au3"
$File = FileRead($sFileName)

$aArr = StringRegExp($File, "(?i)func (.+?)\(", 3)
;_ArrayDisplay($aArr)

_ArraySort($aArr)
;_ArrayDisplay($aArr)

$sFuncless = StringTrimRight(StringRegExpReplace($File, "(?is)\s*func.+?endfunc[^\v]*\s*", @CRLF), 2)
ConsoleWrite($sFuncless & @LF)

$sSortedFuncs = ""
For $i = 0 To UBound($aArr) - 1
$sSortedFuncs &= @CRLF & @CRLF & StringRegExpReplace($File, "(?is).*(Func " & $aArr[$i] & ".+?EndFunc[^\v]*).*$", "\1")
Next
;ConsoleWrite($sFuncless & @CRLF & $sSortedFuncs & @LF)

$sNewFileName = StringRegExpReplace($sFileName, "(.+)(\.au3)", "\1SF\2") ; The file, "Input.au3" becomes "InputSF.au3", the output file.
If FileExists($sNewFileName) Then FileDelete($sNewFileName)
FileWrite($sNewFileName, $sFuncless & $sSortedFuncs)

Edit: The example now works for the scenario when the script is interspersed between the functions.

Edit2: This example does not allow for comments before a function.

Edited April 5, 2013 by Malkey

[PhoenixXL]

Can you check your code with this as Input.au3

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>


;In the Following Example the numbers and the Colon(:) can be entered into the Edit control only.


Global $Chars, $hInput

GUICreate('Test', 220, 180)
GUICtrlCreateInput('', 10, 10, 200, 20)

;Check StringRegExp function in the Helpfile to learn about Meta-characters what is here "\d" stands for digit
_SetAllowedChars(GUICtrlGetHandle(-1),'\d:')

;Register WM_COMMAND
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')

GUISetState()


While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd

Func WM_COMMAND($hWnd, $imsg, $iwParam, $ilParam)
If $ilParam <> $hInput Then Return $GUI_RUNDEFMSG

Static $spText = ''
$nNotifyCode = _WinAPI_HiWord($iwParam)

Switch $nNotifyCode
Case $EN_CHANGE
$nID = _WinAPI_LoWord($iwParam) ;Control ID
$sText = GUICtrlRead($nID) ; THe Text in the Control

If StringRegExp($sText, '^[' & $Chars & ']*$') = 0 Then ; IF the Text is not Valid
GUICtrlSetData($nID, $spText) ;Erase the Text
Else
$spText = $sText
EndIf
EndSwitch

Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND

Func _SetAllowedChars($hEdit, $sChars)
;Check if the Chars input is valid
StringRegExp("", '^[' & $sChars & ']$')
If @error = 2 Then Return SetError(1, @error, @extended)

$Chars = $sChars
$hInput = $hEdit

EndFunc ;==>_SetAllowedChars

Some of the required lines are deleted.. !!

Edited April 5, 2013 by PhoenixXL

[guinness]

My question is why?

[guinness]

If you upgrade scite (download page), you can do an Alt+L to get a list of functions (sorted)...kind of removes the need for this, right?

And SciTE Jump.

[PhoenixXL]

Check if it fits your needs

expandcollapse popup

#include <Array.au3>

$String = FileRead(@ScriptFullPath)
$hFile = FileOpen(@ScriptFullPath, 2 )
FileWrite( $hFile, SortFunctions($String))
FileClose( $hFile )

Func SortFunctions($Source, $iDescending = 0, $fDebug = False)

;Get the Array of Array of Functions
$aFunc = StringRegExp($Source, '(?ism)(^\h*Func\h+\w+.+?^\h*EndFunc.*?$)', 3)
$aTemp = $aFunc ;For the Original Position of the Functions

;Sort The Functions
_ArraySort($aFunc, $iDescending)

;Lets Replace the Functions
If $fDebug Then _ArrayDisplay( $aTemp, "Original Func" )
If $fDebug Then _ArrayDisplay( $aFunc, "Sorted Func")

For $i = 0 To UBound($aFunc) - 1
$Source = StringReplace($Source, $aTemp[$i], $aFunc[$i], -1)
Next

Return $Source
EndFunc   ;==>SortFunctions

Func Y()
;
EndFunc   ;==>X

Func X()
;
EndFunc   ;==>Y

Func A()
;
EndFunc   ;==>A

Thumbs if it helped

Regards

[guinness]

It works.

Thumbs if it helped.

I did, but felt a bit silly giving a thumbs up to my monitor.

[PhoenixXL]

I did, but felt a bit silly giving a thumbs up to my monitor.

Good Sense of humour

[ActualAkshay]

Check if it fits your needs

expandcollapse popup

#include <Array.au3>

$String = FileRead(@ScriptFullPath)
$hFile = FileOpen(@ScriptFullPath, 2 )
FileWrite( $hFile, SortFunctions($String))
FileClose( $hFile )

Func SortFunctions($Source, $iDescending = 0, $fDebug = False)

;Get the Array of Array of Functions
$aFunc = StringRegExp($Source, '(?ism)(^\h*Func\h+\w+.+?^\h*EndFunc.*?$)', 3)
$aTemp = $aFunc ;For the Original Position of the Functions

;Sort The Functions
_ArraySort($aFunc, $iDescending)

;Lets Replace the Functions
If $fDebug Then _ArrayDisplay( $aTemp, "Original Func" )
If $fDebug Then _ArrayDisplay( $aFunc, "Sorted Func")

For $i = 0 To UBound($aFunc) - 1
$Source = StringReplace($Source, $aTemp[$i], $aFunc[$i], -1)
Next

Return $Source
EndFunc ;==>SortFunctions

Func Y()
;
EndFunc ;==>X

Func X()
;
EndFunc ;==>Y

Func A()
;
EndFunc ;==>A

Thumbs if it helped

Regards

Thanks it works perfectly But the only problem is that the functions arent placed at the end of the file Edited April 5, 2013 by ActualAkshay

[guinness]

That's easy to achieve and something you could do yourself, if you gave it a try. Think laterally.

[ActualAkshay]

Thanks it works perfectly But the only problem is that the functions arent placed at the end of the file

That's easy to achieve and something you could do yourself, if you gave it a try. Think laterally.

Oh thanks for your suggestion bro i have done it finally dont need help anymore, thanks everyone