[SOLVED/TICKET] _Capture wrong size

[johnmcloud]

Hi all, this is an example script:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ScreenCapture.au3>

$hGUI = GUICreate("", 200, 200, -1, -1)
$Button = GUICtrlCreateButton("Click", 64, 80, 105, 41)
GUISetState(@SW_SHOW)
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button
_ScreenCapture_Capture(@ScriptDir & "\Test_1.jpg", 0, 0, -1, -1, True)
$hJpg = _ScreenCapture_Capture("")
_ScreenCapture_SaveImage(@ScriptDir & "\Test_2.jpg", $hJpg)
EndSwitch
WEnd

All the parameter are to default, both method but is the same result:

The finale image has 1 pixel more then the real desktop size, so if the desktop is 1024-768, the image is 1025x769

I don't want to say that word so i'll think it

Edited March 27, 2013 by johnmcloud

[water]

Function _ScreenCapture_Capture is a function of the ScreenCapture UDF.

So why not search the error, create a ticket on Trac and post the solution for the Devs to implement?

[johnmcloud]

I have check it out the UDF, the solution is:

Local $iW = ($iRight - $iLeft) + 1
Local $iH = ($iBottom - $iTop) + 1

To

Local $iW = ($iRight - $iLeft)
Local $iH = ($iBottom - $iTop)

But i don't know if break something or not, i don't know why the author add this +1 to the $iW and $iH

Oh, i don't know how to send a ticket to the devs

I don't know many things

Edited March 27, 2013 by johnmcloud

[water]

The calculation of the width is correct in my eyes.

Lets say you want to grab from pixel 10 to 12. The reslt needs to include pixel 10, 11 and 12 = 3 pixels. The current formula returns 3, your formula would return 2.

To open a ticket simply click on "BugTracker" on the top of this page.

[johnmcloud]

I have opened a ticket:

http://www.autoitscript.com/trac/autoit/ticket/2329

If there are news i'll post here, thanks

[water]

[KaFu]

There's already a ticket for this.

http://www.autoitscript.com/trac/autoit/ticket/2305

Edit: Esp. look at the comment section for correction.

Edited March 27, 2013 by KaFu

[Melba23]

Hi,

I just posted a solution to johnmcloud's ticket - glad to see it was the same as that one!

M23

[KaFu]

So it seems to be a good one ...

[johnmcloud]

Cool, thanks but why if that problem was already tracked month ago ( and solved with the same script) there is no trace in the beta? Just for know

[guinness]

OK, I will commit to the UDFs today. I will link the commit to KaFu's ticket and close johnmcloud's as a duplicate and reference KaFu's in the process.

Edit: All done!

Edited March 27, 2013 by guinness

[guinness]

Cool, thanks but why if that problem was already tracked month ago ( and solved with the same script) there is no trace in the beta? Just for know

Firstly the problem wasn't fixed in the UDFs and secondly the beta release cycle isn't monthly. This is down to the Devs to decide when AutoIt beta is ready for testing.

For now my advice would be copy the screen capture function to your script with the proposed fix by Melba23 & KaFu and call it something like... _ScreenCapture_FixedByMelbaAndKaFuInTheYearOf2013_OhAndguinnessIsAwesomeToo(). You get the idea 0_-!

[johnmcloud]

_ScreenCapture_FixedByMelbaAndKaFuInTheYearOf2013_OhAndguinnessIsAwesomeToo(). You get the idea 0_-!

Maybe you need to add ...OhAndguinnessIsAwesomeToo_AndNotForgetJohnmcloudBecauseHeOpenAnUnusefulDuplicateTicket()

I think for now i'll simply use:

$size[2] = [1024,768] ; example
_ScreenCapture_Capture(@ScriptDir & "\Test_1.jpg", 0, 0, $size[1] -1, $size[2] -1, True)

Or something like that with desktop macros, i think the result is the same ( or not? )

Edited March 27, 2013 by johnmcloud

[guinness]

Can you guys check this for me please. I'm being told it's returning the wrong size, though I can't see it myself. Thanks.

expandcollapse popup

#include <ScreenCapture.au3>

; Capture full screen
_ScreenCapture_Capture_Beta(@MyDocumentsDir & "\GDIPlus_Image1.jpg")

; Capture region
_ScreenCapture_Capture_Beta(@MyDocumentsDir & "\GDIPlus_Image2.jpg", 0, 0, 796, 596)

ShellExecute(@MyDocumentsDir)

