Slider jumps

[careca]

Hi, found a post about something like this, but didn't quite get it.

The problem here is that i have a slider, and when i click somewhere in the slider,

the thingy starts jumping in the direction of the mouse press, but doesn't quite stay where im clicking.

Then it seemed like using "_GUICtrlSlider_Create" instead of "GUICtrlCreateSlider" would be a good option,

but it messed up everything, as the "GUICtrlSetData" doesn't work with it.

What are my options?

[Melba23]

careca,

Clicking on the slider away from the thumb (the correct name for the "thingy" ) moves the slider by one "page" in that direction. If you do not have the mouse cursor directly over a "page" boundary then you will not see the thumb move to the cursor and it may well over/undershoot. This is the standard behaviour of slider controls and nothing to do with whether they were created by the native or UDF functions.

Why do you need the thumb to move to precisely where you click the cursor?

M23

[careca]

Why do you need the thumb to move to precisely where you click the cursor?

Hi, thanks for the clarification, i need to move the thumb precisely because of the seek function of the music player.

It does work if i drag it, but most players allow you to just click the seek bar and the thumb will move there.

This is nothing to be seriously worried about, but would be nice if it worked.

[Melba23]

careca,

I think you might have to look at the mouse position when you click and then set the thumb to that position. I will have a play this afternoon and see what I can come up with.

M23

[BrewManNH]

I wouldn't use a slider for this, it may be easier to code it with one, but sliders have that annoying tendency to not move to where you click it.

I have done something similar with a progress bar to indicate where in the song it is, but overlayed that with a blank label. The label is used for getting the mouse click and you have to do a little math as to where on the GUI you clicked and then advance the song or rewind it to that part of the song you want to get to. It's not as easy to do it this way, because there's a lot of parts you need to know before-hand, such as the location of the progress bar in relation to the GUI, how long the song is, how to get the player to jump to the position of the mouse click, etc.

[Melba23]

careca,

Here is a rough idea of what I mean - it does essentially what BrewManNH has just described:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$cSlider = GUICtrlCreateSlider(10, 10, 480, 20)

$cButton = GUICtrlCreateButton("Test", 10, 50, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            $aCinfo = GUIGetCursorInfo()
            If $aCInfo[4] = $cSlider Then
                $iOldOpt = Opt("MouseCoordMode", 2)
                $aMpos = MouseGetPos()
                Opt("MouseCoordMode", $iOldOpt)
                ConsoleWrite($aMpos[0]                & @CRLF)
                $iSliderPos = Int(100 * ($aMPos[0] - 12) / 470)
                GUICtrlSetData($cSlider, $iSliderPos)
            EndIf
    EndSwitch

WEnd

I hope it is useful.

M23

[PhoenixXL]

A _IsPressed check would make it smooth.

M23's code..

#include <GUIConstantsEx.au3>
#include <Misc.au3>

Opt("MouseCoordMode", 2)

$hGUI = GUICreate("Test", 500, 200)

$cSlider = GUICtrlCreateSlider(10, 10, 480, 20)

GUISetState()

While 1

Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $GUI_EVENT_PRIMARYDOWN
$aCinfo = GUIGetCursorInfo()
If $aCinfo[4] = $cSlider Then
While _IsPressed("01")
$aMpos = MouseGetPos()
$iSliderPos = Int(100 * ($aMpos[0] - 12) / 470)
GUICtrlSetData($cSlider, $iSliderPos)
WEnd
ConsoleWrite($aMpos[0] & @CRLF) ;show at release otherwise it becomes a mess
EndIf
EndSwitch

WEnd

Edited March 14, 2013 by PhoenixXL

[BrewManNH]

Here's how I'd do it using a ProgressBar, no UDFs needed.

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 200)
$cLabel = GUICtrlCreateLabel("", 10, 10, 480, 20)
$cProgress = GUICtrlCreateProgress(10, 10, 480, 20)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cLabel
            $aMpos = GUIGetCursorInfo($hGUI)
            $iPercent = Int(100 * ($aMpos[0] - 12) / 470)
            GUICtrlSetData($cProgress, $iPercent)
            ConsoleWrite($aMpos[0] & @CRLF)
    EndSwitch
WEnd

[careca]

Thanks y'all for the help, i'll look into each of the sugestions and choose the one that better suits.

Haveniceday

[careca]

Hey guys, thank you for your help, this is what i ended up doing:

If $CursorInfo[2] = 1 And $CursorInfo[4] = $Slider1 Then
While _IsPressed("01", $hDLL)
$aMpos = MouseGetPos()
$SeekB2Secs = Int(100 * ($aMpos[0] - 12) / 352)
GUICtrlSetData($Slider1, $SeekB2Secs)
$Seek = GUICtrlRead($Slider1)
$SeekB2Secs = $Seek * $Lenght / 100
WEnd
_BASS_ChannelSetPosition($MusicHandle, $SeekB2Secs, $BASS_POS_BYTE)
EndIf

Greetings.