_GUICtrlTreeView_SelectItem

[SecretLanguage]

Im looking for something basic like this example to organize my favorite websites

i dont quite see how the $iRand = Random(0, 9, 1)

_GUICtrlTreeView_SelectItem($hTreeView, $hItem[$iRand])

plays a role in this script.

im sure there is a easy method which im over looking to edit the titles and direct the the selected item

to a webrowser. makes no difference to me if opened in new browser

expandcollapse popup

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_TV = False ; Check ClassName being passed to functions, set to True and use a handle to another control to see it work

Global $hImage, $hStateImage

_Main()

Func _Main()

Local $hItem[10], $hChildItem[30], $iRand, $iYItem, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

GUICreate("TreeView Select Item", 400, 300)

$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
_GUICtrlTreeView_SetUnicodeFormat($hTreeView, False)
GUISetState()

_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To 9
$hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
For $y = 1 To 3
$hChildItem[$iYItem] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $hItem[$x])
$iYItem += 1
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)

$iRand = Random(0, 9, 1)
_GUICtrlTreeView_SelectItem($hTreeView, $hItem[$iRand])

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main

[Nessie]

I really don't have understand what are you looking for Can you give us more explanation of what do you want to do?

[guinness]

The role is that it selects a random treeview control item.

[SecretLanguage]

just want to double click one of the items in the tree view and open explorer to a specified

webpage

[Nessie]

Check that:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>
#include <WinAPI.au3>

Global $hGUI, $hTV, $idTV, $idEdit, $hItem, $hChild

$hGUI = GUICreate("Test", 300, 400)
$hTV = _GUICtrlTreeView_Create($hGUI, 20, 20, 260, 100)
$idTV = _WinAPI_GetDlgCtrlID($hTV)

For $i = 1 To 5
    $hItem = _GUICtrlTreeView_Add($hTV, 0, "Item " & $i)
    For $c = 1 To 5
        $hChild = _GUICtrlTreeView_AddChild($hTV, $hItem, "Child " & $c)
    Next
Next

$idEdit = GUICtrlCreateEdit("", 20, 140, 260, 240)
ControlSetText($hGUI, "", $idEdit, ControlGetText($hGUI, "", $idEdit) & _
        "Initilize script:  " & @CRLF & _
        "$hGUI = " & $hGUI & @CRLF & _
        "$hTV = " & $hTV & "; $idTV = " & $idTV & @CRLF & _
        "$idEdit = " & $idEdit & @CRLF)

GUIRegisterMsg($WM_LBUTTONDBLCLK, "_WM_LBUTTONDBLCLK")
GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")
GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tagNMHDR = "int hwndFrom; int idFrom; int code"
    Switch $wParam
        Case $idTV
            Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
            If @error Then Return
            If DllStructGetData($tNMHDR, "code") = $NM_DBLCLK Then
                ControlSetText($hGUI, "", $idEdit, ControlGetText($hGUI, "", $idEdit) & _
                        "Double click on TreeView:  Hwnd = " & DllStructGetData($tNMHDR, "hwndFrom") & _
                        "; ID = " & DllStructGetData($tNMHDR, "idFrom") & @CRLF)
            EndIf
    EndSwitch
    $tNMHDR = 0
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_NOTIFY

Func _WM_LBUTTONDBLCLK($hWnd, $iMsg, $iwParam, $ilParam)
    Local $iX = BitAND($ilParam, 0xFFFF)
    Local $iY = BitShift($ilParam, 16)
    ControlSetText($hGUI, "", $idEdit, ControlGetText($hGUI, "", $idEdit) & _
            "Double click on GUI:  Hwnd = " & $hWnd & "; X = " & $iX & "; Y = " & $iY & @CRLF)
EndFunc   ;==>_WM_LBUTTONDBLCLK

The author of this function is PsaltyDS!

Hi!