_3DArrayDislpay

[jdelaney]

Ever wanted to debug up to a 3d array? (can be modified to create window for any number of dimentions; was also thinking about adding links for array in arrays)
 

expandcollapse popup

#include <ListviewConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
Local $aTest[3][2][3] = [[["aa1", "aa2", "aa3"],["ab1", "ab2", "ab3"]],[["ba1", "ba2", "ba3"],["bb1", "bb2", "bb3"]],[["ca1", "ca2", "ca3"],["cb1", "cb2", "cb3"]]]
;~ Local $aTest[2][3] =[["aa1", "aa2", "aa3"],["ab1", "ab2", "ab3"]]
_3DArrayDisplay($aTest)
Func _3DArrayDisplay($aCallersArray)
 $iGuiHeight = 400
 $iGuiWidth = 400
 $hgui = GUICreate("3D Array", $iGuiWidth, $iGuiHeight)
 $i1D_Ubound = UBound($aCallersArray)
 $i2D_Ubound = UBound($aCallersArray, 2)
 $i3D_Ubound = UBound($aCallersArray, 3)
 If @error Then
  _ArrayDisplay($aCallersArray)
  Return $aCallersArray
 EndIf
 Local Enum $i2DHolder_TabControl, $i2DHolder_Array, $i2DHolder_UBound
 Local $a2DHolder[$i1D_Ubound][$i2DHolder_UBound]
 For $i = 0 To $i1D_Ubound - 1
  Local $aTemp[$i2D_Ubound][$i3D_Ubound]
  For $j = 0 To 1
   For $k = 0 To 2
    $aTemp[$j][$k] = $aCallersArray[$i][$j][$k]
   Next
  Next
  $a2DHolder[$i][$i2DHolder_Array] = $aTemp
 Next
 GUICtrlCreateTab(10, 10, $iGuiWidth - 20, $iGuiHeight - 20)
 For $i = 0 To UBound($a2DHolder) - 1
  $aTemp = $a2DHolder[$i][$i2DHolder_Array]
  $a2DHolder[$i][$i2DHolder_TabControl] = GUICtrlCreateTabItem("Dimension" & $i)
  $breaks = "Column0"
  For $j = 0 To UBound($aTemp, 2) - 2
   $breaks &= "|Column" & $j + 1
  Next
  $iListView = GUICtrlCreateListView($breaks, 20, 40, $iGuiWidth - 40, $iGuiHeight - 60, -1, $LVS_EX_GRIDLINES)
  For $j = 0 To UBound($aTemp) - 1
   For $k = 0 To UBound($aTemp, 2) - 1
    If $k = 0 Then
     $string = $aTemp[$j][$k]
    Else
     $string = $string & "|" & $aTemp[$j][$k]
    EndIf
   Next
   ConsoleWrite($string & @CRLF)
   GUICtrlCreateListViewItem($string, $iListView)
  Next
 Next
 GUISetState(@SW_SHOW)
 Do
  Local $msg = GUIGetMsg()
 Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>_3DArrayDisplay

edit: when the forum updated, it killed the @error on line 23...just updated

Edited November 22, 2013 by jdelaney

[FireFox]

Another way (I have not searched if it has already been done) :

expandcollapse popup

#include <GUIConstantsEx.au3>

Local $aArray3D[3][2][3] = [ _
        [ _
            ["aa1", "aa2", "aa3"], _
            ["ab1", "ab2", "ab3"] _
        ], _
        [ _
            ["ba1", "ba2", "ba3"], _
            ["bb1", "bb2", "bb3"] _
        ], _
        [ _
            ["ca1", "ca2", "ca3"], _
            ["cb1", "cb2", "cb3"] _
        ] _
    ]

_ArrayDisplayTreeView($aArray3D)

Func _ArrayDisplayTreeView(ByRef $avArray, $blExpandAll = True)
    Local Const $iUBound_1D = UBound($avArray, 1)
    Local Const $iUBound_2D = UBound($avArray, 2)
    Local Const $iUBound_3D = UBound($avArray, 3)

    Local Const $hGUI = GUICreate("Array TreeView Display", 400, 550)

    Local Const $iTreeView = GUICtrlCreateTreeView(10, 10, 380, 530)
    Local Const $iSubTree1D = GUICtrlCreateTreeViewItem("Array (" & $iUBound_1D & ")", $iTreeView)

    Local $iSubTree2D = 0, $iSubTree3D = 0

    For $i_1D = 0 To $iUBound_1D -1
        If $iUBound_2D = 0 Then
            GUICtrlCreateTreeViewItem($avArray[$i_1D], $iSubTree1D)
            ContinueLoop
        EndIf

        $iSubTree2D = GUICtrlCreateTreeViewItem("Array (" & $iUBound_2D & ")", $iSubTree1D)

        For $i_2D = 0 To $iUBound_2D -1
            If $iUBound_3D = 0 Then
                GUICtrlCreateTreeViewItem($avArray[$i_1D][$i_2D], $iSubTree2D)
                ContinueLoop
            EndIf

            $iSubTree3D = GUICtrlCreateTreeViewItem("Array (" & $iUBound_3D & ")", $iSubTree2D)

            For $i_3D = 0 To $iUBound_3D -1
                GUICtrlCreateTreeViewItem($avArray[$i_1D][$i_2D][$i_3D], $iSubTree3D)
            Next

            If $blExpandAll Then GUICtrlSetState($iSubTree3D, $GUI_EXPAND)
        Next

        If $blExpandAll Then GUICtrlSetState($iSubTree2D, $GUI_EXPAND)
    Next

    GUICtrlSetState($iSubTree1D, $GUI_EXPAND)

    GUISetState(@SW_SHOW, $hGUI)

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
        Sleep(10)
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>_3DArrayDisplay

Edited March 30, 2013 by FireFox

[BrewManNH]

Nice examples.

I'll stick with 2D arrays though for me, way too confusing once you get too far off the norm at my age.

[FireFox]

Indeed, our monitors are currently in 2D; so it's not possible to clearly display 3D arrays.

[czardas]

Very nice example. I wonder what the practical limits would be for this - I suppose it depends on how many tabs you can create, and screen resolution.

I had a go at this My second example is better than the first. I think my code needs to be rewritten, although the implimentation is quite confusing.

Edited March 30, 2013 by czardas