12 hours of no solution and need help

[kcd-clan]

Here is what we have.

command("test",'0,"test","ahhh"')

Func test($msg1,$msg2,$msg3,$msg4=0)
MsgBox($msg1, $msg2, $msg3,$msg4)
EndFunc

Func command($cmd$,$myArray)
Call($cmd, $myArray)
EndFunc

I think this should do as far as information.

I extracted it and simplified because to real code has alot of loops and user defined function calls.

Once i get this missing piece i can move on.

Bassically the issue i think i have is, I call command and array isnt defined so it will error itself.

My debugger i made tells me invalid command...

IDK just posting this makes me think maybe the issue isnt the array.

[matwachich]

You need to learn the language a little more: You cannot pass >2 arguments to a function that waits only 2

The solution to avoid messy code is the Execute function

$sCmd = 'MsgBox(0, "Test", "Hi!")'
Execute($sCmd)

[JohnOne]

No-where near enough info to diagnose a problem.

For starters you are calling a function which takes 2 arguments with 3.

[kcd-clan]

You need to learn the language a little more: You cannot pass >2 arguments to a function that waits only 2

WOOOOOH

TY much.

The solution to avoid messy code is the Execute function

$sCmd = 'MsgBox(0, "Test", "Hi!")'
Execute($sCmd)

[PhoenixXL]

This is another example to call from an Array, I found it in the FORUM and it was written by Trancexx

Func CallArrayEx($sFuncName, $aNew)

$aRet = $sFuncName & "("
For $n = 0 To UBound($aNew) - 1
$aRet &= "$aNew[" & $n & "],"
Next
;Execute
$aRet = Execute(StringTrimRight($aRet, 1) & ")")
;Finally return
Return SetError(@error, @extended, $aRet)

EndFunc   ;==>CallArrayEx

Local $aParameters[3] = [64, "Hello There", "Tested Successfully"]
CallArrayEx("MsgBox", $aParameters)

$aParameters = "64|Hello There|Tested Successfully"
CallArrayEx("MsgBox", StringSplit($aParameters, "|", 2))

[water]

What you pass here as parameter 2 isn't an array. It's just a string:

command("test",'0,"test","ahhh"')

Use function StringSplit to create an array from this string.

[PhoenixXL]

I have elaborated what Water said

Local $aSplit = StringSplit('0,"test","ahhh"', ",")
$aSplit[0] = "CallArgArray" ;First element should be this string according to the Help File.
command("test", $aSplit)

Func test($msg1, $msg2, $msg3, $msg4 = 0)
MsgBox($msg1, $msg2, $msg3, $msg4)
EndFunc   ;==>test

Func command($cmd, $myArray)
Call($cmd, $myArray)
EndFunc   ;==>command

[water]

Great! Learned something new today