; #FUNCTION# ====================================================================================================================
; Name...........: _ScreenCapture_Capture_Beta
; Description ...: Captures a region of the screen
; Syntax.........: _ScreenCapture_Capture_Beta([$sFileName = ""[, $iLeft = 0[, $iTop = 0[, $iRight = -1[, $iBottom = -1[, $fCursor = True]]]]]])
; Parameters ....: $sFileName   - Full path and extension of the image file
;                  $iLeft       - X coordinate of the upper left corner of the rectangle
;                  $iTop        - Y coordinate of the upper left corner of the rectangle
;                  $iRight      - X coordinate of the lower right corner of the rectangle.  If this is  -1,  the  current  screen
;                  +width will be used.
;                  $iBottom     - Y coordinate of the lower right corner of the rectangle.  If this is  -1,  the  current  screen
;                  +height will be used.
;                  $fCursor     - If True the cursor will be captured with the image
; Return values .: See remarks
; Author ........: Paul Campbell (PaulIA)
; Modified.......:
; Remarks .......: If FileName is not blank this function will capture the screen and save it to file. If FileName is blank, this
;                  function will capture the screen and return a HBITMAP handle to the bitmap image.  In this case, after you are
;                  finished with the bitmap you must call _WinAPI_DeleteObject to delete the bitmap handle.
;+
;                  Requires GDI+: GDI+ requires a redistributable for applications  that
;                  run on the Microsoft Windows NT 4.0 SP6, Windows 2000, Windows 98, and Windows Me operating systems.
; Related .......: _WinAPI_DeleteObject, _ScreenCapture_SaveImage
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _ScreenCapture_Capture_Beta($sFileName = "", $iLeft = 0, $iTop = 0, $iRight = -1, $iBottom = -1, $fCursor = True)
    If $iRight = -1 Then $iRight = _WinAPI_GetSystemMetrics($__SCREENCAPTURECONSTANT_SM_CXSCREEN) - 1
    If $iBottom = -1 Then $iBottom = _WinAPI_GetSystemMetrics($__SCREENCAPTURECONSTANT_SM_CYSCREEN) - 1
    If $iRight < $iLeft Then Return SetError(-1, 0, 0)
    If $iBottom < $iTop Then Return SetError(-2, 0, 0)

    Local $iW = ($iRight - $iLeft) + 1
    Local $iH = ($iBottom - $iTop) + 1
    Local $hWnd = _WinAPI_GetDesktopWindow()
    Local $hDDC = _WinAPI_GetDC($hWnd)
    Local $hCDC = _WinAPI_CreateCompatibleDC($hDDC)
    Local $hBMP = _WinAPI_CreateCompatibleBitmap($hDDC, $iW, $iH)
    _WinAPI_SelectObject($hCDC, $hBMP)
    _WinAPI_BitBlt($hCDC, 0, 0, $iW, $iH, $hDDC, $iLeft, $iTop, $__SCREENCAPTURECONSTANT_SRCCOPY)

    If $fCursor Then
        Local $aCursor = _WinAPI_GetCursorInfo()
        If $aCursor[1] Then
            Local $hIcon = _WinAPI_CopyIcon($aCursor[2])
            Local $aIcon = _WinAPI_GetIconInfo($hIcon)
            _WinAPI_DeleteObject($aIcon[4]) ; delete bitmap mask return by _WinAPI_GetIconInfo()
            If $aIcon[5] <> 0 Then _WinAPI_DeleteObject($aIcon[5]); delete bitmap hbmColor return by _WinAPI_GetIconInfo()
            _WinAPI_DrawIcon($hCDC, $aCursor[3] - $aIcon[2] - $iLeft, $aCursor[4] - $aIcon[3] - $iTop, $hIcon)
            _WinAPI_DestroyIcon($hIcon)
        EndIf
    EndIf

    _WinAPI_ReleaseDC($hWnd, $hDDC)
    _WinAPI_DeleteDC($hCDC)
    If $sFileName = "" Then Return $hBMP

    Local $ret = _ScreenCapture_SaveImage($sFileName, $hBMP, True)
    Return SetError(@error, @extended, $ret)
EndFunc   ;==>_ScreenCapture_Capture_Beta

[Melba23]

guinness,

As the code is exactly what I suggest, I am not surprised that it returns exactly the size of image that I think it should:

- 1. 1680 x 1050 (full screen)

- 2. 797 x 597

As I pointed out in the Trac ticket asking for (0, 0, 796, 596) should produce a 797 x 597 image - which it does.

M23

Edited March 29, 2013 by Melba23
Because I wanted to!

[johnmcloud]

Sorry Melba but i don't understand, why the 2. is correct? From my point of view is wrong. If i set 796x596 should not to create an image of 796x596 instead of 797x597? If not, 1. is wrong because create an image of 1680x1050 instead of 1681x1051 >_<

This create both correct size:

If $iRight = -1 Then
$iRight = _WinAPI_GetSystemMetrics($__SCREENCAPTURECONSTANT_SM_CXSCREEN) - 1
Else
$iRight = $iRight - 1
EndIf
If $iBottom = -1 Then
$iBottom = _WinAPI_GetSystemMetrics($__SCREENCAPTURECONSTANT_SM_CYSCREEN) - 1
Else
$iBottom = $iBottom - 1
EndIf

I hope I have not written too many stupid things lol

Edited March 29, 2013 by johnmcloud

[BrewManNH]

0 to 796 is 797 pixels.

[Melba23]

johnmcloud,

The first is correct because that is the size of the screen. But the pixels on the screen go from 0-1679 (= 1680) and 0-1049 (= 1050) - so an image of 1680x1050 is correct.

The second is also correct as we ask for the pixels from 0-796 (= 797) and 0-596 (= 597) - so we should get an image of 797x597, which we do.

Think of it like an array - if you want elements 0-100, you need to declare it as [101]. If you declare it as [100] then you only get elements 0-99.

Clearer?

M23

[johnmcloud]

0 to 796 is 797 pixels.

So why this:

_ScreenCapture_Capture_Beta(@MyDocumentsDir & "\GDIPlus_Image1.jpg")

In the beta create an image of the correct size ( 1680 x 1050 instad of 1681 x 1051? Start always from zero ( $iLeft = 0 , $iTop = 0 )

EDIT: Melba, not totally convinced but i think you have right, in my head if i'll write 500x500 i want 500x500 but ok, i'll think it like an array

Edited March 29, 2013 by johnmcloud

[BrewManNH]

You posted the answer yourself, $iRight and $iBottom get 1 subtracted from them regardless of whether you specify a size or accept the default size of the whole screen.

If $iRight = -1 Then

$iRight = _WinAPI_GetSystemMetrics($__SCREENCAPTURECONSTANT_SM_CXSCREEN) - 1

Else

$iRight = $iRight - 1

EndIf

If $iBottom = -1 Then

$iBottom = _WinAPI_GetSystemMetrics($__SCREENCAPTURECONSTANT_SM_CYSCREEN) - 1

Else

$iBottom = $iBottom - 1

EndIf