Text on buttons with icons

[Clark]

$ActGroup2 = GUICtrlCreateGroup("Actions", 50, 360, 520, 50)
$btnRefresh=GUICtrlCreateButton("Refresh",70,375,80,25)
GUICtrlSetImage(-1,"shell32.dll",221,0)
GUICtrlSetTip(-1,"Reset filter and refresh")
$btnExport=GUICtrlCreateButton("Export",170,375,80,25,$BS_ICON)
GUICtrlSetImage(-1,"C:\Program Files (x86)\Microsoft Office\Office14\EXCEL.EXE",1,0)
GUICtrlSetTip(-1,"Export to Excel")
$btnNew=GUICtrlCreateButton("New",270,375,80,25,$BS_ICON)
GUICtrlSetImage(-1,"shell32.dll",1,0)
GUICtrlSetTip(-1,"Create new RFC")
$btnExit = GUICtrlCreateButton("Exit", 370, 375, 80, 25)
GUICtrlSetImage(-1,"shell32.dll",329,0)
$btnOpen = GUICtrlCreateButton("Open", 470, 375, 80, 25)
GUICtrlSetImage(-1,"shell32.dll",290,0)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Hi all

In the following screen snap, you will notice that the second and third buttons do not have text, and yet in the code they clearly do.

Does anyone know why this is so?

[Nessie]

Try to remove ,$BS_ICON from the buttons

Hi!

Edited March 1, 2013 by Nessie

[Clark]

Thanks, that works.

I thought the $BS_ICON was required in order to show the icon.

edit: Which doesn't make a lot of sense as the ones that worked didn't have it.

Edited March 1, 2013 by Clark

[Nessie]

All's well that ends well

Edited March 1, 2013 by Nessie

[AZJIO]

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <GuiImageList.au3>

$hGui = GUICreate('My Program', 650, 460)
$ActGroup2 = GUICtrlCreateGroup("Actions", 50, 360, 520, 50)
$btnRefresh = GUICtrlCreateButton("Refresh", 70, 375, 80, 25)
_GUICtrlSetImage($btnRefresh, "shell32.dll", 221)
GUICtrlSetTip(-1, "Reset filter and refresh")
$btnExport = GUICtrlCreateButton("Export", 170, 375, 80, 25, $BS_ICON)
_GUICtrlSetImage($btnExport, "C:\Program Files\Microsoft Office\Office14\EXCEL.EXE", 1, 0)
GUICtrlSetTip(-1, "Export to Excel")
$btnNew = GUICtrlCreateButton("New", 270, 375, 80, 25, $BS_ICON)
_GUICtrlSetImage($btnNew, "shell32.dll", 1, 0)
GUICtrlSetTip(-1, "Create new RFC")
$btnExit = GUICtrlCreateButton("Exit", 370, 375, 80, 25)
_GUICtrlSetImage($btnExit, "shell32.dll", 329, 0)
$btnOpen = GUICtrlCreateButton("Open", 470, 375, 80, 25)
_GUICtrlSetImage($btnOpen, "shell32.dll", 290, 0)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState()
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _GUICtrlSetImage($hButton, $sFileIco, $iIndIco = 0, $iSize = 0)
    Switch $iSize
        Case 0
            $iSize = 16
        Case 1
            $iSize = 32
        Case Else
            $iSize = 16
    EndSwitch
    Local $hImage = _GUIImageList_Create($iSize, $iSize, 5, 3, 6)
    _GUIImageList_AddIcon($hImage, $sFileIco, $iIndIco)
    _GUICtrlButton_SetImageList($hButton, $hImage)
    Return $hImage
EndFunc   ;==>_GUICtrlSetImage

Edited March 1, 2013 by AZJIO

[Clark]

Thanks Azjio, but I'm not understanding why your method above is better.

Can you enlighten me?

[AZJIO]

Clark

Works on WinXP