"Loops"

[Hallistorm1989]

Case $Button3
$Test=GUICtrlRead($Input1)
$Amount=GUICtrlRead($Input2)
$counter= 0
While $counter<=$Amount
MsgBox(0,"Value of $counter is:",$Test)
$counter = $counter +1
WEnd
For $counter = 1 to $Amount

Hello guys.

I want that the message box will show up that much times , as it has been declared in the $Input2. Actually its working like i put 5 in the $input2 and it shows up 6 time ( if i put 6 in input box , it shows up 7 times)

i already tried this :

$counter = $counter +0

but it didnt work.

Could anyone help me out with that ?

[Melba23]

Hallistorm1989,

Remove the "=" from the condition - then you get the correct number of MsgBoxes:

$Amount = 3

$counter = 0
While $counter < $Amount
    $counter = $counter + 1
    MsgBox(0, "Value of $counter is:", $counter)
WEnd

But it would be best to use a For...Next loop and let AutoIt count for you - like this:

For $i = 1 To $Amount
    MsgBox(0, "Value of $counter is:", $i)
Next

All clear?

M23

[Hallistorm1989]

That easy ? Thank you very much , only question i got is ,

why its $Amount = 3? it would work if i make $Amount = GUICtrlRead($Input1) aint it ?

[Melba23]

Hallistorm1989,

The "3" was just for testing as I did not feel like creating a GUI to hold the input. It will still work with your code - but you might think of ensuring that you have a number in the input before you start looping.

M23

[Hallistorm1989]

Hallistorm1989,

The "3" was just for testing as I did not feel like creating a GUI to hold the input. It will still work with your code - but you might think of ensuring that you have a number in the input before you start looping.

M23

Ok , last thing i have to fix is:

If i got for if i have -1 in $Input2

How Could i block -numbers for this input box ? :/

Edited March 10, 2013 by Hallistorm1989

[Melba23]

Hallistorm1989,

Do as I suggested - get the content of the input and run some error-checking on it to make sure it is within bounds. Or you could force the input to accept only digits. Something like this should do the trick:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Only digits accepted!", 10, 10, 200, 20)
$cInput_1 = GUICtrlCreateInput("", 10, 30, 200, 20, $ES_NUMBER) ; Force digits only

$cInput_2 = GUICtrlCreateInput("", 10, 100, 200, 20)

$cButton = GUICtrlCreateButton("Read", 10, 200, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $sContent_1 = GUICtrlRead($cInput_1)
            $sContent_2 = GUICtrlRead($cInput_2)
            ; Convert content of Input 2 to an integer
            $vContent_2 = Int(Number($sContent_2))
            ; Check this value to see if it is at least 1 or above
            If $vContent_2 < 1 Then
                $vContent_2 = "Error"
            EndIf

            MsgBox(0, "Result", "Input 1: " & $sContent_1 & @CRLF & "Input 2: " & $vContent_2)

            GUICtrlSetData($cInput_1, "")
            GUICtrlSetData($cInput_2, "")

    EndSwitch

WEnd

All clear?

M23

[Hallistorm1989]

yes , thank you

[Melba23]

Hallistorm1989,

Glad I could help. I see you got me to code a GUI in the end!

M23