Multi dimensional arrays & stringsplit() function

[Tioner]

so I wanted to create a multi dimensional array using a loop and stringsplit function, it'd be all great but if the loop goes on over 100 times, the script wont run and will return the following error: ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.

for $i = 1 to 100
$array2 = stringsplit($array[$i],",")
Next

the loop as it is wont let the script compile or even run, if I decrease the 100 to 99 however, the script runs fine. the thing is I need to do over 5000 loops for it to be completed.

any ideas?

kind regards.

[jdelaney]

sounds like the UBound of your array is 99 (100, but starts at 0), not sure where you are pulling 5000 from

using array of arrays:

Local $array2[UBound($array)]
for $i = 0 to UBound($array)-1
$array2[$i] = stringsplit($array[$i],",")
Next

or search forum for csv splitter, tons out there

Edited March 6, 2013 by jdelaney

[PhoenixXL]

Array variable has incorrect number of subscripts or subscript dimension range exceeded.

I'm sure there is some error in your coding. Please submit the full code of the Array

[Tioner]

Thanks for the reply, and sorry for little information on my issue. Array[$i] has over 5000 entries so I thought I need to loop it 5000 times to create a 2d array. I'll put the code for both loops when I get home.

[guinness]

Look at UBound, ReDim, @error and the Array section in the AutoIt Wiki.

[Tioner]

#include 
#include 
#include 
#include 
#include 
#include 
global $i
$Form1 = GUICreate("Loading", 460, 177, -1, -1)
$Pic1 = GUICtrlCreatePic($pic, 0, 0, 460, 150, BitOR($SS_NOTIFY, $WS_GROUP))
$Progress1 = GUICtrlCreateProgress(2, 152, 456, 17)
GUICtrlSetData(-1, $i)
GUISetState(@SW_SHOW)
$file = "base.txt"
$lines = _FileCountLines($file)
$line = filereadline($file,1)
$string1 = stringsplit($line,",")
$string = $string1[0]
local $array[$lines], $i, $array2[$lines]
for $i = 1 to $lines
$array[$i-1] = filereadline($file, $i)
$percent = ($i/$lines)
$percent = $percent * 100
GUICtrlSetData($Progress1, $percent)
next
for $i = 1 to $lines-1
$percent = ($i/$lines)
$percent = $percent * 100
GUICtrlSetData($Progress1, $percent)
$array[$i-1][$i-1] = stringsplit($array[$i],",")
Next
GUISetState(@SW_HIDE)
msgbox(0,"",$array[3][1])

so here's the code for the entire script so far. I'm kinda struggling with the 2D array and how it could be built with 2 loops.

the file is also 2D, it contains columns and rows, I'm ill right now and I cant think bright enough to figure it out myself, so I'd love to get a tip from you guys what might be wrong. the most concerning question is about stringsplit() function, if there's already an array, (like so: $array[$i]) will it write the split elements to the first array or create a multidimenshional array out of the 1D array? so the code would look like so:

$array[$i-1] = stringsplit($array[$i],",")

or is this part correct, and it will assign the elements to the second square bracket [$i-1]

$array[$i-1][$i-1] = stringsplit($array[$i],",")

thanks for your time and I hope we can figure it out together.

[Nessie]

Can you provide to us the file base.txt?

Hi!

[czardas]

Here's a method:

#include <Array.au3> ; Needed for _ArrayDisplay

$sTest = "0,1,2|3,4,5,6|7,8,9"
$a2D = StringTo2dArray($sTest, "|", ",")
_ArrayDisplay($a2D)

Func StringTo2dArray($sString, $sDelim4Rows, $sDelim4Cols)
    Local $aArray = StringSplit($sString, $sDelim4Rows, 2) ; Split to get rows
    Local $iBound = UBound($aArray)

    Local $aRet[$iBound][2], $aTemp, $iOverride = 0
    For $i = 0 To $iBound -1
        $aTemp = StringSplit($aArray[$i], $sDelim4Cols) ; Split to get row items
        If Not @error Then
            If $aTemp[0] > $iOverride Then
                $iOverride = $aTemp[0]
                ReDim $aRet[$iBound][$iOverride] ; Add columns to accomodate more items
            EndIf
        EndIf

        For $j = 1 To $aTemp[0]
            $aRet[$i][$j -1] = $aTemp[$j] ; Populate each row
        Next
    Next
    If $iOverride <= 1 Then $aRet = $aArray ; Array contains single row or column

    Return $aRet
EndFunc ;==> StringTo2dArray

Edited March 8, 2013 by czardas